学习100个Unity Shader (12) --- 高光反射光照模型

效果

高光反射光照模型

：反光度： 越大亮点越小。
：视角方向。
r: 反射方向。

漫反射模型

n: 顶点法线方向。
I: 入射光方向。

Shader

逐顶点光照

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Example/Specular-Vertex-Level"
{
  Properties
  {
    _Diffuse ("Diffuse", Color) =  (1, 1, 1, 1)
    _Specular ("Specular", Color) =  (1, 1, 1, 1)
    _Gloss ("Gloss", Range(8.0, 256)) = 20
  }
  SubShader
  {
    Tags { "LightMode"="ForwardBase" } //渲染路径，前向渲染

    Pass
    {
      CGPROGRAM
      #pragma vertex vert   //定义顶点着色器叫vert
      #pragma fragment frag //定义片元着色器叫frag

      #include "Lighting.cginc" //使用Unity内置变量，如_LightColor0

      // 定义顶点着色器的输入
      struct a2v //a: application, v: vetex
      {
        float4 vertex : POSITION; //POSITION语义告诉Unity, 用模型空间的顶点坐标填充vertex变量
        float3 normal : NORMAL;   //NORMAL语义告诉Unity, 用模型空间的法线方向填充normal变量
      };

      // 定义顶点着色器的输出和片元着色器的输入
      struct v2f 
      {
        float4 pos : SV_POSITION; //SV_POSITION语义告诉Unity, pos里包含了顶点在裁剪空间中的位置信息,必须包含
        float3 color : COLOR;
      };

      float4 _Diffuse;
      float4 _Specular;
      float _Gloss;

      v2f vert (a2v v)
      {
        v2f o ; 
        // 模型空间到投影空间
        o.pos = UnityObjectToClipPos(v.vertex); 
        // 环境光
        fixed3 ambient= UNITY_LIGHTMODEL_AMBIENT.xyz; 
        // 在计算法线和光源方向之间的点积时，我们需要选择它们所在的坐标系 只有两者处千同
        // 坐标空间下，点积才有意。在这里选择了世界坐标空间。而由 a2v 得到的顶点法
        // 线是位于模型空间下的 因此我们首先需要把法线转换到世界空间中。
        fixed3 worldNormal = normalize (mul (v.normal, (float3x3) unity_WorldToObject)) ; 
        // 入射光的方向
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz); 
        // 兰伯特漫反射模型
        // 防止点积结果为负值使用saturat
        fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0.0, dot(worldNormal, worldLightDir));
        // 计算反射方向
        fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal)); 
        // 到世界空间下的视角方向
        fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz); 
        // 高光反射模型
        fixed3 specular =_LightColor0.rgb *_Specular. rgb * pow (max(0.0, dot (reflectDir, viewDir)), _Gloss); 
        o.color = ambient + diffuse + specular; 
        return o;
      }

      fixed4 frag (v2f i) : SV_Target
      {
        return fixed4(i.color, 1.0);
      }
      ENDCG
    }
  }
  Fallback "Specular"
}

逐像素光照

Shader "Example/Specular-Pixel-Level"
{
  Properties
  {
    _Diffuse ("Diffuse", Color) =  (1, 1, 1, 1)
    _Specular ("Specular", Color) =  (1, 1, 1, 1)
    _Gloss ("Gloss", Range(8.0, 256)) = 20
  }
  SubShader
  {
    Pass
    {
      Tags { "LightMode"="ForwardBase" } //渲染路径，前向渲染

      CGPROGRAM
      #pragma vertex vert   //定义顶点着色器叫vert
      #pragma fragment frag //定义片元着色器叫frag


      #include "UnityCG.cginc"

      // 定义顶点着色器的输入
      struct a2v //a: application, v: vetex
      {
        float4 vertex : POSITION; //POSITION语义告诉Unity, 用模型空间的顶点坐标填充vertex变量
        float3 normal : NORMAL;   //NORMAL语义告诉Unity, 用模型空间的法线方向填充normal变量
      };

      // 定义顶点着色器的输出和片元着色器的输入
      struct v2f 
      {
        float4 pos : SV_POSITION; //SV_POSITION语义告诉Unity, pos里包含了顶点在裁剪空间中的位置信息,必须包含
        float3 worldNormal : TEXCOORD0;
        float3 worldPos : TEXCOORD1;
      };  

      float4 _LightColor0; 
      float4 _Diffuse;
      float4 _Specular;
      float _Gloss;

      v2f vert (a2v v)
      {
        v2f o ; 
        // 模型空间到投影空间
        o.pos = UnityObjectToClipPos(v.vertex); 
        o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject); 
        o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
        return o;
      }

      fixed4 frag (v2f i) : COLOR
      {
        fixed3 worldNormal = normalize(i.worldNormal); 
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
        fixed3 diffuse = _Diffuse.rgb * max(0.0, dot(worldNormal, worldLightDir));

        fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
        // 到世界空间下的视角方向
        fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz); 
        // 高光反射模型
        fixed3 specular = _Specular.rgb * pow(max(0.0, dot(reflectDir, viewDir)), _Gloss);
        return fixed4((diffuse + specular + UNITY_LIGHTMODEL_AMBIENT) * _LightColor0.rgb, 1.0);
      }
      ENDCG
    }
  }
  Fallback "Specular"
}

参考

《Unity Shader入门精要》冯乐乐
Shaders in Unity — Specular