PFCG 根角色分配给复合角色 - PRGN_RFC_ADD_AGRS_TO_COLL_AGR / PRGN_RFC_DEL_AGRS_IN_COLL_AGR

最新推荐文章于 2024-05-31 10:46:10 发布
最新推荐文章于 2024-05-31 10:46:10 发布
阅读量87 收藏
点赞数
分类专栏： BAPI 文章标签： java
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_42135249/article/details/131449219
版权

目录

一、程序源代码

二、数据模版

 

一、程序源代码

*&---------------------------------------------------------------------*
*& Report  ZFIU025
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT ZFIU028.

TABLES: SSCRFIELDS.
SELECTION-SCREEN FUNCTION KEY 1.

TYPES: BEGIN OF TYP_UPLOAD,
         AGR_NAME TYPE STR_AGRS-AGR_NAME,"复合角色
         AGR_NAME_SON TYPE STR_AGRS-AGR_NAME,"根角色
         ZSEL TYPE CHAR1,
         ICON TYPE ICON-NAME,
         ZTYPE TYPE C,
         ZMESSAGE TYPE CHAR255,
       END OF TYP_UPLOAD.

DATA: WA_UPLOAD TYPE TYP_UPLOAD,
      IT_UPLOAD LIKE STANDARD TABLE OF WA_UPLOAD.


DATA: L_AGR_NAME TYPE STR_AGRS-AGR_NAME.

DATA: L_CHECK TYPE C.
DATA: G_DO TYPE C.

DATA: IS_LAYOUT TYPE SLIS_LAYOUT_ALV,          "ALV输出样式
      IT_FIELDCAT TYPE SLIS_T_FIELDCAT_ALV,    "ALV输出的头项目(内表)
      WA_FIELDCAT TYPE SLIS_FIELDCAT_ALV,      "ALV输出的头项目(工作区)
      WA_REPID LIKE SY-REPID."程序名



PARAMETERS: P_FILE TYPE RLGRAP-FILENAME.

PARAMETERS: R1 RADIOBUTTON GROUP G1 DEFAULT 'X',
            R2 RADIOBUTTON GROUP G1.



INITIALIZATION.
  PERFORM FRM_INIT.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_FILE.
  PERFORM FRM_FILE_F4.

AT SELECTION-SCREEN.
  CASE SY-UCOMM.
    WHEN 'FC01'.
      PERFORM FRM_DOWNLOAD_TEM_XLS.
  ENDCASE.


START-OF-SELECTION.
  PERFORM FRM_GET_DATA.

END-OF-SELECTION.
  PERFORM FRM_SHOW_DATA.


*&---------------------------------------------------------------------*
*&      Form  FRM_INIT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_INIT .
  SSCRFIELDS-FUNCTXT_01 = '下载上载模板'.
ENDFORM.                    " FRM_INIT
*&---------------------------------------------------------------------*
*&      Form  FRM_FILE_F4
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_FILE_F4 .
  CALL FUNCTION 'WS_FILENAME_GET'
    EXPORTING
      MASK             = ' Excel(*.xls)|*.xls|Excel(*.xlsx)|*.xlsx|全部文件 (*.*)|*.*|'
      TITLE            = '选择文件'
    IMPORTING
      FILENAME         = P_FILE
    EXCEPTIONS
      INV_WINSYS       = 1
      NO_BATCH         = 2
      SELECTION_CANCEL = 3
      SELECTION_ERROR  = 4
      OTHERS           = 5.
  IF SY-SUBRC <> 0 AND SY-SUBRC <> 3.
    MESSAGE E015(ZMM) WITH '选择文件出错！'.
  ENDIF.
ENDFORM.                    " FRM_FILE_F4
*&---------------------------------------------------------------------*
*&      Form  FRM_DOWNLOAD_TEM_XLS
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_DOWNLOAD_TEM_XLS .
  DATA: FILENAME TYPE STRING VALUE 'ZFIU028.xls',
        PATH TYPE STRING VALUE 'C:\',
        FULLPATH TYPE STRING VALUE 'C:\ZFIU028.xls'.

  CALL METHOD CL_GUI_FRONTEND_SERVICES=>FILE_SAVE_DIALOG
    EXPORTING
*     WINDOW_TITLE         =
*     DEFAULT_EXTENSION    =
      DEFAULT_FILE_NAME    = FILENAME
*     WITH_ENCODING        =
      FILE_FILTER          = 'Excel(*.xls)|*.xls|Excel(*.xlsx)|*.xlsx|全部文件 (*.*)|*.*|'
      INITIAL_DIRECTORY    = PATH
*     PROMPT_ON_OVERWRITE  = 'X'
    CHANGING
      FILENAME             = FILENAME
      PATH                 = PATH
      FULLPATH             = FULLPATH
*     USER_ACTION          =
*     FILE_ENCODING        =
    EXCEPTIONS
      CNTL_ERROR           = 1
      ERROR_NO_GUI         = 2
      NOT_SUPPORTED_BY_GUI = 3
      OTHERS               = 4.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ELSE.
    IF FULLPATH IS INITIAL.

    ELSE.
      PERFORM DOWNLOAD_EXCEL_FROMSERVER USING FULLPATH.
      P_FILE = FULLPATH.
      "MESSAGE '模板导出成功' TYPE 'S'.
    ENDIF.
  ENDIF.
ENDFORM.                    " FRM_DOWNLOAD_TEM_XLS
*&---------------------------------------------------------------------*
*&      Form  DOWNLOAD_EXCEL_FROMSERVER
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_FULLPATH  text
*----------------------------------------------------------------------*
FORM DOWNLOAD_EXCEL_FROMSERVER  USING P_DEST.
  DATA: LO_OBJDATA LIKE WWWDATATAB,
        LS_DESTINATION LIKE RLGRAP-FILENAME.
  LS_DESTINATION = P_DEST.
  LO_OBJDATA-RELID = 'MI'.
  LO_OBJDATA-OBJID = 'ZFIU028'.
  CALL FUNCTION 'DOWNLOAD_WEB_OBJECT'
    EXPORTING
      KEY               = LO_OBJDATA
      DESTINATION       = LS_DESTINATION
*   IMPORTING
*     RC                =
*   CHANGING
*     TEMP              =
            .
ENDFORM.                    " DOWNLOAD_EXCEL_FROMSERVER
*&---------------------------------------------------------------------*
*&      Form  FRM_GET_DATA
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_GET_DATA .
  PERFORM FRM_UPLOAD_FILE_XLS.
  PERFORM FRM_CHECK_DATA.
ENDFORM.                    " FRM_GET_DATA
*&---------------------------------------------------------------------*
*&      Form  FRM_UPLOAD_FILE_XLS
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_UPLOAD_FILE_XLS .
  DATA: IT_RAW  TYPE TRUXS_T_TEXT_DATA.

  CALL FUNCTION 'TEXT_CONVERT_XLS_TO_SAP'
    EXPORTING
*     I_FIELD_SEPERATOR    =
      I_LINE_HEADER        = 'X'
      I_TAB_RAW_DATA       = IT_RAW       " WORK TABLE
      I_FILENAME           = P_FILE
    TABLES
      I_TAB_CONVERTED_DATA = IT_UPLOAD  "ACTUAL DATA
    EXCEPTIONS
      CONVERSION_FAILED    = 1
      OTHERS               = 2.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

  IF IT_UPLOAD IS INITIAL.
    MESSAGE '上载文档空请检查' TYPE 'S' DISPLAY LIKE 'E'.
    LEAVE LIST-PROCESSING.
  ELSE.
*************设置标识的初始状态
    LOOP AT IT_UPLOAD INTO WA_UPLOAD.
      WA_UPLOAD-ICON = ICON_YELLOW_LIGHT.
      WA_UPLOAD-ZMESSAGE = ''.
      MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZMESSAGE.
    ENDLOOP.
  ENDIF.
ENDFORM.                    " FRM_UPLOAD_FILE_XLS
*&---------------------------------------------------------------------*
*&      Form  FRM_CHECK_DATA
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_CHECK_DATA .
  L_CHECK = 'S'.
  LOOP AT IT_UPLOAD INTO WA_UPLOAD.
    SELECT SINGLE AGR_NAME
      FROM AGR_DEFINE
      INTO L_AGR_NAME
     WHERE AGR_NAME EQ WA_UPLOAD-AGR_NAME.
    IF SY-SUBRC <> 0.
      L_CHECK = 'E'.
      WA_UPLOAD-ICON = ICON_RED_LIGHT.
      WA_UPLOAD-ZTYPE = 'E'.
      WA_UPLOAD-ZMESSAGE = '复合角色不存在'.
      MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.
      CONTINUE.
    ENDIF.

    SELECT SINGLE AGR_NAME
      FROM AGR_DEFINE
      INTO L_AGR_NAME
     WHERE AGR_NAME EQ WA_UPLOAD-AGR_NAME_SON.
    IF SY-SUBRC <> 0.
      L_CHECK = 'E'.
      WA_UPLOAD-ICON = ICON_RED_LIGHT.
      WA_UPLOAD-ZTYPE = 'E'.
      WA_UPLOAD-ZMESSAGE = '根角色不存在'.
      MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.
      CONTINUE.
    ENDIF.

    IF R1 = 'X'.
      SELECT SINGLE AGR_NAME
        FROM AGR_AGRS
        INTO L_AGR_NAME
       WHERE AGR_NAME EQ WA_UPLOAD-AGR_NAME
         AND CHILD_AGR EQ WA_UPLOAD-AGR_NAME_SON.
      IF SY-SUBRC = 0.
        L_CHECK = 'E'.
        WA_UPLOAD-ICON = ICON_RED_LIGHT.
        WA_UPLOAD-ZTYPE = 'E'.
        WA_UPLOAD-ZMESSAGE = '根角色已分配该复合角色'.
        MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.
        CONTINUE.
      ENDIF.
    ENDIF.

    IF R2 = 'X'.
      SELECT SINGLE AGR_NAME
        FROM AGR_AGRS
        INTO L_AGR_NAME
       WHERE AGR_NAME EQ WA_UPLOAD-AGR_NAME
         AND CHILD_AGR EQ WA_UPLOAD-AGR_NAME_SON.
      IF SY-SUBRC <> 0.
        L_CHECK = 'E'.
        WA_UPLOAD-ICON = ICON_RED_LIGHT.
        WA_UPLOAD-ZTYPE = 'E'.
        WA_UPLOAD-ZMESSAGE = '根角色未分配该复合角色'.
        MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.
        CONTINUE.
      ENDIF.
    ENDIF.


    WA_UPLOAD-ICON = ICON_YELLOW_LIGHT.
    WA_UPLOAD-ZTYPE = 'W'.
    WA_UPLOAD-ZMESSAGE = '检查通过'.
    MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.

  ENDLOOP.
ENDFORM.                    " FRM_CHECK_DATA
*&---------------------------------------------------------------------*
*&      Form  FRM_SHOW_DATA
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_SHOW_DATA .
  WA_REPID = SY-REPID.                     "得到程序名
  IS_LAYOUT-ZEBRA = 'X'.                   "颜色相间显示
  IS_LAYOUT-COLWIDTH_OPTIMIZE = 'X'.       "优化列宽选项
  IS_LAYOUT-BOX_FIELDNAME = 'ZSEL'.       "优化列宽选项

  DATA: DE_POS TYPE I.

  DE_POS = DE_POS + 1.
  CLEAR WA_FIELDCAT.
  WA_FIELDCAT-COL_POS       = DE_POS.
*  WA_FIELDCAT-KEY           = 'X'.
  WA_FIELDCAT-FIELDNAME     = 'ICON'.
  WA_FIELDCAT-ICON          = 'X'.
  WA_FIELDCAT-SELTEXT_L     = ''.
  WA_FIELDCAT-SELTEXT_M     = ''.
  WA_FIELDCAT-SELTEXT_S     = ''.
  WA_FIELDCAT-DDICTXT       = 'L'.
  APPEND WA_FIELDCAT TO IT_FIELDCAT.

  DE_POS = DE_POS + 1.
  CLEAR WA_FIELDCAT.
  WA_FIELDCAT-COL_POS       = DE_POS.
*  WA_FIELDCAT-KEY           = 'X'.
  WA_FIELDCAT-FIELDNAME     = 'AGR_NAME'.
  WA_FIELDCAT-REF_TABNAME   = 'STR_AGRS'.
  WA_FIELDCAT-REF_FIELDNAME = 'AGR_NAME'.
  WA_FIELDCAT-SELTEXT_L     = '复合角色'.
  WA_FIELDCAT-SELTEXT_M     = '复合角色'.
  WA_FIELDCAT-SELTEXT_S     = '复合角色'.
  WA_FIELDCAT-DDICTXT       = 'L'.
  APPEND WA_FIELDCAT TO IT_FIELDCAT.

  DE_POS = DE_POS + 1.
  CLEAR WA_FIELDCAT.
  WA_FIELDCAT-COL_POS       = DE_POS.
*  WA_FIELDCAT-KEY           = 'X'.
  WA_FIELDCAT-FIELDNAME     = 'AGR_NAME_SON'.
  WA_FIELDCAT-REF_TABNAME   = 'STR_AGRS'.
  WA_FIELDCAT-REF_FIELDNAME = 'AGR_NAME'.
  WA_FIELDCAT-SELTEXT_L     = '根角色'.
  WA_FIELDCAT-SELTEXT_M     = '根角色'.
  WA_FIELDCAT-SELTEXT_S     = '根角色'.
  WA_FIELDCAT-DDICTXT       = 'L'.
  APPEND WA_FIELDCAT TO IT_FIELDCAT.

  DE_POS = DE_POS + 1.
  CLEAR WA_FIELDCAT.
  WA_FIELDCAT-COL_POS       = DE_POS.
*  WA_FIELDCAT-KEY           = 'X'.
  WA_FIELDCAT-FIELDNAME     = 'ZMESSAGE'.
  WA_FIELDCAT-SELTEXT_L     = '消息'.
  WA_FIELDCAT-SELTEXT_M     = '消息'.
  WA_FIELDCAT-SELTEXT_S     = '消息'.
  WA_FIELDCAT-DDICTXT       = 'L'.
  APPEND WA_FIELDCAT TO IT_FIELDCAT.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
*     I_INTERFACE_CHECK                 = ' '
*     I_BYPASSING_BUFFER                = ' '
*     I_BUFFER_ACTIVE                   = ' '
      I_CALLBACK_PROGRAM                = WA_REPID
      I_CALLBACK_PF_STATUS_SET          = 'SET_STATUS'
      I_CALLBACK_USER_COMMAND           = 'USER_COMMAND'
*     I_CALLBACK_TOP_OF_PAGE            = ' '
*     I_CALLBACK_HTML_TOP_OF_PAGE       = ' '
*     I_CALLBACK_HTML_END_OF_LIST       = ' '
*     I_STRUCTURE_NAME                  =
*     I_BACKGROUND_ID                   = ' '
*     I_GRID_TITLE                      =
*     I_GRID_SETTINGS                   =
      IS_LAYOUT                         = IS_LAYOUT
      IT_FIELDCAT                       = IT_FIELDCAT
*     IT_EXCLUDING                      =
*     IT_SPECIAL_GROUPS                 =
*     IT_SORT                           =
*     IT_FILTER                         =
*     IS_SEL_HIDE                       =
*     I_DEFAULT                         = 'X'
      I_SAVE                            = 'A'
*     IS_VARIANT                        =
*     IT_EVENTS                         =
*     IT_EVENT_EXIT                     =
*     IS_PRINT                          =
*     IS_REPREP_ID                      =
*     I_SCREEN_START_COLUMN             = 0
*     I_SCREEN_START_LINE               = 0
*     I_SCREEN_END_COLUMN               = 0
*     I_SCREEN_END_LINE                 = 0
*     I_HTML_HEIGHT_TOP                 = 0
*     I_HTML_HEIGHT_END                 = 0
*     IT_ALV_GRAPHICS                   =
*     IT_HYPERLINK                      =
*     IT_ADD_FIELDCAT                   =
*     IT_EXCEPT_QINFO                   =
*     IR_SALV_FULLSCREEN_ADAPTER        =
*   IMPORTING
*     E_EXIT_CAUSED_BY_CALLER           =
*     ES_EXIT_CAUSED_BY_USER            =
    TABLES
      T_OUTTAB                          = IT_UPLOAD
    EXCEPTIONS
      PROGRAM_ERROR                     = 1
      OTHERS                            = 2.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " FRM_SHOW_DATA

*&---------------------------------------------------------------------*
*&      FORM  SET_STATUS
*&---------------------------------------------------------------------*
*       TEXT
*----------------------------------------------------------------------*
*      -->RT_EXTAB   TEXT
*----------------------------------------------------------------------*
FORM SET_STATUS USING RT_EXTAB TYPE SLIS_T_EXTAB.
  SET PF-STATUS 'ZFIU025' EXCLUDING RT_EXTAB.
ENDFORM.                    "SET_STATUS


*&---------------------------------------------------------------------*
*&      FORM  USER_COMMAND
*&---------------------------------------------------------------------*
*       TEXT
*----------------------------------------------------------------------*
*      -->RF_UCOMM     TEXT
*      -->RS_SELFIELD  TEXT
*----------------------------------------------------------------------*
FORM USER_COMMAND USING RF_UCOMM LIKE SY-UCOMM
                        RS_SELFIELD TYPE SLIS_SELFIELD.
  CASE RF_UCOMM.
    WHEN 'ZDO'.
      IF L_CHECK = 'E'.
        MESSAGE '上载数据有错，不能保存' TYPE 'E'.
      ENDIF.
      IF G_DO = 'X'.
        MESSAGE '修改操作已执行' TYPE 'E'.
      ENDIF.
      G_DO = 'X'.
      PERFORM FRM_GO..
  ENDCASE.
*如果前面把内表的数据修改了,通过这个就会自到更新数据
  RS_SELFIELD-REFRESH = 'X'.
ENDFORM.                    "USER_COMMAND
*&---------------------------------------------------------------------*
*&      Form  FRM_GO
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM FRM_GO .
  DATA: L_ZTYPE TYPE C.
  DATA: L_ZMESSAGE TYPE CHAR255.
  DATA: AGR_ROLENAME TYPE AGR_DEFINE-AGR_NAME." 角色

  DATA: WA_ROLESON TYPE AGR_TXT,
        IT_ROLESON LIKE STANDARD TABLE OF WA_ROLESON.

  DATA: WA_RETURN TYPE BAPIRET2,
        IT_RETURN LIKE STANDARD TABLE OF WA_RETURN.


  LOOP AT IT_UPLOAD INTO WA_UPLOAD.
    CLEAR: L_ZTYPE,
           L_ZMESSAGE.
    CLEAR: WA_ROLESON,
           IT_ROLESON,
           IT_RETURN,
           WA_RETURN.
    AGR_ROLENAME = WA_UPLOAD-AGR_NAME.
    WA_ROLESON-AGR_NAME = WA_UPLOAD-AGR_NAME_SON.
    SELECT SINGLE TEXT
      FROM AGR_TEXTS
      INTO WA_ROLESON-TEXT
     WHERE AGR_NAME EQ WA_UPLOAD-AGR_NAME_SON.
    APPEND WA_ROLESON TO IT_ROLESON.

    IF R1 = 'X'.
      CALL FUNCTION 'PRGN_RFC_ADD_AGRS_TO_COLL_AGR'
        EXPORTING
          ACTIVITY_GROUP                = AGR_ROLENAME
*         CHECK_NAMESPACE               = 'X'
*         ENQUEUE                       = 'X'
*         PROFILE_COMPARISON            = 'X'
        TABLES
          ACTIVITY_GROUPS               = IT_ROLESON
          RETURN                        = IT_RETURN
        EXCEPTIONS
          ACTIVITY_GROUP_DOES_NOT_EXIST = 1
          NO_COLLECTIVE_ACTIVITY_GROUP  = 2
          ACTIVITY_GROUP_ENQUEUED       = 3
          NAMESPACE_PROBLEM             = 4
          NOT_AUTHORIZED                = 5
          AUTHORITY_INCOMPLETE          = 6
          OTHERS                        = 7.
      IF SY-SUBRC <> 0.
        L_ZTYPE = 'E'.
        MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                 WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4
                 INTO L_ZMESSAGE.
        CONCATENATE '失败:'
                    L_ZMESSAGE
                    INTO
                    L_ZMESSAGE.
        ROLLBACK WORK.
      ELSE.
        LOOP AT IT_RETURN INTO WA_RETURN WHERE TYPE = 'E'
                                            OR TYPE = 'A'.
        ENDLOOP.
        IF SY-SUBRC = 0.
          CONCATENATE '失败:'
                      WA_RETURN-MESSAGE
                      INTO
                      L_ZMESSAGE.
          ROLLBACK WORK.
        ELSE.
          L_ZTYPE = 'S'.
          L_ZMESSAGE = '成功'.
          COMMIT WORK AND WAIT.
        ENDIF.
      ENDIF.
    ENDIF.

    IF R2 = 'X'.
      CALL FUNCTION 'PRGN_RFC_DEL_AGRS_IN_COLL_AGR'
        EXPORTING
          ACTIVITY_GROUP                = AGR_ROLENAME
*         CHECK_NAMESPACE               = 'X'
*         ENQUEUE                       = 'X'
*         PROFILE_COMPARISON            = 'X'
        TABLES
          ACTIVITY_GROUPS               = IT_ROLESON
          RETURN                        = IT_RETURN
        EXCEPTIONS
          ACTIVITY_GROUP_DOES_NOT_EXIST = 1
          NO_COLLECTIVE_ACTIVITY_GROUP  = 2
          ACTIVITY_GROUP_ENQUEUED       = 3
          NAMESPACE_PROBLEM             = 4
          NOT_AUTHORIZED                = 5
          AUTHORITY_INCOMPLETE          = 6
          OTHERS                        = 7.
      IF SY-SUBRC <> 0.
        L_ZTYPE = 'E'.
        MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                 WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4
                 INTO L_ZMESSAGE.
        CONCATENATE '失败:'
                    L_ZMESSAGE
                    INTO
                    L_ZMESSAGE.
        ROLLBACK WORK.
      ELSE.
        LOOP AT IT_RETURN INTO WA_RETURN WHERE TYPE = 'E'
                                            OR TYPE = 'A'.
        ENDLOOP.
        IF SY-SUBRC = 0.
          CONCATENATE '失败:'
                      WA_RETURN-MESSAGE
                      INTO
                      L_ZMESSAGE.
          ROLLBACK WORK.
        ELSE.
          L_ZTYPE = 'S'.
          L_ZMESSAGE = '成功'.
          COMMIT WORK AND WAIT.
        ENDIF.
      ENDIF.
    ENDIF.

    CASE L_ZTYPE.
      WHEN 'S'.
        WA_UPLOAD-ICON = ICON_GREEN_LIGHT.
      WHEN 'E'.
        WA_UPLOAD-ICON = ICON_RED_LIGHT.
    ENDCASE.
    WA_UPLOAD-ZTYPE = L_ZTYPE.
    WA_UPLOAD-ZMESSAGE = L_ZMESSAGE.
    MODIFY IT_UPLOAD FROM WA_UPLOAD TRANSPORTING ICON ZTYPE ZMESSAGE.
  ENDLOOP.
ENDFORM.                    " FRM_GO

二、数据模版

复合角色根角色
ZFH_TEST_002ZTEST_002
ZFH_TEST_002ZTEST_001

陈送平er
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
sap_权限的设定PFCG等
10-12
在開始了解權限前,有几點是要大家注意的 1.權限設定非常重要﹐而且權限的DEBUG操作非常繁瑣,耗時,所以請大家設定時一定要非常謹慎,每次更改都要記錄。 2.權限設定除非特殊情況﹐不允許在正式環境直接更改﹐請在測試...
SAP角色权限设置与管理
11-07
主要包括角色的创建，代码PFCG，分为单一角色和复合角色，可以通过复制类似功能的角色快速创建一个新的角色，然后修改需要的权限。角色创建之后通过添加或删除包含的事务代码来修改权限，然后生成配置文件，注意生成...
PFCG--复合角色创建
MRwugang的博客
05-23 623
复合角色增加权限步骤分享 复合角色，顾名思义即从属角色权限的集合体 PS:走过路过留下你的????????，不足之处敬请留言，共学习同进步 输入信息及他的小兵： 导入菜单信息： 输入用户名比较即可： ...
PFCG 根角色创建/删除 - PRGN_RFC_CREATE_AGR_MULTIPLE / PRGN_ACTIVITY_GROUP_DELETE
陈送平的博客
06-29 143
PFCG 根角色创建/删除 - PRGN_RFC_CREATE_AGR_MULTIPLE / PRGN_ACTIVITY_GROUP_DELETE
PFCG 角色TCODE分配 - PRGN_RFC_ADD_TRANSACTION / PRGN_RFC_DELETE_TRANSACTION
陈送平的博客
06-29 89
PFCG 角色TCODE分配 - PRGN_RFC_ADD_TRANSACTION
PFCG 角色分配用户 - PRGN_RFC_CHANGE_USERS_IN_AGRS
陈送平的博客
06-29 75
PFCG 角色分配用户 - PRGN_RFC_CHANGE_USERS_IN_AGRS
PFCG 复合角色创建/删除 - PRGN_RFC_CREATE_AGR_MULTIPLE / PRGN_ACTIVITY_GROUP_DELETE
陈送平的博客
06-29 94
AAAAZTEST_001复合角色描述。
PFCG 创建根角色/分配TCODE/生成权限参数文件 - PRGN_RFC_CREATE_ACTIVITY_GROUP
陈送平的博客
06-29 305
PFCG 创建根角色/分配TCODE/生成权限参数文件 - PRGN_RFC_CREATE_ACTIVITY_GROUP
PFCG 激活权限参数文件 - PRGN_AUTO_GENERATE_PROFILE_NEW
陈送平的博客
06-29 84
PFCG 激活权限参数文件 - PRGN_AUTO_GENERATE_PROFILE_NEW
sap 用户权限表_SAP权限管理有关数据表-权限角色用户
weixin_32085599的博客
01-13 1221
表名描述AGR_1016活动组参数文件名称AGR_1016B活动组参数文件名称AGR_1250活动组的权限数据AGR_1251活动组的权限数据AGR_1252权限的组织元素AGR_1253作业组的权限数据 - 静态对象AGR_AGRS组合角色中的角AGR_AGRS2作用定义AGR_ATTS角色属性AGR_BUFFI角色的 InterneAGR_BUFFI2Internet 链接AGR_BUFFI3...
abap 给用户分配事物代码权限_如何检查某用户是否分配了某ABAP权限对象
weixin_29219539的博客
02-06 105
For example, I would like to check whether my user has enough authorization defined by authorization object s_carrid with value actvt = 03.In tcode SU01, I can only see PFCG roles assigned to my user....
PFCG批量添加T-code利用Import from file(1)
07-27
以下将阐述如何通过PFCG批量插入"事务码";In the role maintenance transaction PFCG, on the Menu tab page there is a function Import from file.(W)hat's the purpose of the function? (W)hich file format is ...
PFCG批量添加T-CODE利用Import form file(3)
07-27
以下将阐述如何通过PFCG批量插入"事务码";In the role maintenance transaction PFCG, on the Menu tab page there is a function Import from file.(W)hat's the purpose of the function? (W)hich file format is ...
PFCG批量添加T-CODE利用Import form file(2)
07-27
以下将阐述如何通过PFCG批量插入"事务码";In the role maintenance transaction PFCG, on the Menu tab page there is a function Import from file.(W)hat's the purpose of the function? (W)hich file format is ...
operator ＜=＞ (spaceship operator)
janeqi1987的专栏
05-28 991
= 与!= 操作符为了检查是否相等，现在定义== 操作符就够了。当编译器找不到表达式的匹配声明a!=b 时，编译器会重写表达式并查找!(a==b)。若这不起作用，编译器也会尝试改变操作数的顺序，所以也会尝试!(b==a):a!=b,!(b==a)因此，对于TypeA 的a 和TypeB 的b，编译器将能够识别并编译a!= b若需要的话，可以这样做• 一个独立函数operator!• 一个独立函数operator==(TypeA, TypeB)
Java 异常处理中try-catch块、finally子句以及自定义异常的使用
最新发布
Itmastergo的博客
05-31 786
异常是程序运行过程中出现的非正常情况。Java 使用异常类（Exception 类及其子类）来表示这些异常情况。异常处理的核心思想是将正常的程序流程与异常处理流程分离开来，使代码更加清晰和可维护。Throwable 类：所有异常和错误的基类。Error 类：表示系统级的错误，程序通常无法处理，比如内存不足（OutOfMemoryError）。Exception 类：表示程序中可以处理的异常情况。RuntimeException 类。
Java手动启动jar包
liangweihao的博客
05-29 288
【代码】Java手动启动jar包。
java调用cmd执行命令
weixin_45210565的博客
05-28 257
3、exec(String command, String[] envp) ，在调用外部程序之前设置系统环境变量，该变量仅供command入参使用，envp每个元素为一个系统环境变量，并且字符串格式为“环境变量名=环境变量值”。2、exec(String[] cmdArray) ，调用外部程序，入参cmdArray的元素将组合成为一条完整的外部可执行程序的启动路径或命令。1、exec(String command) ，调用外部程序，入参command为外部可执行程序的启动路径或命令。
SAP PFCG角色参数文件合并
12-15
根据提供的引用内容，SAP PFCG角色参数文件合并是指将两个或多个角色的参数文件合并为一个文件。具体步骤如下： 1. 打开PFCG事务代码。 2. 选择要合并的角色。 3. 在“角色”菜单下选择“更改”。 4. 在“更改角色”屏幕上，选择“菜单”选项卡。 5. 选择要合并的角色的菜单。 6. 在“菜单”菜单下选择“导出”。 7. 将导出的文件保存到本地计算机上。 8. 重复步骤2-7，导出另一个角色的菜单。 9. 打开两个导出的文件，并将它们合并为一个文件。 10. 在“更改角色”屏幕上，选择“菜单”选项卡。 11. 选择“导入”。 12. 选择合并的文件。 13. 单击“打开”。 14. 保存角色。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

陈送平er

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值