Unity着色器和屏幕特效开发秘籍 顶点-片元着色器实现系列-AnimatedSprite

表面着色器实现：

Shader "AnimatedSprite"
{
	Properties
	{
		_MainTex("Base(RGB)",2D) = ""{}
		_CellAmount("Cell Amount",Float) = 9.0
		_Speed("Speed",Range(0.01,32)) = 12
	}
	SubShader
	{
		Tags{"RenderType" = "Opaque"}
		LOD 200
		CGPROGRAM
		#pragma surface surf Lambert
		sampler2D _MainTex;
		fixed _CellAmount;
		fixed _Speed;
		struct Input
		{
			half2 uv_MainTex;
		};
		void surf(Input IN,inout SurfaceOutput o)
		{
			half2 spriteUV = IN.uv_MainTex;
			float timeVal = fmod(_Speed * _Time.y,_CellAmount);
			timeVal = ceil(timeVal);
			float xValue = spriteUV.x + timeVal;
			xValue /= _CellAmount;
			spriteUV = half2(xValue,spriteUV.y);
			fixed4 col = tex2D(_MainTex,spriteUV);
			o.Albedo = col.rgb;
			o.Alpha = col.a;
		}
		ENDCG
	}
	FallBack "Diffuse"
}

顶点-片元着色器实现：

Shader "AnimatedSprite"
{
	Properties
	{
		_MainTex("Base(RGB)",2D) = ""{}
		_CellAmount("Cell Amount",Float) = 0.0
		_Speed("Speed",Range(0.01,32)) = 12
	}
	SubShader
	{
		Pass
		{
			Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			sampler2D _MainTex;
			fixed4 _MainTex_ST;
			fixed _CellAmount;
			fixed _Speed;
			struct a2v
			{
				float4 vertex:POSITION;
				float4 texcoord:TEXCOORD0;
				float3 normal:NORMAL;
			};
			struct v2f
			{
				float4 pos:SV_POSITION;
				half2 uv:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float3 worldNormal:TEXCOORD2;
			};
			v2f vert(a2v v)
			{
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
				half2 uv = TRANSFORM_TEX(v.texcoord,_MainTex);
				float timeVal = fmod(_Time.y * _Speed,_CellAmount);
				timeVal = ceil(timeVal);
				uv.x += timeVal;
				uv.x /= _CellAmount;
				o.uv = uv;
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				return o;
			}
			fixed4 frag(v2f i):SV_Target
			{	
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,lightDir));
				return fixed4(ambient + diffuse,1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}