halcon 历程注解 check_hazelnut_wafers.hdev

* 此示例演示了榛子饼干的质量检查。
* 利用形态学工具，根据一些形状特征，如矩形和区域孔，提取和检查波动。
* 该程序还显示了操作符area_holes的使用。

* This example demonstrates a quality inspection on hazelnut wavers.
* Using the morphology tools the waver is extracted and examined according to a few shape features like Rectangularity and AreaHoles.
* This program also shows the use of the operator area_holes.
* 
* 此示例演示了榛子饼干的质量检查。
* 利用形态学工具，根据一些形状特征，如矩形和区域孔，提取和检查波动。
* 该程序还显示了操作符area_holes的使用。
read_image (Image, 'food/hazelnut_wafer_01')
dev_close_window ()
dev_open_window_fit_image (Image, 0, 0, -1, -1, WindowHandle)
dev_update_window ('off')
dev_set_line_width (3)
dev_set_draw ('margin')
set_display_font (WindowHandle, 20, 'mono', 'true', 'false')
* 
for Index := 1 to 24 by 1
    read_image (Image, 'food/hazelnut_wafer_' + Index$'.02')
    * 使用二值阈值分割图像
    * ’max_separability’：最大限度的可分性, ‘smooth_histo’：直方图平滑。
    * 这两种方法只能用于具有双峰直方图的图像。
    * Method= ’ max_separability '，根据“灰度直方图的阈值选择方法”的灰度直方图自动阈值调用。该算法首先计算图像的直方图，然后利用统计矩找到将像素分割为前景和背景的最优阈值，并最大化这两个类之间的可分性。此方法仅适用于byte和uint2图像。
    binary_threshold (Image, Foreground, 'smooth_histo', 'light', UsedThreshold)
    opening_circle (Foreground, FinalRegion, 8.5)
    * 计算区域的孔洞面积
    * 得到饼干区域破损的面积
    area_holes (FinalRegion, AreaHoles)
    * 矩形度
    rectangularity (FinalRegion, Rectangularity)
    dev_display (Image)
    if (AreaHoles > 300 or Rectangularity < 0.92)
        dev_set_color ('red')
        Text := 'Not OK'
    else
        dev_set_color ('forest green')
        Text := 'OK'
    endif
    dev_display (FinalRegion)
    disp_message (WindowHandle, Text, 'window', -1, -1, '', 'false')
    if (Index < 24)
        disp_continue_message (WindowHandle, 'black', 'true')
        stop ()
    endif
endfor