RationalDMIS 7.1 B89重复性测试

$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$B89重复性测试$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

UNITS/MM, ANGDEC
WKPLAN/XYPLAN
PRCOMP/ON
TECOMP/OFF
FLY/1
MODE/PROG, MAN
SNSET/APPRCH, 10.000000
SNSET/RETRCT, 10.000000
SNSET/DEPTH, 0.000000
SNSET/SEARCH, 20.0000
SNSET/CLRSRF, 5.000000
RECALL/D(MCS)
GEOALG/CIRCLE, LSTSQR
GEOALG/ARC, LSTSQR
GEOALG/PLANE, LSTSQR
$$
$$

DECL/COMMON,DOUBLE,NOM_D,MAX_C[3],MIN_C[3],B89[3]
DECL/COMMON,DOUBLE,P_Cord[3],SPH_Cord[3],VALUE_SPH[10,3]
DECL/COMMON,INTGR,NUM_PT,I,J



TEMPSTRING = PROMPT/TITLE,'B89重复性测试程序',TEXT,'请将测头移动到标准球的正上方',$
                    TEXT,'标准球的理论直径为',EDIT,NOM_D,                         $
                    TEXT,'重复性检定球的点数',EDIT,NUM_PT
                    
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$取得标准球球心的坐标值$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$定义标准球理论值$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
F(S_Point) = FEAT/POINT,CART,0,0,0,0,0,1
  MEAS/POINT,F(S_Point),0
  ENDMES
  
	P_Cord[1] = OBTAIN/FA(S_Point),3
	P_Cord[2] = OBTAIN/FA(S_Point),4
	P_Cord[3] = OBTAIN/FA(S_Point),5

  MEAS/POINT,F(S_Point),1
    PTMEAS/CART, P_cord[1], P_cord[2], P_cord[3]-1, 0, 0, 1
  ENDMES
  
	P_Cord[1] = OBTAIN/FA(S_Point),3
	P_Cord[2] = OBTAIN/FA(S_Point),4
	P_Cord[3] = OBTAIN/FA(S_Point),5

F(M_SPH) = FEAT/SPHERE, OUTER, CART, P_cord[1], P_cord[2], P_cord[3]-NOM_D/2,$
                NOM_D
MODE/AUTO,PROG,MAN
  MEAS/SPHERE,F(M_SPH),5
  ENDMES
  
	SPH_Cord[1] = OBTAIN/FA(M_SPH),4
	SPH_Cord[2] = OBTAIN/FA(M_SPH),5
	SPH_Cord[3] = OBTAIN/FA(M_SPH),6

F(M_SPH) = FEAT/SPHERE, OUTER, CART, SPH_Cord[1], SPH_Cord[2],$
                SPH_Cord[3],NOM_D
  MEAS/SPHERE,F(M_SPH),5
  ENDMES
  
	SPH_Cord[1] = OBTAIN/FA(M_SPH),4
	SPH_Cord[2] = OBTAIN/FA(M_SPH),5
	SPH_Cord[3] = OBTAIN/FA(M_SPH),6

F(M_SPH) = FEAT/SPHERE, OUTER, CART, SPH_Cord[1], SPH_Cord[2],$
                SPH_Cord[3],NOM_D
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

$$$$$$$$$$$$$$$$$$$$$$$$$$$平移坐标系$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
D(SPH25) = TRANS/XORIG,FA(M_SPH),YORIG,FA(M_SPH),ZORIG,FA(M_SPH)
$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

DO/I,1,10

   MEAS/SPHERE,F(M_SPH),5
   ENDMES
   
   VALUE_SPH[I,1] = OBTAIN/FA(M_SPH),4
   VALUE_SPH[I,2] = OBTAIN/FA(M_SPH),5
   VALUE_SPH[I,3] = OBTAIN/FA(M_SPH),6
   
ENDDO

MAX_C[1] = ASSIGN/VALUE_SPH[1,1]
MAX_C[2] = ASSIGN/VALUE_SPH[1,2]
MAX_C[3] = ASSIGN/VALUE_SPH[1,3]

MIN_C[1] = ASSIGN/VALUE_SPH[1,1]
MIN_C[2] = ASSIGN/VALUE_SPH[1,2]
MIN_C[3] = ASSIGN/VALUE_SPH[1,3]

DO/I,1,10

  DO/J,1,3
   
    IF/(VALUE_SPH[I,J] .GE. MAX_C[J])
        MAX_C[J] = ASSIGN/VALUE_SPH[I,J]
    ENDIF
    
    IF/(VALUE_SPH[I,J] .LE. MIN_C[J])
        MIN_C[J] = ASSIGN/VALUE_SPH[I,J]
    ENDIF
  
  ENDDO

ENDDO

B89[1] = ASSIGN/MAX_C[1] - MIN_C[1]
B89[2] = ASSIGN/MAX_C[2] - MIN_C[2]
B89[3] = ASSIGN/MAX_C[3] - MIN_C[3]

$$ Set.ForeGround.Output

WRITE/DID(DEFAULTSCREEN),'球心X坐标最大值为',MAX_C[1],'    球心X坐标最小值为',MIN_C[1]
WRITE/DID(DEFAULTSCREEN),'球心Y坐标最大值为',MAX_C[2],'    球心Y坐标最小值为',MIN_C[2]
WRITE/DID(DEFAULTSCREEN),'球心Z坐标最大值为',MAX_C[3],'    球心Z坐标最小值为',MIN_C[3]

WRITE/DID(DEFAULTSCREEN),'B89_X重复性为',B89[1]
WRITE/DID(DEFAULTSCREEN),'B89_Y重复性为',B89[2]
WRITE/DID(DEFAULTSCREEN),'B89_Z重复性为',B89[3]