win32汇编创建窗口

最新推荐文章于 2020-04-03 21:47:40 发布

It塔塔开

最新推荐文章于 2020-04-03 21:47:40 发布

阅读量296

点赞数

分类专栏：学习笔记文章标签： win32 汇编

本文链接：https://blog.csdn.net/weixin_37703001/article/details/104240955

版权

学习笔记专栏收录该内容

15 篇文章 0 订阅

订阅专栏

    .386
    .model flat,stdcall
    option casemap:none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include    \masm32\include\windows.inc
include    \masm32\include\user32.inc
includelib \masm32\lib\user32.lib
include    \masm32\include\gdi32.inc
includelib \masm32\lib\gdi32.lib
include    \masm32\include\kernel32.inc
includelib    \masm32\lib\kernel32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;数据段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    .data
hInstance   dd  ?
hWinMain    dd  ?
    .const
szClassName     db  'MyClass',0
szCaptionMain   db  'My first Window !',0
szText          db  'Win32 Assembly, Simple and powerful !',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;代码段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    .code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;窗口过程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcWinMain    proc   uses ebx edi esi, hWnd,uMsg,wParam,lParam
                local @stPS:PAINTSTRUCT
                local @stRect:RECT
                local @hDC
                mov eax,uMsg
;**********************************************************************
                .if eax == WM_PAINT
                    invoke  BeginPaint,hWnd,addr @stPS
                    mov @hDC,eax
                    invoke  GetClientRect,hWnd,addr @stRect
                    invoke  DrawText, @hDC,addr szText, -1 ,\
							addr @stRect,\
                            DT_SINGLELINE or DT_CENTER or DT_VCENTER
                    invoke  EndPaint,hWnd,addr @stPS
;***********************************************************************
                .elseif eax == WM_CLOSE
                        invoke  DestroyWindow,hWinMain
                        invoke  PostQuitMessage,NULL
;***********************************************************************
                .else
                    invoke  DefWindowProc,hWnd,uMsg,wParam,lParam
					ret
                .endif
;***********************************************************************
                xor eax, eax
                ret
_ProcWinMain    endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>

_WinMain    Proc	
            local   @stWndClass11:WNDCLASSEX
            local   @stMsg:MSG

            invoke  GetModuleHandle,NULL
            mov     hInstance,eax
            invoke  RtlZeroMemory,addr @stWndClass11,sizeof @stWndClass11
;*******************************************************************************
;注册窗口
;*******************************************************************************

           ; invoke LoadCursor,0,IDC_ARROW
            mov     @stWndClass11.hCursor,NULL
            push    hInstance
            pop     @stWndClass11.hInstance
            mov @stWndClass11.cbSize,sizeof WNDCLASSEX
            mov @stWndClass11.style,CS_HREDRAW or CS_VREDRAW
            mov @stWndClass11.lpfnWndProc, offset _ProcWinMain
            mov @stWndClass11.hbrBackground,COLOR_WINDOW + 1
            mov @stWndClass11.lpszClassName, offset szClassName
            invoke  RegisterClassEx,addr @stWndClass11
;*******************************************************************************
;建立并显示窗口
;*******************************************************************************
            invoke  CreateWindowEx,WS_EX_CLIENTEDGE,\
                    offset  szClassName, offset szCaptionMain,\
                    WS_OVERLAPPEDWINDOW,\
                    100,100,600,400,\
                    NULL,NULL,hInstance,NULL
                    mov hWinMain, eax
                    invoke  ShowWindow, hWinMain,SW_SHOWNORMAL
                    invoke  UpdateWindow, hWinMain
 ;***************************************************************************
 ;消息循环
 ;***************************************************************************
            .while TRUE
                    invoke GetMessage, addr @stMsg, hWinMain, 0, 0
                    .break.if eax == -1
                    invoke  TranslateMessage, addr @stMsg
                    invoke  DispatchMessage, addr   @stMsg  
            .endw
            ret
            
_WinMain    endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
           call _WinMain
           invoke   ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
            end start