mysql 一键脚本_MYSQL一键安装脚本

视频演示：https://www.bilibili.com/video/BV1p54y1Q7qn/

脚本代码(复制下边的代码保存为MYSQL安装.bat):

@setlocal enabledelayedexpansion

@echo off

color f0

title MYSQL一键安装

set basedir=!cd!

set bin=!cd!\bin

if exist !bin!\mysqld.exe (

rem 写入配置

>my.ini echo [mysqld]

>>my.ini echo port=3306

>>my.ini echo basedir=!basedir!

>>my.ini echo datadir=!basedir!\Data

>>my.ini echo log-error=!basedir!\Logs.log

>>my.ini echo max_connections=200

>>my.ini echo max_connect_errors=10

>>my.ini echo character-set-server=utf8mb4

>>my.ini echo default-storage-engine=INNODB

>>my.ini echo default_authentication_plugin=mysql_native_password

>>my.ini echo local_infile=ON

>>my.ini echo.

>>my.ini echo [mysql]

>>my.ini echo default-character-set=utf8mb4

>>my.ini echo local_infile=ON

>>my.ini echo.

>>my.ini echo [client]

>>my.ini echo port=3306

>>my.ini echo default-character-set=utf8mb4

rem 添加环境变量

echo 开始检查环境变量...

echo.

for /f "tokens=2*" %%i ^

in ('reg query "HKLM\SYSTEM\ControlSet001\Control\Session Manager\Environment" /v Path^|findstr /i "path"') ^

do (set "p=%%j")

for /f "tokens=*" %%a in ('echo !p! ^| find /i "!bin!"') do (set flag=1)

if not defined flag (

echo 开始添加环境变量

setx Path "!p!;!bin!" /M | find "成功" && echo 环境变量添加成功

set p=!Path!

) else (echo 环境变量已存在，无需设置。)

echo.

rem 初始化 --console

cd !bin!

>!basedir!\Logs.log echo --------初始化数据库开始--------

echo 开始初始化数据库

mysqld --initialize

>>!basedir!\Logs.log echo --------初始化数据库结束--------

for /f "tokens=4 delims=:" %%a in ('findstr /i "password" !basedir!\Logs.log') do (

set pwd=%%a

)

echo 初始化完成，root账号的临时密码: !pwd!

echo 请及时修改root账号的密码，临时密码记录在 !basedir!\Logs.log

echo.

rem 安装服务

echo 开始安装服务

mysqld --install MySQL | find "successfully" && echo 服务安装成功

echo.

rem 启动服务

echo 开始启动MYSQL服务

net start MySQL

echo.

ping -t 127.0 -n 2 >nul

echo 请输入临时密码登录MySQL修改root密码，输入以下命令修改密码:

echo    ALTER USER root@localhost IDENTIFIED BY '新密码';

echo.

mysql -u root -p

echo 安装完成，现在可以使用新密码登录MYSQL，按任意键退出

) else (

echo 请将本工具放在解压后的MYSQL根目录下再打开

)

pause >nul