CorelDRAWX4的VBA插件开发(三十一)使用C++制作动态连接库DLL辅助VBA构键强大功能-(5)在VBA中动态调用DLL文件

• 我们先来看一下动态调用的截图
  
• 先上代码

'静态调用
Public Declare Function wodedll Lib "E:\VS-DLL\conglingkaishi\Debug\CongLingKaiShi.dll" Alias "WoDeDll" (ByVal Application As Application, ByVal hwnd As Long) As Integer


'动态调用
Private Declare Function FreeLibrary Lib "kernel32" (ByVal hLibModule As Long) As Long
Private Declare Function LoadLibrary Lib "kernel32" Alias "LoadLibraryA" (ByVal lpLibFileName As String) As Long
Private Declare Function GetProcAddress Lib "kernel32" (ByVal hModule As Long, ByVal lpProcName As String) As Long

 '把第2第3第4第5个参考都改成any  这样在传参的时候直接保持原样传过去
Private Declare Function CallWindowProc Lib "User32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Any, ByVal Msg As Any, ByVal wParam As Any, ByVal lParam As Any) As Long

Public Sub loadCineDll(ByVal dllname As String, ByVal myFunc As String)
    
    Dim lb As Long, pa As Long
    
    '加载动态连接库,成功后返回值是模块的句柄,用一个长整数lb来储存
    lb = LoadLibrary(dllname)
    If lb = 0 Then
        MsgBox "DLL读取失败！"
        Exit Sub
    End If
    
    '取得库中的函数地址句柄,用一个长整数pa来储存
    pa = GetProcAddress(lb, myFunc)
    If pa = 0 Then
        MsgBox "函数读取失败！", vbCritical
        FreeLibrary lb
        Exit Sub
    End If

     '调用函数并传入四个参数,前面两个参数就是我们需要用的,多余的后面两个参数随便填0&不影响,&是表示是长整数long
    CallWindowProc pa, CorelDRAW.Application, CorelDRAW.Windows.Item(1).Handle, 0&, 0&
    
    '释放
    FreeLibrary lb

End Sub

• 上面这个是待使用的模块,然后我们写一下调用
  

Sub 第一个插件()

    vbaToDll.loadCineDll "E:\VS-DLL\conglingkaishi\Debug\CongLingKaiShi.dll", "WoDeDll"
    
End Sub

• 可以看到我们在调用的时候只要传两个参数就可以了,一个就是导出的DLL的全路径,第二个就是函数名称.

• 为何这么好用就是因为有了这个功能FreeLibrary lb,在内存里面释放了加载的DLL,而且是每一次用完都会释放,所以可以让我们的DLL和CDR程序不产生瓜葛.

最终效果

这样我们就实现了第二十七节中第一张图的效果啦,到了这里,使用C++制作动态连接库DLL辅助VBA构键强大功能这一小节就告一段落.