Unity着色器和屏幕特效开发秘籍 顶点-片元着色器实现系列-SimpleReflection

表面着色器实现：

Shader "Custom/SampleReflection"
{
	Properties
	{
		_MainTex("Base(RGB)",2D) = ""{}
		_MainTint("Main Tint",Color) = (1,1,1,1)
		_CubeMap("Cube Map",CUBE) = ""{}
		_ReflAmount("Reflection Amount",Range(0.01,1)) = 0.5
		//_ReflMask("Reflection Mask",2D) = ""{}
	}
	SubShader
	{
		Tags{"RenderType" = "Opaque"}
		LOD 200
		CGPROGRAM
		#pragma surface surf Lambert
		sampler2D _MainTex;
		fixed4 _MainTint;
		samplerCUBE _CubeMap;
		fixed _ReflAmount;
		sampler2D _ReflMask;
		struct Input
		{
			half2 uv_MainTex;
			fixed3 worldRefl;
		};
		void surf(Input IN,inout SurfaceOutput o)
		{
			fixed4 col = tex2D(_MainTex,IN.uv_MainTex);
			o.Albedo = col.rgb;
			o.Alpha = col.a;
			o.Emission = texCUBE(_CubeMap,IN.worldRefl) * _ReflAmount;
			//fixed4 reflMask = tex2D(_ReflMask,IN.uv_MainTex);
			//o.Emission = texCUBE(_CubeMap,IN.worldRefl) * _ReflAmount * reflMask.r;
		}
		ENDCG
	}
	FallBack "Diffuse"
}

顶点-片元着色器实现：

Shader "Custom/SampleReflection"
{
	Properties
	{
		_MainTex("Base(RGB)",2D) = ""{}
		_MainTint("Main Tint",Color) = (1,1,1,1)
		_CubeMap("Cube Map",CUBE) = ""{}
		_ReflAmount("Reflection Amount",Range(0.01,1)) = 0.5
		//_ReflMask("Reflection Mask",2D) = ""{}
	}
	SubShader
	{
		Pass
		{
			Tags{"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			sampler2D _MainTex;
			fixed4 _MainTex_ST;
			fixed4 _MainTint;
			samplerCUBE _CubeMap;
			fixed _ReflAmount;
			sampler2D _ReflMask;
			struct a2v
			{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f
			{
				float4 pos:SV_POSITION;
				float2 uv:TEXCOORD0;
				float3 worldNormal:TEXCOORD1;
				float3 worldPos:TEXCOORD2;
			};
			v2f vert(a2v v)
			{
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
				o.worldNormal = mul(unity_ObjectToWorld,v.normal);
				return o;
			}
			fixed4 frag(v2f i):SV_Target
			{
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				float3 worldRefl = reflect(-viewDir,worldNormal);
				fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _MainTint.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,lightDir));
				fixed3 reflection = texCUBE(_CubeMap,worldRefl);
				//fixed3 reflMask= tex2D(_ReflMask,i.uv).rgb;
				//fixed3 reflection = texCUBE(_CubeMap,worldRefl) * reflMask.r;
				fixed3 color = ambient + lerp(diffuse,reflection,_ReflAmount);
				return fixed4(color,1.0);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}