halcon 圆拟合

最新推荐文章于 2024-07-07 16:51:18 发布

Alphapeople

最新推荐文章于 2024-07-07 16:51:18 发布

阅读量676

点赞数 8

文章标签： linux 数据库前端

本文链接：https://blog.csdn.net/weixin_38241876/article/details/135003024

版权

* Approximation of XLD contours by ellipses or elliptic arcs
* 
gen_image_const (Image, 'byte', 400, 400)
dev_set_color ('green')
gen_ellipse (Ellipse, 200, 200, rad(30), 150, 120)
paint_region (Ellipse, Image, ImageEllipse, 255, 'fill')
edges_sub_pix (ImageEllipse, EdgesComplete, 'mderiche2', 0.5, 20, 40)
* First, the easy case:
fit_ellipse_contour_xld (EdgesComplete, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)
* Now simulate a fragmented ellipse:
gen_ellipse_contour_xld (ContEllipse, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder, 1.5)
gen_rectangle2 (Rectangle1, 200, 200, rad(30), 150, 2)
gen_rectangle2 (Rectangle2, 200, 200, rad(120), 150, 2)
union2 (Rectangle1, Rectangle2, Cross)
complement (Cross, CrossComplement)
reduce_domain (ImageEllipse, CrossComplement, ImageEllipseReduced)
edges_sub_pix (ImageEllipseReduced, EdgesIncomplete, 'mderiche2', 0.5, 20, 40)
* Now the difficult case:
* First, make a fit to the individual arcs.
fit_ellipse_contour_xld (EdgesIncomplete, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)
* Now we would have to determine which elliptic arcs should be merged.
* We assume that the customer is able to do this.
* If not, this could be done by clustering the elliptic arcs based on the centers
* and radii that result from the above fit.
* 
* Now we have to determine in which order the arcs should be merged.
* This can be done by sorting them according to their StartPhi.
Order := sort_index(StartPhi)
* Now construct a new contour from the coordinates of the segments to be merged:
RowsMerged := []
ColsMerged := []
for I := 0 to |Order| - 1 by 1
    select_obj (EdgesIncomplete, SelectedEdge, Order[I] + 1)
    get_contour_xld (SelectedEdge, Rows, Cols)
    if (PointOrder[Order[I]] == 'negative')
        Rows := inverse(Rows)
        Cols := inverse(Cols)
    endif
    RowsMerged := [RowsMerged,Rows]
    ColsMerged := [ColsMerged,Cols]
endfor
dev_set_color ('blue')
gen_contour_polygon_xld (Contour, RowsMerged, ColsMerged)
fit_ellipse_contour_xld (Contour, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)
dev_set_color ('red')
gen_ellipse_contour_xld (ContEllipseIncomplete, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder, 1.5)