KEIL 5.38的ARM-CM3/4 ARM汇编设计学习笔记13 - STM32的SDIO学习5 - 卡的轮询读写擦

已于 2024-05-06 16:57:29 修改
阅读量1k 收藏 18
点赞数 20
分类专栏： KEIL 5.38的ARM汇编 文章标签： arm开发 汇编 学习
于 2024-05-06 14:14:11 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_40169389/article/details/138483914
版权

KEIL 5.38的ARM-CM3/4 ARM汇编设计学习笔记13 - STM32的SDIO学习5 - 卡的轮询读写擦

一、前情提要

在上一篇提到了要实现SDIO内存卡的读写擦，但是由于程序在调试的时候出现了一些bug，所以一直没有把这个坑填上。最近由于做了一些测试，把读写擦实现了。所以特此来把这个坑填上。

二、目标

  1. 实现读写擦的函数。
  2. 编写测试用例，将一个块擦除，写入内容，再读出来。

三、技术方案

3.1 读写擦的操作

读写擦的具体的指令其实很多帖子都有介绍，笔者就是参考的手册本身。但是具体的流程还是要说一下。

3.1.1 读卡操作

  1. 设置SDIO_DLEN和SDIO_DCTRL两个寄存器。在SDIO_DLEN设置块大小，一般是512字节；在SDIO_DCTRL里设置块大小是9（代表512）、数据传输方向是卡到MCU，暂不启动。必要的话CMD16设置卡的块大小。
  2. CMD7+RCA选中卡。
  3. 置位SDIO_DCTRL的Dten位，使能MCU的传输。
  4. CMD17+块地址要求卡发送数据
  5. 轮询SDIO_STA的SDIO_STA_RXFIFOHF位看看有没有数据到位；轮询SDIO_STA的SDIO_STA_DATAEND位检查卡是否已经发送完成。
  6. 轮询SDIO_STA的SDIO_STA_RXDAVL把管子里的数据都收拾出来。
  7. 通过复位SDIO_DCTRL的Dten位以关闭DPSM。
  8. 通过SDIO_ICR清了SDIO_STA。
  9. 收工

3.1.2 写卡操作

  1. 设置SDIO_DLEN和SDIO_DCTRL两个寄存器。在SDIO_DLEN设置块大小，一般是512字节；在SDIO_DCTRL里设置块大小是9（代表512）、数据传输方向是MCU到卡，暂不启动。必要的话CMD16设置卡的块大小。
  2. CMD7+RCA选中卡。
  3. 置位SDIO_DCTRL的Dten位，使能MCU的传输。
  4. CMD24+块地址通知卡MCU将要发送数据
  5. 轮询SDIO_STA的SDIO_STA_TXFIFOHE位看看是否管子里有空间发数据；轮询SDIO_STA的SDIO_STA_DATAEND位检查MCU是否已经发送完成。
  6. 轮询SDIO_STA的SDIO_STA_DBCKEND直至发送结束
  7. 通过复位SDIO_DCTRL的Dten位以关闭DPSM。
  8. CMD13轮询卡的状态。直至状态离开PROG状态。
  9. 收工

3.1.3 擦除操作

  1. CMD7+RCA选中卡。
  2. CMD32设置起始块、CMD33设置终止块和CMD38执行擦除。
  3. CMD13轮询卡的状态。直至离开PROG状态。
  4. 收工

3.2 一些技术点

3.2.1 轮询标志位的选择不唯一

由于没有采用DMA，所以读写的时候都必须手动轮询SDIO_STA的某些标志位来保证读写操作的顺利完成。但是参考手册会发现对于读写操作并没有规定操作规范。有的时候对于同一个目的可以有多个标志位可以使用。这里确实是有多个标志位可以采用。但是要通过测试去验证。

3.2.2 写和擦的卡状态查询

卡在执行写和擦的操作时候会处于PROG状态。这个时候必须要轮询至状态转移才可以保证操作的成功。

3.2.3 写的速度

按照卡的SDIO_STATUS，很多时候卡的速度都是24MBit/s或50MBit/s，但是在实际操作的时候会发现速度似乎只能开到6.7MBit/s左右，不论是单线模式还是4线模式都不行。看时钟信号发现是非常连续的，所以排除了发送数据的时候有延迟的原因。这个问题目前没有解决，如果未来找到了原因再记录。
请添加图片描述
从上面的这个图中可以看到，时钟信号SDIO_CLK（红色）其实是非常连贯的。但是频率只能达到6.8，也就是5+2分频。所以笔者认为其实换成DMA传输也不太可能改善这个。但是未来如果有机会试试再测试吧。

四、代码实现

4.1 接口定义

SDIO内存卡的接口定义如下所示：

#ifndef _SDIO_Memory_CARD_H_
#define _SDIO_Memory_CARD_H_

#include "stdint.h"
typedef enum {
	waitRsp_noRsp     = 0,
	waitRsp_shortRsp = 1,
	waitRsp_longRsp  = 3,
}WaitRspKind;

typedef struct {
	void  (*init)(void);
	uint32_t (*card_identification)(void);
	uint32_t (*read_SD_status)(void);
	uint32_t (*erase_block)(uint32_t, uint32_t);
	uint32_t (*read_block)(uint32_t, uint32_t*);
	uint32_t (*write_block)(uint32_t, uint32_t*);
}SDIO_Memory_Card_Def;

extern const SDIO_Memory_Card_Def SDIO_Memory_Card;
#endif

添加了3个函数接口，分别是

	uint32_t (*erase_block)(uint32_t, uint32_t);
	uint32_t (*read_block)(uint32_t, uint32_t*);
	uint32_t (*write_block)(uint32_t, uint32_t*);

这三个接口的实现如下所示。但是由于前面说了逻辑，具体的每行的解释这里就不说了。

4.2 read_block接口的实现

; uint32_t read_block(uint32_t, uint32_t*);
; r0 is the address of the block,
; r1 is the read buffer.
     align  4
read_block	proc
	 push   {r4 - r11, lr}
	 ldr    rSDIO, =SDIO_BaseAddr
	 ldr	rCard_Info, =card_info_data
	 sub    sp, #4 * 2
	 ldrb	r4, card_isSDSC
	 lsl	r0, r4
	 str	r0, [sp, #0]
	 str	r1, [sp, #4]

; Select the Card.	 	 
	 mov	r0, #7:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd
; Set the block size in case of SDSC.	 	 
	 mov	r0, #16:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov    r1, #512	 	 
	 bl     send_cmd
	 
	 ldr	r4, [sp, #0] ;  The address of the block in the SD Memory Card
	 ldr	r5, [sp, #4] ;  The address of the buffer	 
; Send CMD17 to inform the card to start a data sending.
	 mov    r0, #17:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov    r1, r4
	 bl     send_cmd 	
	 
	 mov	r0, #0
	 str	r0, [rSDIO, #SDIO_DCTRL]
	 mov 	r0, #512
	 str	r0, [rSDIO, #SDIO_DLEN]
	 mov	r0, #(9 :shl: 4):or:SDIO_DCTRL_DTDIR_Card2Controller \
					:or: SDIO_DCTRL_Dten
	 str	r0, [rSDIO, #SDIO_DCTRL] 
	 
reading_data_start	 
	 ldr	r0, [rSDIO, #SDIO_STA]	
	 tst	r0, #SDIO_STA_RXACT
	 beq	reading_data_start
reading_data
	 ldr	r0, [rSDIO, #SDIO_STA]	
	 tst	r0, #SDIO_STA_DATAEND
	 bne	reading_clear_the_FIFO
	 tst	r0, #SDIO_STA_RXFIFOHF
	 beq	reading_data
	 ldr	r1, [rSDIO, #SDIO_FIFO]
	 str	r1, [r5]
	 add	r5, #4
	 b		reading_data
reading_clear_the_FIFO
	 ldr	r0, [rSDIO, #SDIO_STA]
	 tst	r0, #SDIO_STA_RXDAVL
	 beq	reading_completed
	 ldr	r1, [rSDIO, #SDIO_FIFO]
	 str	r1, [r5]
	 add	r5, #4
	 b		reading_clear_the_FIFO
reading_completed	
	 mov	r0, #0
	 str	r0, [rSDIO, #SDIO_DCTRL]
	 mov	r0, #0x7ff
	 str	r0, [rSDIO, #SDIO_ICR]
	 mov	r0, #7:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov	r1, #0
	 bl		send_cmd
	 mov	r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd
	 ldr 	r0, [rSDIO, #SDIO_RESP1]
	 ubfx	r0, r0, #9, #4
	 add	sp, #4 * 2
	 pop    {r4 - r11, lr}
	 bx     lr
	 ltorg
     endp

4.3 write_block接口的实现

; uint32_t write_block(uint32_t, uint32_t*);
	 align	4
write_block	proc
	 push   {r4 - r11, lr}	
	 ldr    rSDIO, =SDIO_BaseAddr
	 ldr	rCard_Info, =card_info_data
	 ldrb	r4, card_isSDSC
	 lsl	r0, r4
	 sub	sp, #4 * 2
	 str	r0, [sp, #0]
	 str	r1, [sp, #4]
	 
	 mov	r0, #7:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd
	 	 
	 mov	r0, #16:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov    r1, #512	 	 
	 bl     send_cmd
	 
	 ldr	r4, [sp, #0] ;  The address of the block in the SD Memory Card
	 ldr	r5, [sp, #4] ;  The address of the buffer
	 mov	r6, #0;
	 
	 mov    r0, #24:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov    r1, r4
	 bl     send_cmd 
	 
	 mov	r0, #0
	 str	r0, [rSDIO, #SDIO_DCTRL]
	 mov 	r0, #512
	 str	r0, [rSDIO, #SDIO_DLEN]
	 mov	r0, #(9:shl:4):or:SDIO_DCTRL_Dten
	 str	r0, [rSDIO, #SDIO_DCTRL]
writing_data_start
	 ldr	r0, [rSDIO, #SDIO_STA]
	 tst	r0, #SDIO_STA_TXACT
	 beq	writing_data_start
	 mov	r1, #SDIO_STA_DBCKEND:or:SDIO_STA_DCRCFAIL
writing_data
	 ldr	r0, [rSDIO, #SDIO_STA]
	 tst	r0, r1
	 bne	writing_completed
	 tst	r0, #SDIO_STA_TXFIFOE
	 beq	writing_data
	 ldr	r0, [r5]
	 str	r0, [rSDIO, #SDIO_FIFO]
	 add	r5, #4
	 add	r6, #1
	 b		writing_data
writing_completed
	 mov	r0, #0
	 str	r0, [rSDIO, #SDIO_DCTRL]
;	 mov    r0, #12:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
;	 ldr    r1, card_rca	 	 
;	 bl     send_cmd
write_block_the_card_is_programming	 
	 mov    r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr    r1, card_rca	 	 
	 bl     send_cmd
	 ldr	r0, [rSDIO, #SDIO_RESP1]
	 ubfx	r1, r0, #9, #4
	 cmp	r1, #7
	 beq	write_block_the_card_is_programming
	 
	 mov	r0, #0x7ff
	 str	r0, [rSDIO, #SDIO_ICR]
	 	 
	 mov    r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr    r1, card_rca	 	 
	 bl     send_cmd
	 ldr	r0, [rSDIO, #SDIO_RESP1]
	 
	 add	sp, #4 * 2
	 pop    {r4 - r11, lr}
	 bx		lr
	 endp

4.4 erase_block接口的实现

; uint32_t erase_block(uint32_t, uint32_t);		 
; r0: Start block
; r1: End block
     align  4
erase_block proc
	 push   {r4 - r11, lr}
	 ldr    rSDIO, =SDIO_BaseAddr
	 ldr	rCard_Info, =card_info_data
	 sub	sp, #4 * 2
	 ldrb	r4, card_isSDSC
	 lsl	r0, r4
	 lsl	r1, r4
	 str	r0, [sp, #0]; [sp, #0] is the start block 
	 str	r1, [sp, #4]; [sp, #4] is the end block
	 
	 mov	r0, #7:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd 
	 mov	r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd
	 
	 mov	r0, #32:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, [sp, #0];
	 bl	 	send_cmd
	 mov	r0, #33:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, [sp, #4];
	 bl	 	send_cmd
	 mov	r0, #38:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 mov	r1, #0
	 bl	 	send_cmd

erase_block_the_card_is_programming
	 mov    r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr    r1, card_rca	 	 
	 bl     send_cmd
	 ldr	r0, [rSDIO, #SDIO_RESP1]
	 ubfx	r1, r0, #9, #4
	 cmp	r1, #7
	 beq	erase_block_the_card_is_programming
	 
	 mov	r0, #7:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd 
	 
	 mov	r0, #13:or:SDIO_CMD_WAITRESP_Short:or:SDIO_CMD_CPSMEN
	 ldr	r1, card_rca
	 bl		send_cmd
	 ldr 	r0, [rSDIO, #SDIO_RESP1]
	 ubfx	r0, r0, #9, #4
	 
	 add	sp, #4 * 2
	 pop    {r4 - r11, lr}
	 bx     lr
	 ltorg
     endp

4.5 send_cmd内部函数

虽然前面的几个帖子中也讲到了这个内部函数的实现。但是为了方便阅读，这里还是把它粘过来了。

; 	 Priviate Function Name: Send_cmd
;	 Args:  r0 - cmd, r1 - arg
;	 实现这个函数

	 align  4		 
send_cmd	proc
	 push   {r4 - r11, lr}
	 ldr    rSDIO, =SDIO_BaseAddr
	 ldr    rCard_Info, =card_info_data
	 mov    r2, #0x7f
	 str    r2, [rSDIO, #SDIO_ICR]
	 str    r1, [rSDIO, #SDIO_ARG]
	 str    r0, [rSDIO, #SDIO_CMD]
wait_for_response
	 ldr    r1, [rSDIO, #SDIO_STA]
	 tst    r1, #SDIO_STA_CMDREND:or:SDIO_STA_CCRCFAIL:or:SDIO_STA_CTIMEOUT
	 beq    wait_for_response
	 bic	r0, #SDIO_CMD_CPSMEN
	 str    r0, [rSDIO, #SDIO_CMD]
	 pop    {r4 - r11, lr}	
	 bx     lr
	 endp

五、测试与结论

5.1 测试用例

#include "cmsis_os2.h"                          // CMSIS RTOS header file
#include "SDIO_TestCase.h"
#include "SDIO_Memory_Card.h"
#include "stdio.h"
/*----------------------------------------------------------------------------
 *      Thread 1 'Thread_Name': Sample thread
 *---------------------------------------------------------------------------*/
 
static osThreadId_t tid_SDIO_Testcase;                        // thread id
 
void SDIO_Testcase (void *argument);                   // thread function
 
int Init_SDIO_Testcase (void) {
 
  tid_SDIO_Testcase = osThreadNew(SDIO_Testcase, NULL, NULL);
  if (tid_SDIO_Testcase == NULL) {
    return(-1);
  }
 
  return(0);
}
 
__NO_RETURN void SDIO_Testcase (void *argument) {
	static uint32_t resp = 0;
	static union{
		uint32_t buf32[512 / 4];
		char buf8[512];
	}rBuf, wBuf;
	(void)argument;
	sprintf(wBuf.buf8, "I love Miao! I love you, Da Miao");
	SDIO_Memory_Card.card_identification();
	SDIO_Memory_Card.read_SD_status();
	
//	SDIO_Memory_Card.erase_block(0,0);
	SDIO_Memory_Card.read_block(0, rBuf.buf32);
	
	SDIO_Memory_Card.erase_block(10,15);
	SDIO_Memory_Card.read_block(10, rBuf.buf32);
	SDIO_Memory_Card.write_block(11, wBuf.buf32);
	SDIO_Memory_Card.read_block(11, rBuf.buf32);
	
  while (1) {
		resp = (resp + 1)%100;
   		osDelay(101);
  }
}

5.2 运行结果

在这里插入图片描述

可以看到，笔者成功地向第11块中写入了一行英文，“I love you, Da Miao, Kitty and Andy!”。

5.3 其他测试结果

对于这种SDIO内存卡，用单线还是四线数据总线模式其实都是成立的。只要MCU和卡的设置都协调好就可以了。

我把程序换到了另一个pin都引出来的板子上，把波形打出来。请添加图片描述
单线模式下的波形。红线是SDIO_CLK，黄线是D0。也许有人会认为，这不就是个高速的I2C么。其实不是的。会看到，每一帧都没有ACK和NACK。所以不能替代I2C。

请添加图片描述

四线模式下的波形。红线是SDIO_CLK，其他是D0、D1和D2。由于这个示波器是借的，没有配数字探头，所以看不全所有的信号。

但是从调试上可以看到都能实现操作。
在这里插入图片描述

这里注明一下，因为HX32F4的开发板没有将SDIO有关的引脚引出，所以无法测量。我用另一个板子做了测试，但是用的IDE是Segger Embedded Studio做的，也就是上面的这个界面。

六、总结

这样，用轮询的方式实现读写擦SD卡的驱动就实现了。有若干的技术点：

  1. 读的速率可以根据卡的额定速度来，但是写入的速度不能高于6.8MBit/s。
  2. 写入和擦除之后要轮询卡的状态，确认卡已经从PROG状态中转出。
  3. 读写擦的轮询的标志位其实可以有多个选择。但是要测试确认。
  4. 管子的数据是32位的，但是发送的是按照8位的。所以可以认为是一次发4个字节。读写缓冲区都必须是字对齐（4字节对齐）。
  5. 要查询SDIO_STATUS，根据版本号确认如何读写。这里还是点一下，2GB以下的卡的寻址是以字节的，而以上的都是以块寻址的。当然，读写的时候都要以块为单位。比如，1GB的卡以字节寻址到第10块，但是还是要一次读1个整块。除非中途用CMD12打断。

这样就可以实现一套SDIO内存卡的驱动。

超级喵窝窝
关注
专栏目录
搭建并配置Keil嵌入式开发环境，完成一个基于STM32汇编程序的编写。
m0_53073729的博客
10-08 200
1）记录build生成的 hex文件各段的大小，了解Hex文件格式及其前8个字节内容含义； 2）学习在没有硬件条件下进行仿真调试的方法，观察ARM寄存器变化状况。 一、环境配置 ​MDK（Microcontroller Development Kit）是针对ARM处理器，特别是Cortex-M内核处理器的最佳开发工具。 下载地址: mdk531安装 链接：https://pan.baidu.com/s/1ttrDhv6kXgAvPiYINf9iGw 提取码：1234 注册器 链接：http
【ARM】基本汇编指令——Keil
colorfulshark
07-28 7899
area reset, code ; 定义一个代码段叫reset ;/*汇编文件中的符号*/ ;1.指令：编译完成后作为一条指令存储在内存单元当中，CPU执行时能完成一定的操作 ;2.伪操作：不会生成代码也不会占用内存，告诉编译器怎样编译 ;3.伪指令：本身不是指令，编译器在编译的时候将其替换成CPU能识别的指令;/*指令*/ ;1.数据操作指令：对数据进行逻辑
KEIL 5.38的ARM-CM3/4 ARM汇编设计学习笔记8 - STM32的CAN学习与测试3
超级喵窝窝的博客
02-23 346
但是我这里只是为了了解CAN总线的接收功能，就不去费事搞了。只要能在DEBUG里看到接收到的数据就可以了。测试用例的代码如下所示。由于KEIL的寄存器窗口不能看到ASCII码，所以笔者把RDL0R的地址用memory标签也打开了。综上所述，也包括前面写到的两篇文章，可以确定：CAN总线接口在下面的初始化流程之后，就可以方便的收发数据了。给两块板子下载完成以后，DEBUG进入一块板子的DEBUG界面，如下所示。虽然两个板子都在发送，但是还是可以接收到其他的板子发送的数据。这样就可以时间数据的发送了。
ARM汇编程序调试——keil5环境搭建和stm32汇编程序编写
lg_laowang的博客
01-13 3718
搭建并配置Keil嵌入式开发环境，完成一个基于STM32汇编程序的编写 一、新建项目 二、代码编写及配置 1. 代码 2. 配置环境 三、编译调试 四、了解Hex文件 1.打开.hex文件 2. 解释含义 小小的总结 参考文献 一、新建项目 按以下步骤新建项目即可： project——New 保存位置及项目名称 选择芯片 按以下勾选即可 添加源文件 二、代码编写及配置 1. 代码 处于源文件中 AREA MYDATA, DATA AREA M...
基于Keil 5编写汇编程序
热门推荐
qq_45237293的博客
12-28 2万+
本文目的是通过keil 5 编写汇编程序来熟悉汇编语言的相关知识。这里分为两个部分：第一个部分在Keil上练习汇编的编写和调试，同时了解一下Hex文件的格式；第二个部分是使用汇编进行stm32F103的点灯实验，用实战的方式来加深理解。 目录（一）汇编语言1.简介2.指令3.优缺点（二）使用Keil 5编写汇编程序1.新建汇编工程2.新建汇编文件 （一）汇编语言 1.简介 汇编语言（Assembly Language）是一种用于电子计算机、微处理器、微控制器或其他可编程器件的低级语言，亦称为符号语言。.
stm32f4-discovery-keil-sdio-fatfs-master.zip
02-12
这个压缩包"stm32f4-discovery-keil-sdio-fatfs-master.zip"包含了在STM32F407上实现SDIO接口与FATFS文件系统的示例代码，适用于Keil MDK集成开发环境。 SDIO（Secure Digital Input/Output）是一种高速接口，用于...
Keil.STM32F4xx-DFP.2.17.0.pack(最新固件！ M32F4xx系列固件库for Keil MDK 5)
02-02
STM32F4xx系列固件库是专为基于ARM Cortex-M4内核的STM32微控制器设计的，主要用于Keil MDK (uVision) 5开发环境。这个固件库版本为2.17.0，是官方提供的最新更新，确保开发者能够利用最新的功能和性能优化。 Keil ...
Keil.STM32F4xx-DFP.2.17.0.pack
01-19
Version: 2.17.0 (2023-01-16) Keil.STM32F4xx_DFP.2.17.0.pack Download Updated Pack to STM32Cube_FW_F4 Firmware Package version V1.27.1 using HAL Drivers V1.8.1.
keil5.38安装包
05-31
keil5.38安装包
Keil.STM32F4xx_DFP.2.14.0.pack(官方STM32F4xx系列最新固件库for Keil MDK 5)
06-21
此固件库为Keil官方提供，直接双击安装即可，安装成功后在MDK5工程的Device中可以选择STM32该系列的ARM芯片。 Version: 2.14.0 (2019-07-24) Keil.STM32F4xx_DFP.2.14.0.pack Warning: --C99 is no longer ...
嵌入式ARM下keil汇编的简单使用
wer4567的博客
10-08 1383
Keil-MDK下汇编语言的简单使用，以及相关环境的配置
ARM汇编基础基于Keil创建STM32汇编程序的编写
m0_49297422的博客
10-02 3804
文章目录新建项目配置环境调试代码hex文件分析参考资料 新建项目 配置环境 调试代码 hex文件分析 参考资料 ARM汇编基础之基于MDK创建纯汇编语言的STM32工程 hex文件百科 基于 MDK 创建 STM32 汇编语言工程并分析 HEX 文件内容 STM32基于汇编方式创建工程文件和闪烁LED灯 ...
Keil 丢失编译器版本5、内核文件core_cm3.c报错
qq_52804040的博客
03-02 3356
若用的是旧版本的core_cm3.c ，就使用编译器v5编译工程；若想用编译器v6，就更新4个相关的内核文件：（CMSIS：Cortex Microcontroller Software Interface Standard，ARM Cortex™ 微控制器软件接口标准）
第3周--ARM汇编语言编程入门实践
Porpoise_的博客
10-08 690
本文介绍了如何搭建并配置Keil嵌入式开发环境，完成一个基于STM32汇编程序的编写。记录build生成的 hex文件各段的大小，了解Hex文件格式及其前8个字节内容含义，学习在没有硬件条件下进行仿真调试的方法，观察ARM寄存器变化状况。
Keil下ARM汇编程序建立与调试简介
朝辞暮见的博客
06-05 1万+
1. 新建工程  选择目标处理器 比如：SAMSUNG /S3C2410 2. 新建文件 保存SAVE3. 把文件添加入工程或者双击组文件夹，选择你保存的文件 4. 设置工程属性     5. 编辑代码  6. build  7. debug 8. 调试方法简介  窗口1汇编代码编辑窗口窗口2单步调试工作栏，也可以按快捷键F11或F10窗口3 是程序执行时的寄存器窗口，Supervisor 高黑，...
ARM 汇编学习——编写简单的ARM汇编程序
知秋一叶
02-23 2万+
首先，我们先看一个简单的汇编程序： area ff,code,readonly ；声明代码段 code32 ；声明为32位ARM指令 entry ；声明程序入口 start ;b指令 ;1.b 跳转范围+_ 32M b + 标号 ;b start ;b stop ;2.bl 子函数调用 ;会把预取指令的地址保存在lr（r14） ;3.bx 子函数返回
Docker Swarm集群配置与使用
大头皮鞋的博客
10-31 852
Docker Swarm集群配置与使用。
ARM base instruction -- bic
最新发布
xiaozhi
11-01 282
ARM base instruction -- bic
Harmony OS搭建广告展示页
LexinZong的博客
10-29 525
1. 通过首选项配置存储我们的常用配置，比如是否需要广告页、广告页的路由地址、点击广告页跳转的链接以及广告页倒计时。上面还用到了两个常量，我们需要在constants目录下定义一个文件专门用来记录setting。1.2 新建一个关于读取首选项的类，用于读取和设置首选项的广告设置。1.4 模拟一个请求，给一个默认广告，写入首选项-正常加载主页。有些app需要广告页，有的不需要，我们需要搞个配置。1.1 新建一个关于广告页的数据模型。实现start页的页面结构及倒计时逻辑。2. window窗口广告模式。
STM32F103ZET6开发板上成功移植ARM-2D图形库
对于ARM开发，常见的IDE包括Keil MDK、IAR Embedded Workbench、STM32CubeIDE等。不同版本的IDE可能对代码的编译和优化有所差异，因此需要确保使用的IDE版本与库和硬件兼容。 8. 文件名称： 提供的文件名称为"arm_...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值