汇编 串处理

汇编 串处理

一、串的概念

1. 串：n个存储单元称为串。根据存储单元的内容，有不同的叫法，如字符串数组等。
2. 串处理：对串的操作称为串处理。

二、串处理指令

1. 定义：串操作指令是$8086$指令系统中比较独特的一类指令，采用比较特殊的数据串寻址方式，是可以直接实现存储区之间操作的指令。
2. 操作对象：内存中连续存放的数据串，即在连续的内存区域中以字为单位的字串，或是以字节为单位的字节串。

2.1 串传送$MOVS$

1. 格式：

　　　MOVS  DST,SRC
　　　MOVSB  （字节）
　　　MOVSW   （字）

2. 功能：将以$SI$为指针的源串中的一个字节（或字）存储单元中的数据传送至以$DI$为指针的目的地址中去，并自动修改指针，使之指向下一个字节（或字）存储单元。
3. 执行操作：
   1. $DS：[SI]\to ES：[DI]$。
   2. 当$DF=0$时，$SI$和$DI$自动增量；当$DF=1$时，$SI$和$DI$自动减量。
4. 举例：传送$100$个字节操作数的例子。
   传送一个字节

   	mov si,offset source
   	mov di,offset destination
   	mov cx,100	；cx←传送次数
   	cld	；置DF=0，地址增加
   again:	movsb	；传送一个字节
   	dec cx	；传送次数减1
   	jnz again
   	；判断传送次数cx是否为0
   	；不为0，则到again位置执行指令
   	；否则，结束
   

   传送一个字

   	mov si,offset source
   	mov di,offset destination
   	mov cx,50	；cx←传送次数
   	cld	；置DF=0，地址增加
   again:	movsw	；传送一个字
   	dec cx	；传送次数减1
   	jnz again
   	；判断传送次数cx是否为0
   	；不为0，则到again位置执行指令
   	；否则，结束
   

2.2 串比较$CMPS$

1. 格式：

   　　　CMPS  SRC,DST
   　　　CMPSB  （字节）
   　　　CMPSW   （字）
   

2. 功能：将$SI$所指的源串中的一个字节（或字）存储单元中的数据与$DI$所指的目的串中的一个字节（或字）存储单元中的数据相减，并根据相减的结果设置标志，但结果并不保存。
3. 执行操作：
   1. $（[SI]）－（[DI]）$。
   2. 修改串指针，使之指向串中的下一个元素。
      当$DF=0$时，（$SI$）和（$DI$）增量。
      当$DF=1$时，（$SI$）和（$DI$）减量。
4. 举例：对$string1$和$string2$两个字符串进行比较，若串相同，在$result$单元中置$0$，否则置$－1$。

   	mov si,offset string1
   	mov di,offset string2
   	mov cx,count
   	cld
   again:	cmpsb	；比较两个字符
   	jnz unmat	；有不同字符，转移
   	dec cx
   	jnz again	；进行下一个字符比较
   	mov al,0	；字符串相等，设置00h
   	jmp output	；转向output
   unmat:	mov al,0ffh	；设置ffh
   output:	mov result,al	；输出结果标记
   

2.3 串扫描$SCAS$

1. 格式：

　　　SCAS     DST
　　　SCASB  （字节）
　　　SCASW   （字）

2. 功能：$AL$（字节）或$AX$（字）中的内容与$DI$所指的目的串中的一个字节（或字）存储单元中的数据相减，根据相减结果设置标志位，结果不保存。

3. 执行操作：

   1. 字节操作:$AL－[DI]$,字操作:$AX－[DI]$。
   2. 修改指针使之指向串中的下一个元素。
      　当$DF=0$时，（$DI$）增量。
      　当$DF=1$时，（$DI$）减量。

4. 举例：查找字符串

   	mov di,offset string
   	mov al,20h　；空格的ASCII码值
   	mov cx,count
   	cld
   again:	scasb	；搜索
   	jz found	；为0（ZF=1），发现空格
   	dec cx	；不是空格
   	jnz again	；搜索下一个字符
   	...	；不含空格，则继续执行
   found:	...
   

2.4 串获取$LODS$

1. 格式：

   　　　LODS     SRC
   　　　LODSB  （字节）
   　　　LODSW   （字）
   

2. 功能：将$SI$所指的源串中的一个字节（或字）存储单元中的数据取出来送入$AL$（或$AX$）中。
3. 执行操作：
   • 字节操作：$[SI]\to AL$，字操作：$[SI]\to AX$。
   • 修改指针$SI$，使它指向串中的下一个元素。
     当$DF=0$时，$SI$增量。
     当$DF=1$时，$SI$减量。

2.5 串存入$STOS$

1. 格式：

　　　STOS     DST
　　　STOSB  （字节）
　　　STOSW   （字）

2. 功能：将$AL$或$AX$中的数据送入$DI$所指的目的串中的字节（或字）存储单元中。
3. 操作执行：
   1. 字节操作：$AL\to [DI]$，字操作：$AX\to [DI]$。
   2. 修改指针$DI$，使之指向串中的下一个元素。
      当$DF=0$时，$DI$增量；
      当$DF=1$时，$DI$减量。
4. 举例：数据区初始化

   	mov ax,0
   	mov di,0
   	mov cx,1000h
   	cld	；DF=0，地址增加
   again:	stosw	；传送一个字
   	loop again	；传送次数cx是否为0
   

3. 串与循环

• 串操作指令执行一次，仅对数据串中的一个字节或字进行操作。但是在串操作指令前，都可以加一个重复前缀，实现串操作的重复执行。

3.1 $REP$重复前缀指令

1. 格式：

 REP　串指令

2. 功能：当$CX\ne 0$时，重复执行后面的串指令。可以理解为每执行一次后面的串指令，$CX$减$1$，并回送$CX$，直到$CX＝0$，重复执行结束。
3. 说明： $REP$指令一般用在$MOVS$、$STOS$指令前。
4. 举例：重复串传送

   	mov si,offset source
   	mov di,offset destination
   	mov cx,100	；cx←传送次数
   	cld
   	rep movsb
   

   rep movsb 等于一下程序。

   again:	movsb	；传送一个字节
   	dec cx	；传送次数减1
   	jnz again	；判断传送次数cx是否为0
   	；不为0（ZF=0），则转移again位置执行
   	；否则，结束
   

3.2 $REPZ$重复前缀指令

1. 格式：

    REPZ　串指令
   

2. 功能：重复执行串指令的条件是： $CX\ne 0$，且字符相等$ZF＝1$。可以理解为：每执行一次串指令，$CX$减$1$回送$CX$，并判断$ZF$是否为$0$，只要$CX＝0$或$ZF＝0$，重复执行结束。
3. 说明： $REPZ$后面常跟$CMPS$串指令，用于字符串的比较。
4. 举例：比较字符串

   	mov si,offset string1
   	mov di,offset string2
   	mov cx,count
   	cld
   	repz cmpsb	；重复比较两个字符
   	jnz unmat	；字符串不等，转移
   	mov al,0	；字符串相等，设置00h
   	jmp output	；转向output
   unmat:	mov al,0ffh	；设置ffh
   output:	mov result,al	；输出结果标记
   

3.3 $REPNZ$重复前缀指令

1. 格式：

   REPNZ　串指令
   

2. 功能：重复执行后面串指令的条件是：$CX\ne 0$并且串不相等 $ZF＝0$。可以理解为：每执行一次后面的串指令，$CX$减$1$，并判断$ZF$是否为$1$，只要$CX＝0$或$ZF＝1$，重复执行结束。

3. 说明： $REPNZ$后面常跟$SCAS$串指令，用于搜索一个字符。

4. 举例：查找字符串

   	mov di,offset string
   	mov al,20h
   	mov cx,count
   	cld
   	repnz scasb	；搜索
   	jz found	；（ZF=1），发现空格
   	...	；不含空格，则继续执行
   found:	...