ARM Cortex-M0 全可编程SoC原理及实现笔记（1）

已于 2023-01-01 16:07:04 修改
阅读量3.8k 收藏 63
点赞数 11
分类专栏： 与ARM有关的一切 文章标签： fpga开发 嵌入式硬件
于 2022-12-31 21:20:54 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_44265207/article/details/128490884
版权

对应全书的第九章

目录

一、Cortex-M0架构的全貌是什么

  Cortex-M0架构分为硬件和软件部分，整个片上系统的内部结构如图1.1所示。
在这里插入图片描述

图1.1

1.1硬件部分

硬件部分在FPGA上由纯数字逻辑实现，主要模块包括：
  （1）系统时钟生成器(pll核)
  （2）ARM Cortex-M0微处理器
  （3）AHB-Lite系统总线：
   控制信号，用于同步和识别交易，如：准备，写、读以及传输模式信号
   32位地址总线，用于选择一个外设，或者一个外设中的一个寄存器
   32位数据总线，用于交换数据信息
  （4）两个AHB外设：
   程序存储器，通过FPGA内的块存储器实现
   LED外设
整个硬件部分的设计如图1.2
在这里插入图片描述

图1.2

1.2软件部分

Hello world程序：
  （1）在Keil μVision5中，使用汇编语言对Cortex-M0处理器编程
  （2）建立（build）汇编语言设计文件，生成十六进制的编程文件

1.3AHB_Lite总线

1.3.1AHB_Lite总线操作

总线操作过程如图1.3所示
在这里插入图片描述

图1.3
处理器访问一个AHB-Lite外设的过程

  （1）处理器提供要访问外设的地址信息
  （2）通过地址译码器生成目标外设的选择信号，同时处理器输出一个控制信号，如读写、传输数据的数量等
  （3）若处理器输出的是读控制信号，则待从设备ready之后读数据

1.3.2AHB-Lite主设备接口

  AHB-Lite主设备接口如图1.4和表1.1所示
在这里插入图片描述

图1.4AHB-Lite主设备接口
表1.1AHB-Lite主设备接口信号

在这里插入图片描述
  AHB-Lite有四种基本传输类型，如表1.2，交易的同步和识别由处理器的控制信号给出.

表1.2 AHB-Lite交易类型
交易访问描述
HSTRANS[1:0]=2’b00空闲处理器不希望处理任何交易
HSTRANS[1:0]=2’b10
HPROT[0]=1’b0
HSIZE[1:0]=2’b10
HWRITE=1’b0		取指处理器取指操作，处理器一次性从存储器取出32位指令
HSTRANS[1:0]=2’b10
HPROT[0]=1’b1
HSIZE[1:0]=2’b00		字节处理器希望一个8位数据访问操作，该操作由LDRB，LDRBS，STRB指令生成。加载执行将驱动HWRITE信号为低，保存指令将驱动HWRITE指令为高
HSTRANS[1:0]=2’b10
HPROT[0]=1’b1
HSIZE[1:0]=2’b01		半字处理器希望一个16位数据访问操作，该操作由LDRH，LDRHS，STRH指令生成。加载执行将驱动HWRITE信号为低，保存指令将驱动HWRITE指令为高
HSTRANS[1:0]=2’b10
HPROT[0]=1’b1
HSIZE[1:0]=2’b10		字处理器希望执行一个由LDR，LDM，POP，STR，STM，PUSH指令，或者异常入口的一部分，或者返回所产生的32位数据访问操作，加载执行将驱动HWRITE信号为低，保存指令将驱动HWRITE指令为高

其中各指令和异常、返回的概念在软件部分介绍

  Cortex-M0处理器总是工作在小端模式，所有交易总是自然对齐，怎么对齐如表1.3所示

表1.3 交易对齐方式

在这里插入图片描述

1.4Cortex-M0处理器端口描述

在这里插入图片描述
在这里插入图片描述

1.5处理器存储器映射属性

在这里插入图片描述
在这里插入图片描述

二、Cortex-M0架构在数字逻辑上怎么实现

看代码，怎么才算看懂代码或者数学公式？能用中文说出来就算看懂

2.1顶层文件AHBLITE_SYS

  代码如下


module AHBLITE_SYS(
	//CLOCKS & RESET
	input		wire				CLK,
	input		wire				RESET, 
	
	//TO BOARD LEDs
	output 	wire	[7:0] 	LED

);
 
//AHB-LITE SIGNALS 
//Gloal Signals
wire 				HCLK;
wire 				HRESETn;
//Address, Control & Write Data Signals
wire [31:0]		HADDR;
wire [31:0]		HWDATA;
wire 				HWRITE;
wire [1:0] 		HTRANS;
wire [2:0] 		HBURST;
wire 				HMASTLOCK;
wire [3:0] 		HPROT;
wire [2:0] 		HSIZE;
//Transfer Response & Read Data Signals
wire [31:0] 	HRDATA;
wire 				HRESP;
wire 				HREADY;

//SELECT SIGNALS
wire [3:0] 		MUX_SEL;

wire 				HSEL_MEM;
wire 				HSEL_LED;

//SLAVE READ DATA
wire [31:0] 	HRDATA_MEM;
wire [31:0] 	HRDATA_LED;

//SLAVE HREADYOUT
wire 				HREADYOUT_MEM;
wire 				HREADYOUT_LED;

//CM0-DS Sideband signals
wire 				LOCKUP;
wire 				TXEV;
wire 				SLEEPING;
wire [15:0]		IRQ;
  
//SYSTEM GENERATES NO ERROR RESPONSE
assign 			HRESP = 1'b0;

//CM0-DS INTERRUPT SIGNALS  
assign 			IRQ = {16'b0000_0000_0000_0000};

// Clock divider, divide the frequency by two, hence less time constraint 
 clk_wiz_0 Inst_clk_wiz_0
 (
 // Clock in ports
  .clk_in1(CLK),      // input clk_in1
  // Clock out ports
  .clk_out1(HCLK),     // output clk_out1
  // Status and control signals
  .reset(RESET), // input reset
  .locked(HRESETn));      // output locked
// INST_TAG_END ------ End INSTANTIATION Template ---------     

//AHBLite MASTER --> CM0-DS

CORTEXM0DS u_cortexm0ds (
	//Global Signals
	.HCLK        (HCLK),
	.HRESETn     (HRESETn),
	//Address, Control & Write Data	
	.HADDR       (HADDR[31:0]),
	.HBURST      (HBURST[2:0]),
	.HMASTLOCK   (HMASTLOCK),
	.HPROT       (HPROT[3:0]),
	.HSIZE       (HSIZE[2:0]),
	.HTRANS      (HTRANS[1:0]),
	.HWDATA      (HWDATA[31:0]),
	.HWRITE      (HWRITE),
	//Transfer Response & Read Data	
	.HRDATA      (HRDATA[31:0]),			
	.HREADY      (HREADY),					
	.HRESP       (HRESP),					

	//CM0 Sideband Signals
	.NMI         (1'b0),
	.IRQ         (IRQ[15:0]),
	.TXEV        (),
	.RXEV        (1'b0),
	.LOCKUP      (LOCKUP),
	.SYSRESETREQ (),
	.SLEEPING    ()
);

//Address Decoder 

AHBDCD uAHBDCD (
	.HADDR(HADDR[31:0]),
	 
	.HSEL_S0(HSEL_MEM),
	.HSEL_S1(HSEL_LED),
	.HSEL_S2(),
	.HSEL_S3(),
	.HSEL_S4(),
	.HSEL_S5(),
	.HSEL_S6(),
	.HSEL_S7(),
	.HSEL_S8(),
	.HSEL_S9(),
	.HSEL_NOMAP(HSEL_NOMAP),
	 
	.MUX_SEL(MUX_SEL[3:0])
);

//Slave to Master Mulitplexor

AHBMUX uAHBMUX (
	.HCLK(HCLK),
	.HRESETn(HRESETn),
	.MUX_SEL(MUX_SEL[3:0]),
	 
	.HRDATA_S0(HRDATA_MEM),
	.HRDATA_S1(HRDATA_LED),
	.HRDATA_S2(),
	.HRDATA_S3(),
	.HRDATA_S4(),
	.HRDATA_S5(),
	.HRDATA_S6(),
	.HRDATA_S7(),
	.HRDATA_S8(),
	.HRDATA_S9(),
	.HRDATA_NOMAP(32'hDEADBEEF),
	 
	.HREADYOUT_S0(HREADYOUT_MEM),
	.HREADYOUT_S1(HREADYOUT_LED),
	.HREADYOUT_S2(1'b1),
	.HREADYOUT_S3(1'b1),
	.HREADYOUT_S4(1'b1),
	.HREADYOUT_S5(1'b1),
	.HREADYOUT_S6(1'b1),
	.HREADYOUT_S7(1'b1),
	.HREADYOUT_S8(1'b1),
	.HREADYOUT_S9(1'b1),
	.HREADYOUT_NOMAP(1'b1),
    
	.HRDATA(HRDATA[31:0]),
	.HREADY(HREADY)
);

// AHBLite Peripherals


//AHBLite Slave 
AHB2MEM uAHB2MEM (
	//AHBLITE Signals
	.HSEL(HSEL_MEM),
	.HCLK(HCLK), 
	.HRESETn(HRESETn), 
	.HREADY(HREADY),     
	.HADDR(HADDR),
	.HTRANS(HTRANS[1:0]), 
	.HWRITE(HWRITE),
	.HSIZE(HSIZE),
	.HWDATA(HWDATA[31:0]), 
	
	.HRDATA(HRDATA_MEM), 
	.HREADYOUT(HREADYOUT_MEM)
	//Sideband Signals
	
);

//AHBLite Slave 
AHB2LED uAHB2LED (
	//AHBLITE Signals
	.HSEL(HSEL_LED),
	.HCLK(HCLK), 
	.HRESETn(HRESETn), 
	.HREADY(HREADY),     
	.HADDR(HADDR),
	.HTRANS(HTRANS[1:0]), 
	.HWRITE(HWRITE),
	.HSIZE(HSIZE),
	.HWDATA(HWDATA[31:0]), 
	
	.HRDATA(HRDATA_LED), 
	.HREADYOUT(HREADYOUT_LED),
	//Sideband Signals
	.LED(LED[7:0])
);


endmodule

2.2系统主时钟IP核

输出20MHz时钟作为系统主时钟

2.3AHB总线地址译码器AHBDCD

  注意该模块为纯组合逻辑，没有全局时钟和复位信号

module AHBDCD(
  input wire [31:0] HADDR,
  
  output wire HSEL_S0,
  output wire HSEL_S1,
  output wire HSEL_S2,
  output wire HSEL_S3,
  output wire HSEL_S4,
  output wire HSEL_S5,
  output wire HSEL_S6,
  output wire HSEL_S7,
  output wire HSEL_S8,
  output wire HSEL_S9,
  output wire HSEL_NOMAP,
  
  output reg [3:0] MUX_SEL
    );

reg [15:0] dec;

//REFER CM0-DS REFERENC MANUAL FOR RAM & PERIPHERAL MEMORY MAP
//									//MEMORY MAP --> START ADDR 		END ADDR 	SIZE 
assign HSEL_S0 = dec[0];   //MEMORY MAP --> 0x0000_0000 to 0x00FF_FFFF  16MB
assign HSEL_S1 = dec[1];   //MEMORY MAP --> 0x5000_0000 to 0x50FF_FFFF  16MB	
assign HSEL_S2 = dec[2];   //MEMORY MAP --> 0x5100_0000 to 0x51FF_FFFF  16MB
assign HSEL_S3 = dec[3];   //MEMORY MAP --> 0x5200_0000 to 0x52FF_FFFF  16MB
assign HSEL_S4 = dec[4];   //MEMORY MAP --> 0x5300_0000 to 0x53FF_FFFF  16MB
assign HSEL_S5 = dec[5];   //MEMORY MAP --> 0x5400_0000 to 0x54FF_FFFF  16MB
assign HSEL_S6 = dec[6];   //MEMORY MAP --> 0x5500_0000 to 0x55FF_FFFF  16MB
assign HSEL_S7 = dec[7];   //MEMORY MAP --> 0x5600_0000 to 0x56FF_FFFF  16MB
assign HSEL_S8 = dec[8];   //MEMORY MAP --> 0x5700_0000 to 0x57FF_FFFF  16MB
assign HSEL_S9 = dec[9];   //MEMORY MAP --> 0x5800_0000 to 0x58FF_FFFF  16MB
assign HSEL_NOMAP = dec[15]; //REST OF REGION NOT COVERED ABOVE
    
always@*
begin

  case(HADDR[31:24])
    8'h00: 						//MEMORY MAP --> 0x0000_0000 to 0x00FF_FFFF  16MB
      begin
        dec = 16'b0000_0000_00000001;
        MUX_SEL = 4'b0000;
      end
    8'h50: 						//MEMORY MAP --> 0x5000_0000 to 0x50FF_FFFF  16MB 
      begin
        dec = 16'b0000_0000_0000_0010;
        MUX_SEL = 4'b0001;
      end
    8'h51: 						//MEMORY MAP --> 0x5100_0000 to 0x51FF_FFFF  16MB
      begin
        dec =16'b0000_0000_0000_0100;
        MUX_SEL = 4'b0010;
      end   
    8'h52:  					//MEMORY MAP --> 0x5200_0000 to 0x52FF_FFFF  16MB
      begin
        dec = 16'b0000_0000_0000_1000;
        MUX_SEL = 4'b0011;
      end
    8'h53: 						//MEMORY MAP --> 0x5300_0000 to 0x53FF_FFFF  16MB 
      begin
        dec = 16'b0000_0000_0001_0000;
        MUX_SEL = 4'b0100;
      end
    8'h54:						//MEMORY MAP --> 0x5400_0000 to 0x54FF_FFFF  16MB  
      begin
        dec = 16'b0000_0000_0010_0000;
        MUX_SEL = 4'b0101;
      end
    8'h55:						//MEMORY MAP --> 0x5500_0000 to 0x55FF_FFFF  16MB 
      begin
        dec = 16'b0000_0000_0100_0000;
        MUX_SEL = 4'b0110;
      end
    8'h56:						//MEMORY MAP --> 0x5600_0000 to 0x56FF_FFFF  16MB 
      begin
        dec = 16'b0000_0000_1000_0000;
        MUX_SEL = 4'b0111;
      end
    8'h57: 						//MEMORY MAP --> 0x5700_0000 to 0x57FF_FFFF  16MB
      begin
        dec = 16'b0000_0001_0000_0000;
        MUX_SEL = 4'b1000;
      end
    8'h58:						//MEMORY MAP --> 0x5800_0000 to 0x58FF_FFFF  16MB 
      begin
        dec = 16'b0000_0010_0000_0000;
        MUX_SEL = 4'b1001;
      end
    default: //NOMAP
      begin
        dec = 16'b1000_0000_00000000;
        MUX_SEL = 4'b1111;
      end
  endcase
end

endmodule

  AHB地址译码器模块根据地址信号的高八位HADDR[31:24]来输出十个外设使能HSEL与NOMAP信号，和使能外设地址号MUX_SEL，其中各信号映射如表2.1。

HADDR[31:24]decMUX_SELMEMORY MAP
8’h00HSEL_S000x0000_0000 to 0x00FF_FFFF 16MB
8’h50HSEL_S110x5000_0000 to 0x00FF_FFFF 16MB
8’h51HSEL_S220x5100_0000 to 0x00FF_FFFF 16MB
8’h52HSEL_S330x5200_0000 to 0x00FF_FFFF 16MB
8’h53HSEL_S440x5300_0000 to 0x00FF_FFFF 16MB
8’h54HSEL_S550x5400_0000 to 0x00FF_FFFF 16MB
8’h55HSEL_S660x5500_0000 to 0x00FF_FFFF 16MB
8’h56HSEL_S770x5600_0000 to 0x00FF_FFFF 16MB
8’h57HSEL_S880x5700_0000 to 0x00FF_FFFF 16MB
8’h58HSEL_S990x5800_0000 to 0x00FF_FFFF 16MB
defaultHSEL_NOMAP15none
表2.1
  该表是各外设在ram中的地址映射，每个外设都分配了16MB的地址，注意s0外设的起始位与其他的不一样,外设与ram中的地址映射可参考CM0-DS手册，其中HSEL_S0与HSEL_S1将分别与外部存储器和LED模块相连。   对于32位地址信号HADDR，0x40000000~0x5FFFFFFF的部分是推荐给外设使用的。

2.4 AHB总线从设备多路复用器

  选择从设备的读数据和ready信号给主设备。在地址阶段锁存MUX_SEL，在数据阶段输出READY(RESPONSE貌似外设都没用到)和RDATA。由代码可知，S0(即片上存储器)必须先READY


 
module AHBMUX(
  //GLOBAL CLOCK & RESET
  input wire HCLK,
  input wire HRESETn,
   
  //MUX SELECT FROM ADDRESS DECODER
  input wire [3:0] MUX_SEL,

  //READ DATA FROM ALL THE SLAVES  
  input wire [31:0] HRDATA_S0,		
  input wire [31:0] HRDATA_S1,
  input wire [31:0] HRDATA_S2,
  input wire [31:0] HRDATA_S3,
  input wire [31:0] HRDATA_S4,
  input wire [31:0] HRDATA_S5,
  input wire [31:0] HRDATA_S6,
  input wire [31:0] HRDATA_S7,
  input wire [31:0] HRDATA_S8,
  input wire [31:0] HRDATA_S9,
  input wire [31:0] HRDATA_NOMAP,

  //READYOUT FROM ALL THE SLAVES  
  input wire HREADYOUT_S0,
  input wire HREADYOUT_S1,
  input wire HREADYOUT_S2,
  input wire HREADYOUT_S3,
  input wire HREADYOUT_S4,
  input wire HREADYOUT_S5,
  input wire HREADYOUT_S6,
  input wire HREADYOUT_S7,
  input wire HREADYOUT_S8,
  input wire HREADYOUT_S9,
  input wire HREADYOUT_NOMAP,
 
  //MULTIPLEXED HREADY & HRDATA TO MASTER
  output reg HREADY,
  output reg [31:0] HRDATA
);

 
  reg [3:0] APHASE_MUX_SEL;			// LATCH THE ADDRESS PHASE MUX_SELECT
												// TO SEND THE APPROPRIATE RESPONSE & RDATA
												// IN THE DATA PHASE
  always@ (posedge HCLK or negedge HRESETn)
  begin
    if(!HRESETn)
      APHASE_MUX_SEL <= 4'h0;
    else if(HREADY)						// NOTE: ALL THE CONTROL SIGNALS ARE VALID ONLY IF HREADY = 1'b1
      APHASE_MUX_SEL <= MUX_SEL;
  end


  always@*
  begin
    case(APHASE_MUX_SEL)
      4'b0000: begin						// SELECT SLAVE0 RESPONSE & DATA IF PREVIOUS APHASE WAS FOR S0
        HRDATA = HRDATA_S0;
        HREADY = HREADYOUT_S0;
      end
      4'b0001: begin
        HRDATA = HRDATA_S1;
        HREADY = HREADYOUT_S1;
      end
      4'b0010: begin
        HRDATA = HRDATA_S2;
        HREADY = HREADYOUT_S2;
      end
      4'b0011: begin
        HRDATA = HRDATA_S3;
        HREADY = HREADYOUT_S3;
      end
      4'b0100: begin
        HRDATA = HRDATA_S4;
        HREADY = HREADYOUT_S4;
      end
      4'b0101: begin
        HRDATA = HRDATA_S5;
        HREADY = HREADYOUT_S5;
      end
      4'b0110: begin
        HRDATA = HRDATA_S6;
        HREADY = HREADYOUT_S6;
      end
      4'b0111: begin
        HRDATA = HRDATA_S7;
        HREADY = HREADYOUT_S7;
      end
      4'b1000: begin
        HRDATA = HRDATA_S8;
        HREADY = HREADYOUT_S8;
      end
      4'b1001: begin
        HRDATA = HRDATA_S9;
        HREADY = HREADYOUT_S9;
      end
      default: begin            
        HRDATA = HRDATA_NOMAP;
        HREADY = HREADYOUT_NOMAP;
      end
    endcase
    
  end


endmodule

2.5 AHB片上存储器外设

  软件程序最终会被翻译为机器指令，片上存储器就是存储机器指令的地方，由FPGA上的BRAM(块存储器)实现

//  --
module AHB2MEM
#(parameter MEMWIDTH = 10)					// SIZE = 1KB = 256 Words
(
	//AHBLITE INTERFACE
		//Slave Select Signals
			input wire HSEL,
		//Global Signal
			input wire HCLK,
			input wire HRESETn,
		//Address, Control & Write Data
			input wire HREADY,
			input wire [31:0] HADDR,
			input wire [1:0] HTRANS,
			input wire HWRITE,
			input wire [2:0] HSIZE,
			
			input wire [31:0] HWDATA,
		// Transfer Response & Read Data
			output wire HREADYOUT,
			output wire [31:0] HRDATA,
	
	//LED Output
			output wire [7:0] LED
);


  assign HREADYOUT = 1'b1; // Always ready

// Registers to store Adress Phase Signals
 
  reg APhase_HSEL;
  reg APhase_HWRITE;
  reg [1:0] APhase_HTRANS;
  reg [31:0] APhase_HADDR;
  reg [2:0] APhase_HSIZE;

// Memory Array  
  reg [31:0] memory[0:(2**(MEMWIDTH-2)-1)];
  
  initial
  begin
(*rom_style="block"*)	 $readmemh("code.hex", memory);
  end

// Sample the Address Phase   
  always @(posedge HCLK or negedge HRESETn)
  begin
	 if(!HRESETn)
	 begin
		APhase_HSEL <= 1'b0;
      APhase_HWRITE <= 1'b0;
      APhase_HTRANS <= 2'b00;
		APhase_HADDR <= 32'h0;
		APhase_HSIZE <= 3'b000;
	 end
    else if(HREADY)
    begin
      APhase_HSEL <= HSEL;
      APhase_HWRITE <= HWRITE;
      APhase_HTRANS <= HTRANS;
		APhase_HADDR <= HADDR;
		APhase_HSIZE <= HSIZE;
    end
  end

// Decode the bytes lanes depending on HSIZE & HADDR[1:0]

  wire tx_byte = ~APhase_HSIZE[1] & ~APhase_HSIZE[0];
  wire tx_half = ~APhase_HSIZE[1] &  APhase_HSIZE[0];
  wire tx_word =  APhase_HSIZE[1];
  
  wire byte_at_00 = tx_byte & ~APhase_HADDR[1] & ~APhase_HADDR[0];
  wire byte_at_01 = tx_byte & ~APhase_HADDR[1] &  APhase_HADDR[0];
  wire byte_at_10 = tx_byte &  APhase_HADDR[1] & ~APhase_HADDR[0];
  wire byte_at_11 = tx_byte &  APhase_HADDR[1] &  APhase_HADDR[0];
  
  wire half_at_00 = tx_half & ~APhase_HADDR[1];
  wire half_at_10 = tx_half &  APhase_HADDR[1];
  
  wire word_at_00 = tx_word;
  
  wire byte0 = word_at_00 | half_at_00 | byte_at_00;
  wire byte1 = word_at_00 | half_at_00 | byte_at_01;
  wire byte2 = word_at_00 | half_at_10 | byte_at_10;
  wire byte3 = word_at_00 | half_at_10 | byte_at_11;

// Writing to the memory

// Student Assignment: Write a testbench & simulate to spot bugs in this Memory module

  always @(posedge HCLK)
  begin
	 if(APhase_HSEL & APhase_HWRITE & APhase_HTRANS[1])
	 begin
		if(byte0)
			memory[APhase_HADDR[MEMWIDTH:2]][7:0] <= HWDATA[7:0];
		if(byte1)
			memory[APhase_HADDR[MEMWIDTH:2]][15:8] <= HWDATA[15:8];
		if(byte2)
			memory[APhase_HADDR[MEMWIDTH:2]][23:16] <= HWDATA[23:16];
		if(byte3)
			memory[APhase_HADDR[MEMWIDTH:2]][31:24] <= HWDATA[31:24];
	  end
  end

// Reading from memory 
  assign HRDATA = memory[APhase_HADDR[MEMWIDTH:2]];

// Diagnostic Signal out
assign zeroth_location = 0;
assign LED = memory[zeroth_location][7:0];
  
endmodule

  分析下面这一段代码，若将表1.3中的7种情况编号，则byte0表示第1、5、7种情况，byte1表示第2、5、7种情况，byte2表示第3、6、7种情况，byte1表示第4、6、7种情况。
  APhase_HADDR[MEMWIDTH:2]表示把输入的地址除以4，为什么要这样做？因为一个字有四个字节。S0端口号对应的地址范围为0x00000000~0x00FFFFFF,而片上存储器只有1kb，所以其地址范围为0x00000000~0x000003FF,即MEMWIDTH那么多位的空间，但要右移2位，再写入对应的字节通道，因为一个字有四个字节。所以知道为什么C++要字节对齐了吧。

  wire byte0 = word_at_00 | half_at_00 | byte_at_00;
  wire byte1 = word_at_00 | half_at_00 | byte_at_01;
  wire byte2 = word_at_00 | half_at_10 | byte_at_10;
  wire byte3 = word_at_00 | half_at_10 | byte_at_11;

// Writing to the memory

// Student Assignment: Write a testbench & simulate to spot bugs in this Memory module

  always @(posedge HCLK)
  begin
	 if(APhase_HSEL & APhase_HWRITE & APhase_HTRANS[1])
	 begin
		if(byte0)
			memory[APhase_HADDR[MEMWIDTH:2]][7:0] <= HWDATA[7:0];
		if(byte1)
			memory[APhase_HADDR[MEMWIDTH:2]][15:8] <= HWDATA[15:8];
		if(byte2)
			memory[APhase_HADDR[MEMWIDTH:2]][23:16] <= HWDATA[23:16];
		if(byte3)
			memory[APhase_HADDR[MEMWIDTH:2]][31:24] <= HWDATA[31:24];
	  end
  end

  其中这一段，是将程序文件预加载到硬件中，因为要将生成的软件程序镜像文件与硬件文件合并。但是为什么这里memory加载了软件程序后还能赋值HWDATA呢？ 后续揭晓

 initial
  begin
(*rom_style="block"*)	 $readmemh("code.hex", memory);
  end

2.6 AHB LED外设

  将写数据的低八位显示在8个LED灯上

module AHB2LED(
	//AHBLITE INTERFACE
		//Slave Select Signals
			input wire HSEL,
		//Global Signal
			input wire HCLK,
			input wire HRESETn,
		//Address, Control & Write Data
			input wire HREADY,
			input wire [31:0] HADDR,
			input wire [1:0] HTRANS,
			input wire HWRITE,
			input wire [2:0] HSIZE,
			
			input wire [31:0] HWDATA,
		// Transfer Response & Read Data
			output wire HREADYOUT,
			output wire [31:0] HRDATA,
		//LED Output
			output wire [7:0] LED
);

//Address Phase Sampling Registers
  reg rHSEL;
  reg [31:0] rHADDR;
  reg [1:0] rHTRANS;
  reg rHWRITE;
  reg [2:0] rHSIZE;

  reg [7:0] rLED;
 
//Address Phase Sampling
  always @(posedge HCLK or negedge HRESETn)
  begin
	 if(!HRESETn)
	 begin
		rHSEL		<= 1'b0;
		rHADDR	<= 32'h0;
		rHTRANS	<= 2'b00;
		rHWRITE	<= 1'b0;
		rHSIZE	<= 3'b000;
	 end
    else if(HREADY)
    begin
      rHSEL		<= HSEL;
		rHADDR	<= HADDR;
		rHTRANS	<= HTRANS;
		rHWRITE	<= HWRITE;
		rHSIZE	<= HSIZE;
    end
  end

//Data Phase data transfer
  always @(posedge HCLK or negedge HRESETn)
  begin
    if(!HRESETn)
      rLED <= 8'b0000_0000;
    else if(rHSEL & rHWRITE & rHTRANS[1])
      rLED <= HWDATA[7:0];
  end

//Transfer Response
  assign HREADYOUT = 1'b1; //Single cycle Write & Read. Zero Wait state operations

//Read Data  
  assign HRDATA = {24'h0000_00,rLED};

  assign LED = rLED;

endmodule
一叽咕咕咕
关注
  • 11
    点赞
  • 踩
  • 63
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
ARM公司的Cortex-M0概况介绍
uunubt的专栏
08-19 6545
概况 ARM公司的Cortex-M0应用于各种微控制器（MCU）中，并可让研发工程师以8位的价位创造32位的的效能，并将传统的8位和16位的处理器升级到更高效、更低功耗的32位处理器。 Cortex-M0是Cortex-M家族中的M0系列。最大特点是低功耗的设计。Cortex-M0为32位、3级流水线RISC处理器，其核心仍为冯.诺依曼结构，是指令和数据共享同一总线的架构。作为新一代的处理器，...
ARM M0开源HDL
最新发布
生活需要深度
05-02 465
参考相关资料，根据AMBA总线协议规范写了AHBDCD.v、AHBMUX.v、AHB2MEM.v、AHB2LED.v、AHBLITE_SYS.v五个Verilog 接口，分别是解码器、多路选择器、存储器、LED以及顶层模块。包括APB和AHB各个信号的名称及内涵、总线互联关系、总线操作方法、基本传输、传输类型、突发操作、控制信号、地址译码、从机传输相应、数据总线、总裁、复位等内容。Cortex-M0是ARM公司的一款开源内核，以低功耗著称，本文提纲挈领的讲述了用FPGA实现SOPC的流程。
ARM cortex M0+ introduction
Andy的博客
01-06 1908
cortex M0
【ARM Cortex-M 系列 1 -- Cortex-M0, M3, M4, M7, M33, M35P 差异】
热门推荐
CodingCos的博客
07-18 1万+
Cortex-M0 是 ARM 公司推出的一款微控制器（MCU）核心。这个核心是基于ARMv6-M架构设计的，只支持 56 条指令的小指令集，大部分指令是 16 位指令, 是 ARM Cortex-M 系列中的入门级产品。Cortex-M0 的设计目标是提供一种低成本、低功耗的解决方案，适用于简单的微控制器应用。它的特点包括：小型和低功耗：Cortex-M0 的硬件设计非常紧凑，消耗的功率也非常低，这使得它非常适合在功率和空间受限的应用中使用。简单的指令集：Cortex-M0 使用的是。
ARM Cortex-M0原理与应用实践
01-29
ARM Cortex-M0原理与应用实践
1167_ARM CORTEX-M0了解
小灰笔记
02-17 1640
全部学习汇总：https://github.com/GreyZhang/g_arm_cores CORTEX-M0的内核是一个32bit的RISC指令集架构。 早期的ARM设计其实是在PC领域的，但是随着ARM在比如说手机这样的电池供电的系统中越来越流行的时候，ARM也开始向MCU转换。ARM7可能是最早用于设计MCU的一个内核，自带RAM、Flash以及一些其他的外设。而Atmel AT91以及ST的STR7可能是最早一批使用ARM核做MCU设计的。 ...
ARM Cortex-M架构基本概念
blueblue_ya的博客
06-12 1789
R13寄存器可以作为stack pointer，SP用于记录当前堆栈的地址，当在不同任务中切换时，SP用于保存上下文（一般来说，SP寄存器中的地址是当前正在执行的指令所在的地址）Cortex-m0中可以将SP细化成MSP和PSP：在应用程序中，需要特权访问时使用MSP，例如异常访问和系统内核访问；R14可用于链式寄存器，主要功能:（1）用于保存子程序或者一个程序调用的返回地址 （2）当程序调用结束后，将LR中的返回地址加载到程序计数器(PC)中。(1)R0-R7可以被任意指令访问。
RN7213是ARM Cortex-M0内核的电表SOC芯片带LCD驱动 采样速度快，开发例程齐全，有参考方案-应用笔记.zip
09-03
1. **高性能ARM Cortex-M0内核**：Cortex-M0内核提供了高效的32位计算能力，同时保持了低功耗的特点，适合长时间运行的电表应用。 2. **内置LCD驱动器**：集成的LCD驱动器使得RN7213可以直接驱动液晶显示屏，简化了...
RN7213是ARM Cortex-M0内核的电表SOC芯片带LCD驱动 采样速度快，开发例程齐全，有参考方案-应用笔记2016.zip
09-03
ARM Cortex-M0是ARM公司推出的低功耗、高性能的微控制器系列，针对嵌入式应用设计，具有易于编程、高代码密度和低功耗的特性。RN7213选择Cortex-M0作为核心，意味着它能在保证计算性能的同时，保持较低的功耗，这...
RN7213是ARM Cortex-M0内核的电表SOC芯片带LCD驱动 采样速度快，开发例程齐全，有参考方案-RN721X手册.zip
09-03
RN7213是一款基于ARM Cortex-M0内核的高性能微控制器，专为电能计量应用而设计。这款SOC（System on Chip）芯片集成了多种功能，以满足现代智能电表的需求。Cortex-M0是ARM公司推出的低功耗、高效率的处理器核心，...
eetop.cn_数据结构(C语言版).part2.rar
08-20
ARM Cortex-M0 全可编程SoC原理及实现 面向处理器、协议、外设、编程和操作系统.pdf
免费学习ARM_M0相关知识.zip
07-23
来自于OPENCORE的Verilog语言的embedded_risc软核 SOC设计，包含比较多的内容。可以作为学习参考代码。比较有价值 顶层文件描述： MODULE:  Top Level System On A Chip Design FILE NAME: soc.v DATE:  May 7th, 2002 AUTHOR:  Hossein Amidi COMPANY: CODE TYPE: Register Transfer Level DESCRIPTION: This module is the top level RTL code of System On a Chip Verilog code. It will instantiate the following blocks in the ASIC: 1)   Vertex STARTUP 2) DLL 3) RISC uProcessor 4) DMA Cntrl 5) LRU Data Cache 6) LRU Instruction Cache 7) Bus Arbiter 8) UART 9) Timer 10)  Flash Controller 11) SDRAM Controlle
RN7213是ARM Cortex-M0内核的电表SOC芯片带LCD驱动 采样速度快，开发例程齐全，有参考方案-RN821x_RN831x_RN721x应用笔记003-库函数使用说明v1.1.zip
09-03
RN7213是一款基于ARM Cortex-M0内核的高性能电能计量系统级芯片（SoC），特别适用于智能电表的开发。这款芯片集成了快速的采样电路，能够准确、高效地处理电能数据，确保电表测量的精确性。同时，RN7213还内置了LCD...
关于ARM的内核架构
weixin_30527143的博客
02-08 1969
很多时候我们都会对M0，M0+,M3,M4，M7，arm7，arm9，CORTEX-A系列，或者说AVR,51，PIC等，一头雾水，只知道是架构，不知道具体是什么，有哪些不同？今天查了些资料，来解解惑，不是很详细，但对此有个大体了解。咱先来当下最火的ARM吧 1.ARM ARM即以英国ARM（Advanced RISC Machines）公司的内核芯片作为CPU，同时附加其他外围功能的嵌入式开...
MCU学习笔记_ARM Cortex M0_简介
GloriaHuo's Blogs
03-31 2735
MCU学习笔记 ARM Cortex M0 1. RM的CPU core 的基本概念 2. ARM Cortex M0组成架构 3. Cortex-M0 Processo 1. ARM的CPU core 的基本概念 A系列：手机上应用;应用于high end application processor; cortex_A5, cortex_A8, cortex_A9, cortex_A19等 R系列：路由器，汽车等; 应用于高性能的实时系统（high performance real-time syst
ARM探索之旅 | 一、带你认识ARM Cortex-M阵营
Mculover666的博客（嵌入式）
05-24 3139
引言 笔者接触嵌入式领域软件开发已近五年，几乎用的都是 ARM Cortex M 内核系列的微控制器。在这五年期间，感谢C语言编译器的存在，让我不用接触汇编即可进行开发，但是彷佛也错过了一些风景，没有领域到编译器之美和CPU之美，所以决定周末无聊的休息时间通过寻找资料、动手实验、得出结论的方法来探索 ARM CPU 架构的美妙，以及C语言编译器的奥秘。（因为我个人实在是不赞同学校中微机原理类课程的教学方法）。 一、ARM CPU Architecture ARM CPU架构是一个用于计算机处理器的精简指令集
FPGA 串口中断_敏矽微电子Cortex-M0学习笔记15-看门狗定时中断实例
weixin_39670511的博客
10-22 258
学习笔记1、看门狗时钟在上一章节的学习中，我们使用了看门狗的系统复位功能，通过触摸按键触发喂狗的方式，演示了看门狗的复位功能。这一章节再讲解下看门狗的定时中断功能。既然提到了定时功能，那就需要先介绍下看门狗的时钟系统。看门狗定时器模块使用两个时钟：PCLK和WDCLK。PCLK由系统时钟生成，供APB 访问看门狗寄存器使用。WDCLK由看门狗时钟振荡器中的wdt_clk生成，供看门狗定时器计数使用...
【学习笔记】基于Arm Cortex-M0 DesignStart Eval设计SOC（一）
m0_66764513的博客
01-31 5911
一、简介 本项目是使用Arm Cortex-M0 Designstart Eval进行开发，以下内容来自Arm Cortex-M0 DesignStart Eval User Guide。 点击此处下载Arm Cortex-M0 Designstart Eval 开发环境： Win10、MDK5、TD(Tang Dynasty)、安路EG4S20 FPGA开发板 二、Designstart Eval文件介绍 点击上方链接申请Arm Cortex-M0 Designstart Eval后，得到一个
arm cortex-m0 全可编程soc原理及实现
06-28
### 回答1： ARM Cortex-M0是一种全可编程的SOC（系统级芯片），它的原理是将处理器、内存、外设等多个功能模块集成在一个芯片上，实现了高度集成化的设计。Cortex-M0采用了ARM架构，具有低功耗、高性能、易于编程等特点，广泛应用于物联网、智能家居、工业控制等领域。 实现Cortex-M0 SOC需要进行多个步骤，包括设计芯片架构、选择器件、编写软件等。首先，需要确定芯片的功能需求和性能指标，设计出合适的架构。然后，选择适合的器件，包括处理器、存储器、外设等，进行芯片的布局和布线。最后，编写软件，包括底层驱动程序、操作系统、应用程序等，实现芯片的功能。 总之，ARM Cortex-M0全可编程SOC的实现需要进行多个步骤，包括芯片架构设计、器件选择和软件编写等，需要具备丰富的硬件和软件开发经验。 ### 回答2： ARM Cortex-M0是一种精简型微控制器（MCU）的处理器核心，广泛应用于普通消费电子产品、智能物联网、低功耗应用等多个领域。ARM Cortex-M0采用3级流水线的指令执行架构和16/32位的总线结构，在搭载外设、调度内部资源和处理I/O操作等方面表现优异，同时还具有低功耗性、强大的数据处理能力和高效的价格性能比。ARM Cortex-M0 全可编程SOC原理及实现正是基于ARM Cortex-M0处理器核心的MCU核心，具有以下几个关键特征： 首先，ARM Cortex-M0全可编程性是其最大的特点之一。SOC的可编程性通常包括芯片基础可编程、可重构逻辑实现和可编程存储器等，ARM Cortex-M0采用的可编程方案是基于其流水线架构和编程模型。MCU核心芯片通过开放的软件编程接口（API）向外界提供可编程的开放式体系结构。这样，用户可以将其功能需求通过编程进行灵活的配置和扩展。 其次，ARM Cortex-M0全可编程SOC依赖于外设和内核资源的完美协调。ARM Cortex-M0全可编程SOC一般被设计成包括多个IO、通信、控制和运算等外设单元，同时还包括中央处理单元（CPU）、DMA控制器、定时器和触摸控制器等多种内核资源。这些内核资源和外设单元靠编程方式连接到一起，CPUCPU通过中断机制、DMA控制器与I/O设备直接交换数据，实现了数据在外设间的传输，提高系统运行效率。 最后，ARM Cortex-M0全可编程SOC的实现依赖于设计工具和技术的支持。ARM Cortex-M0全可编程SOC的实现需要用到各种先进的技术和设计工具，如芯片设计技术、加密算法和嵌入式软件开发技术等。此外，各种先进的设计工具如MATLAB、Cortex-M0开发板和仿真工具等可以帮助开发者轻松实现ARM Cortex-M0全可编程SOC的各项功能，提高产品的研发速度和效率。 总之，ARM Cortex-M0全可编程SOC是基于现有技术和芯片设计工具，依托ARM Cortex-M0处理器核心、外设和高效的软件编程接口（API）实现的一种全可编程型微控制器（MCU）核心。其优势在于灵活的编程体验、高效的数据传输能力和图形化的编程工具支持，从而为设计者提供了更多的创意空间和产品实现方案。 ### 回答3： ARM Cortex-M0全可编程SOC是一种低功耗的嵌入式处理器系统。该处理器系统包含了ARM的Cortex-M0内核，还包括了片上内存、外设、以及通信接口等。其实现方式可以分为两个方面：硬件实现和软件实现。 硬件实现方面，ARM Cortex-M0全可编程SOC采用了先进的28纳米工艺，以及一些先进的设备。在系统中，ARM Cortex-M0内核与片上外设之间通过总线进行连接。而通信接口则是通过串口或者USB实现，在系统设计过程中可以根据需求选择适合的通信接口。此外，该系统还包含有SRAM，FLASH等片上内存组件。其中，SRAM是用于存储栈空间、寄存器和其他变量的，而FLASH则是用于存储应用程序和数据的。 软件实现方面，ARM Cortex-M0全可编程SOC通过ARM的软件开发工具链进行开发。其中，主要的开发工具包括C/C++编译器、调试器、仿真器等。系统设计者可以使用这些工具进行应用程序的编译、调试和仿真等操作。此外，还可以使用ARM的软件库来加速应用程序的开发。这些软件库包括CMSIS（Cortex Microcontroller Software Interface Standard）、HAL（Hardware Abstraction Layer）等。这些库提供了许多已经被验证的软件组件，可以使系统设计者更加快速、简单地开发基于ARM Cortex-M0全可编程SOC的应用程序。 总之，ARM Cortex-M0全可编程SOC可以提供强大的处理性能、通信接口和片上外设，同时还可以基于ARM的开发工具链和软件库快速地开发应用程序。这使得它成为了众多嵌入式设备的理想选择。
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值