SQL Server中的STRING_SPLIT函数的实现

概要

SQL Server在2016版本中支持了STRING_SPLIT方法，可以将字符串按照分隔符，切割成一个数据表，使用非常方便。但是SQL Server 2016之前的版本没有这个方法。本文通过SQL Server的自定义方法实现该方法。

源码和实现

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[fn_Split]
(@input nvarchar(max), @separater char(1))
RETURNS 
 @result TABLE (
	value nvarchar(max) not null 
)
AS
BEGIN
	declare @tmp nvarchar (max)
	declare @EndIndex int
	SET @input = @input + @separater
	WHILE LEN(@input) > 0
	BEGIN
		SET @EndIndex = CHARINDEX(@separater, @input)
		SET @tmp =  SUBSTRING(@input, 1, @EndIndex - 1);
		IF LEN(@tmp) > 0
			INSERT INTO @result SELECT  @tmp		
		SET @input = SUBSTRING(@input, @EndIndex+1, LEN(@input)- @EndIndex)
	END
	RETURN 
END
GO

1. 方法接收两个参数，第一个是要被分割的字符串，另一个是分隔符，分隔符只有1位；
2. 方法返回一个表值变量，该变量只有一列value；
3. 为了字符串处理方便，将分隔符附加到要分割字符串的尾部；
4. 在要分割的的字符串内找到第一个分隔符的位置，将分割符之前的内容插入表变量中，将该分隔符和分隔符前的字符串从要分割的字符串中删除，直至要分割的字符串为空为止；
5. 返回表变量。

方法调用

该方法返回的是表值函数，所以需要放到from子句后面

 select * from dbo.fn_Split('a,b,c',',')

本方法会忽略空值的情况，下面的字符串只会返回a b c三条数据。

 select * from dbo.fn_Split('a,b,c,,',',')