MDK自动生成带校验带SVN版本号的升级文件

MDK自动生成带校验带SVN版本号的升级文件

获取SVN版本信息

• 确保SVN安装了命令行工具，默认安装时不会安装命令行工具
  
• 编写一个模板头文件 svn_version.temp.h, 版本号格式为 1_0_0_SVN版本号

#ifndef __SVN_VERSION_H
#define __SVN_VERSION_H


#define SVN_REVISION_NUM  100$WCREV$    
#define SVN_REVISION_STR  "$WCREV$" 
#define SVN_COMMIT_TIME   "$WCDATE$"
#define SVN_NOW_TIME      "$WCNOW$"

#endif

• 编写get_svn_version.bat 脚本，利用模板头文件生成带版本号的头文件

::获取本地版本
::for /f "tokens=5" %%i in ('SubWCRev  ../^|find "Last committed at revision"') do set version=%%i
::set SVN_CUR_VER=%version%

::获取服务器版本
::set svnURL="SVN服务器URL"
::for /f "delims=" %%i in ('svn info %svnURL% ^| findstr "Rev:"') do set rev=%%i
::set SVN_MAX_VER=%rev:~18%

::echo version:%SVN_CUR_VER%    version:%SVN_MAX_VER%  

subwcrev.exe ../ "svn_version.temp.h" "svn_version.h"

• MDK 编译器执行该脚本
  
• 将版本号添加到app的中断向量表中（或者自己添加到固定位置），方便boot查找版本号

#include "svn_version.h"
/* SVN版本号 */
const uint32_t g_ulSVNVersion = SVN_REVISION_NUM;

extern int Image$$ER_IROM1$$Base;
#define SVN_VERSION_ADDR     (&Image$$ER_IROM1$$Base + 7)
uint32_t GetVersion(void)
{
    return *((uint32_t*)*((uint32_t*)SVN_VERSION_ADDR));
}

注意填入中断向量表的是存放版本号的地址，需要用指针来转化成版本号。

在bin文件末尾添加CRC校验

• 编写脚本文件，生成带版本号名字的app。

@rem 显示RAM FLASH使用情况
Keil5_disp_size_bar_v0.4.exe  


echo off
@rem 原始bin文件路径
set file_path=Objects

@rem 原始bin文件名
set file_name=name.hex

@rem 转换为bin文件的前缀
set file_prefix=app

copy %file_path%\%file_name% .\app.hex

@rem 转换为bin文件

for /f "tokens=1,2 delims=:" %%a in ('hex2bin app.hex') do (
	if /i "%%a"=="Lowest address" (    
        set "StartAddrs=%%b"    
    )
	if /i "%%a"=="Max Length" (    
        set "Length=%%b"    
    )
)

@rem 获取bin文件大小 和起始地址 
set "addr=0x%StartAddrs: =%"
set "indexdx=%Length: =%"

ECHO app length is: %indexdx%


@rem 获取版本号 
set "file=svn_version.h"    
    
for /f "tokens=2,3 delims= " %%a in ('type "%file%"') do (    
    if /i "%%a"=="SVN_REVISION_NUM" (    
        set "revision=%%b"    
    )
)     

@rem 将版本号拆分成 V1_0_0_xx 的形式
set "result=%revision:~0,1%_%revision:~1,1%_%revision:~2,1%_%revision:~3%" 
echo version is: %result% 
set "revision=%result%"    


@rem 获取设备型号
set "file=svn_version.h"    
    
for /f "tokens=2,3 delims= " %%a in ('type "%file%"') do (    
    if /i "%%a"=="PRODUCT_MODEL" (    
        set "product=%%b"    
    )
)    
    


@rem 生成带版本号的升级文件 
srec_cat.exe app.bin -Binary -crop 0 %indexdx% -STM32_Little_Endian %indexdx% -o %file_prefix%_%product%_v%revision%.bin -Binary
echo create %file_prefix%_%product%_v%revision%.bin

echo app startAddr is: %addr%

@rem 生成带CRC校验的hex文件 替换在MDK中下载的hex
srec_cat.exe %file_prefix%_%product%_v%revision%.bin -Binary -offset %addr% -o app_crc.hex -Intel -Output_Block_Size=16
copy .\app_crc.hex  %file_path%\%file_prefix%_%product%_V%revision%.hex 
echo create %file_path%\%file_prefix%_%product%_V%revision%.hex 

del %file_path%\%file_name%
copy .\app_crc.hex  %file_path%\%file_name%

del app.hex 
del app.bin
del app_crc.hex 

echo create app is ok

在boot中获取版本信息和校验升级文件

uint32_t CheckApp(void)
{
    uint32_t* addr = (uint32_t *)APP_END_ADDR;
    /* 从flash尾部向前扫描，找到CRC位置 */
    while(*addr == 0xffffffff)
    {
        addr--;
        if((uint32_t)addr <= APP_START_ADDR)
        {
            return 0;
        }
    }
    
    /* 校验固件 */
    MX_CRC_Init();
    uint32_t crc = HAL_CRC_Calculate(&hcrc, (uint32_t*)APP_START_ADDR, ((uint32_t)addr - APP_START_ADDR)/4);
    
    if(*addr == crc)
    {
        return 1;
    }
    return 0;
}

用到的小软件 https://download.csdn.net/download/weixin_42378319/88414367