FPGA人脸识别检测（先获取人脸图像以及灰度二值化）

已于 2024-04-05 21:47:19 修改
阅读量746 收藏 14
点赞数 7
分类专栏： 图像处理算法 文章标签： 计算机视觉 图像处理 人工智能
于 2024-03-14 17:53:48 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_46312715/article/details/136717178
版权

读取图片的方式按照博客咸鱼里的方式来做，如下。

1、先用matlab将图片转换成txt数据，代码如下 

%==========================================================================
%                 彩色图片转为txt文本，格式为24bit的hex数据
%==========================================================================
clc;
clear all;
%--------------------------------------------------------------------------
pre_img = imread('pre_img.jpg');   %读取图片文件
[ROW,COL,N] = size(pre_img);       %获得图片尺寸[高度，长度，维度]
RGB_ij = uint64(zeros(ROW,COL));   %定义32位宽的RGB变量
%--------------------------------------------------------------------------
fid = fopen('pre_img.txt','w');    %打开文件
for i = 1:ROW
    for j = 1:COL
        R = double(pre_img(i,j,1));
        G = double(pre_img(i,j,2));
        B = double(pre_img(i,j,3));
        %-------------------------------------
        RGB          = R*(2^16) + G*(2^8) + B;
        RGB_ij(i,j)  = RGB;
        RGB_hex      = dec2hex(RGB);
        %-------------------------------------
        fprintf(fid,'%s\n',RGB_hex); %将字符打印到txt文件
    end
end
fclose(fid);
%--------------------------------------------------------------------------
imshow(pre_img),title('处理前');      %查看处理前的图片

2、FPGA读取txt数据 

`timescale 1 ns/1 ns

module img_gen
//========================< 参数 >==========================================
//					  640x480 @60Hz 25Mhz
#(
parameter H_ADDR			= 640					,	//行有效数据	  
parameter H_SYNC			= 96					,	//行同步  
parameter H_BACK			= 48					,	//行显示后沿
parameter H_TOTAL			= H_ADDR+H_SYNC+H_BACK	,	//行扫描周期
parameter V_ADDR			= 480					,	//场有效数据	  
parameter V_SYNC			= 2						,	//场同步	
parameter V_BACK			= 33					,	//场显示后沿
parameter V_TOTAL			= V_ADDR+V_SYNC+V_BACK		//场扫描周期
)
//========================< 端口 >==========================================
(
//system --------------------------------------------
input	wire				clk						,	//时钟
input	wire				rst_n					,	//复位，低电平有效
//img output ----------------------------------------
output	wire				img_hsync				,	//img行信号
output	wire				img_vsync				,	//img场信号
output	reg  	[23:0]		img_data				,	//img数据信号
output	reg					img_de						//img数据有效指示信号
);
//========================< 信号 >==========================================
reg	  	[15:0]				cnt_h				 	;
wire						add_cnt_h				;
wire						end_cnt_h				;
reg	  	[15:0]				cnt_v					;
wire						add_cnt_v				;
wire						end_cnt_v				;
//---------------------------------------------------
reg  	[23:0] 				ram [H_ADDR*V_ADDR-1:0]	;
reg 	[31:0] 				i						;
//==========================================================================
//==	行、场计数
//==========================================================================
always @(posedge clk or negedge rst_n) begin
	if(!rst_n)
		cnt_h <= 0;
	else if(add_cnt_h) begin
		if(end_cnt_h)
			cnt_h <= 0;
		else
			cnt_h <= cnt_h + 1;
	end
end

assign add_cnt_h = 1;
assign end_cnt_h = add_cnt_h && cnt_h==H_TOTAL-1;
//---------------------------------------------------
always @(posedge clk or negedge rst_n) begin 
	if(!rst_n)
		cnt_v <= 0;
	else if(add_cnt_v) begin
		if(end_cnt_v)
			cnt_v <= 0;
		else
			cnt_v <= cnt_v + 1;
	end
end

assign add_cnt_v = end_cnt_h;
assign end_cnt_v = add_cnt_v && cnt_v==V_TOTAL-1;
//==========================================================================
//==	输出
//==========================================================================
//行场同步
//---------------------------------------------------
assign img_hsync = (cnt_h <= H_SYNC - 1) ? 0 : 1;
assign img_vsync = (cnt_v <= V_SYNC - 1) ? 0 : 1;

//数据请求
assign img_req = (cnt_h >= H_SYNC + H_BACK - 1) && (cnt_h < H_SYNC + H_BACK + H_ADDR - 1) &&
				 (cnt_v >= V_SYNC + V_BACK	  ) && (cnt_v < V_SYNC + V_BACK + V_ADDR    );

//读取txt文件到raw数组中,格式为16进制
//---------------------------------------------------
initial begin
	$readmemh("C:/Users/xiaozhou/Desktop/people_face/matlab/pre_img.txt", ram);
end

//数据输出
//---------------------------------------------------
always@(posedge clk or negedge rst_n) begin
	if(!rst_n)begin
		img_data <= 24'd0;
		i <= 0;
	end
	else if(img_req) begin
		img_data <= ram[i];
		i <= i + 1;
	end
	else if(i==H_ADDR*V_ADDR) begin
		img_data <= 24'd0;
		i <= 0;
	end
end

//数据使能
always @(posedge clk) begin 
	img_de <= img_req;
end


endmodule

由于顶层模块传给img_gen的H_ADDR和V_ADDR分别是480和272（而不是原来的640和480），在行计数器在96+48=144和480+96+48-1=623之间，以及场计数器33+2=35和272+33+2-1=306之间的时候，使能信号拉高。 

当行计数器为0~95时为低电平（行同步期间）， 当行计数器为0~1时为低电平（场同步期间）。

3、FPGA灰度二值化 


module RGB565_YCbCr444_face
//========================< 端口 >==========================================
(
input   wire                clk                     ,
input   wire                rst_n                   ,
//input ---------------------------------------------
input   wire                RGB_de                  ,
input   wire                RGB_hsync               ,
input   wire                RGB_vsync               ,
input   wire    [15:0]      RGB_data                , //RGB像素
//output --------------------------------------------
output  wire                face_de                 ,
output  wire                face_hsync              ,
output  wire                face_vsync              ,
output  reg     [15:0]      face_data                 //灰度像素
);
//========================< 信号 >==========================================
wire    [ 7:0]              R0, G0, B0              ;
reg     [15:0]              R1, G1, B1              ;
reg     [15:0]              R2, G2, B2              ;
reg     [15:0]              R3, G3, B3              ;
reg     [15:0]              Y1, Cb1, Cr1            ;
reg     [ 7:0]              Y2, Cb2, Cr2            ;
reg     [ 3:0]              RGB_de_r                ;
reg     [ 3:0]              RGB_hsync_r             ;
reg     [ 3:0]              RGB_vsync_r             ;
//==========================================================================
//==    RGB565转RGB888
//==========================================================================
assign R0 = {RGB_data[15:11],RGB_data[13:11]};
assign G0 = {RGB_data[10: 5],RGB_data[ 6: 5]};
assign B0 = {RGB_data[ 4: 0],RGB_data[ 2: 0]};
//==========================================================================
//==    RGB888转YCbCr
//==========================================================================
//clk 1
//---------------------------------------------------
always @(posedge clk or negedge rst_n) begin
    if(!rst_n)begin
        {R1,G1,B1} <= {16'd0, 16'd0, 16'd0};
        {R2,G2,B2} <= {16'd0, 16'd0, 16'd0};
        {R3,G3,B3} <= {16'd0, 16'd0, 16'd0};
    end
    else begin
        {R1,G1,B1} <= { {R0 * 16'd77},  {G0 * 16'd150}, {B0 * 16'd29 } };
        {R2,G2,B2} <= { {R0 * 16'd43},  {G0 * 16'd85},  {B0 * 16'd128} };
        {R3,G3,B3} <= { {R0 * 16'd128}, {G0 * 16'd107}, {B0 * 16'd21 } };
    end
end

//clk 2
//---------------------------------------------------
always @(posedge clk or negedge rst_n) begin
    if(!rst_n)begin
        Y1  <= 16'd0;
        Cb1 <= 16'd0;
        Cr1 <= 16'd0;
    end
    else begin
        Y1  <= R1 + G1 + B1;
        Cb1 <= B2 - R2 - G2 + 16'd32768; //128扩大256倍
        Cr1 <= R3 - G3 - B3 + 16'd32768; //128扩大256倍
    end
end

//clk 3，除以256即右移8位，即取高8位
//---------------------------------------------------
always @(posedge clk or negedge rst_n) begin
    if(!rst_n)begin
        Y2  <= 8'd0;
        Cb2 <= 8'd0;
        Cr2 <= 8'd0;
    end
    else begin
        Y2  <= Y1[15:8];  
        Cb2 <= Cb1[15:8];
        Cr2 <= Cr1[15:8];
    end
end

//clk 4，人脸肤色检测
//---------------------------------------------------
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        face_data <= 'h0;
    end
    else if( (Cb2 > 77) && (Cb2 < 127) && (Cr2 > 133) && (Cr2 < 173) ) begin
        face_data <= 16'hffff;
    end
    else begin
        face_data <= 'h0;
    end
end
//==========================================================================
//==    信号同步
//==========================================================================
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        RGB_de_r    <= 4'b0;
        RGB_hsync_r <= 4'b0;
        RGB_vsync_r <= 4'b0;
    end
    else begin  
        RGB_de_r    <= {RGB_de_r[2:0],    RGB_de};
        RGB_hsync_r <= {RGB_hsync_r[2:0], RGB_hsync};
        RGB_vsync_r <= {RGB_vsync_r[2:0], RGB_vsync};
    end
end

assign face_de    = RGB_de_r[3];
assign face_hsync = RGB_hsync_r[3];
assign face_vsync = RGB_vsync_r[3];



endmodule

  

使能信号和行场同步信号，均打了四拍 （上两图）。

RGB转YCbCr打了三拍（上图）；二值化打了一拍（下图）。加起来总共打了四拍。

4、FPGA顶层模块及仿真

`timescale 1 ns/1 ns

module top
//========================< 参数 >==========================================
#(
parameter 		 			IMG_H = 480				,	//图像长度
parameter 		 			IMG_V = 272		 			//图像高度
)
//========================< 端口 >==========================================
(
input   wire                clk                 	, 	//时钟
input   wire                rst_n               	, 	//复位，低电平有效
//---------------------------------------------------
output	wire				VGA_hsync				,	//VGA行同步
output	wire				VGA_vsync				,	//VGA场同步
output  wire    [23:0]      VGA_data				,	//数据
output	wire				VGA_de						//数据有效
);
//========================< 信号 >==========================================
wire                        img_hsync				;
wire                        img_vsync				;
wire    [23:0]              img_data				;
wire                        img_de					;
//face ----------------------------------------------
wire                        face_de                 ;
wire                        face_hsync              ;
wire                        face_vsync              ;
wire    [15:0]              face_data               ;

//==========================================================================
//==                        图像数据产生
//==========================================================================
img_gen
#(
	.H_ADDR					(IMG_H					),	//图像宽度
	.V_ADDR					(IMG_V					)	//图像高度
)
u_img_gen
(
    .clk                    (clk              		), 
    .rst_n                  (rst_n					),
    //-----------------------------------------------
    .img_hsync              (img_hsync              ),  //img输出行同步
    .img_vsync              (img_vsync              ),  //img输出场同步
    .img_data               (img_data               ),  //img输出数据
	.img_de					(img_de					)	//img输出数据有效指示
);
//==========================================================================
//==            RGB565转YCbCr444，再转人脸肤色检测
//==========================================================================
RGB565_YCbCr444_face u_RGB565_YCbCr444_face
(
    .clk                    (clk                    ),
    .rst_n                  (rst_n                  ),
    //原图 ------------------------------------------
    .RGB_de                 (img_de                 ),
    .RGB_hsync              (img_hsync              ),
    .RGB_vsync              (img_vsync              ),
    .RGB_data               ({img_data[23:19],img_data[15:10],img_data[7:3]}),
    //肤色图 ----------------------------------------
    .face_de                (face_de                ),
    .face_hsync             (face_hsync             ),
    .face_vsync             (face_vsync             ),
    .face_data              (face_data              )
);

assign VGA_de 		= 		face_de;
assign VGA_hsync 	= 		face_hsync;
assign VGA_vsync 	= 		face_vsync;

assign VGA_data  	= 		{	face_data[15:11],face_data[13:11],
								face_data[10: 5],face_data[ 7: 5],
								face_data[ 4: 0],face_data[ 2: 0]
							};




endmodule
`timescale 1ns/1ns  //时间精度
`define    Clock 20 //时钟周期
//--------------------------------------------------------------------------------RGB转YCbCr------------------------------------------------------------------------------
module top_tb;
//========================< 参数 >==========================================
parameter                   IMG_H = 480         	;   //图像长度
parameter                   IMG_V = 272         	;   //图像高度
//========================< 信号 >==========================================
reg                         clk                     ; //时钟，50Mhz
reg                         rst_n                   ; //复位，低电平有效
wire                        VGA_hsync               ; //VGA行同步
wire                        VGA_vsync               ; //VGA场同步
wire    [23:0]              VGA_data                ; //数据
wire                        VGA_de                  ; //数据有效
//==========================================================================
//==    模块例化
//==========================================================================
top
#(
    .IMG_H                  (IMG_H                  ),
    .IMG_V                  (IMG_V                  )
)
u_top
(
    .clk                    (clk                    ),
    .rst_n                  (rst_n                  ),
    .VGA_hsync              (VGA_hsync              ),
    .VGA_vsync              (VGA_vsync              ),
    .VGA_data               (VGA_data               ),
    .VGA_de                 (VGA_de                 )
);
//==========================================================================
//==    时钟信号和复位信号
//==========================================================================
initial begin
    clk = 1;
    forever
        #(`Clock/2) clk = ~clk;
end

initial begin
    rst_n = 0; #(`Clock*20+1);
    rst_n = 1;
end
//==========================================================================
//==    图像数据转变为txt文本
//==========================================================================

//打开post_img.txt文件
//---------------------------------------------------
integer post_img_txt;

initial begin
    post_img_txt = $fopen("C:/Users/xiaozhou/Desktop/people_face/matlab/gray_img.txt");
end

//像素写入到txt中
//---------------------------------------------------
reg [20:0] pixel_cnt;

always @(posedge clk) begin
    if(!rst_n) begin
        pixel_cnt <= 0;
    end
    else if(VGA_de) begin
        pixel_cnt = pixel_cnt + 1;
        $fdisplay(post_img_txt,"%h",VGA_data);
		
        if(pixel_cnt == IMG_H*IMG_V)
            $stop;
    end
end


endmodule

5、通过modelsim将操作后的图片数据写入gray_img.txt里面后，用matlab将txt转成图片。代码如下

%==========================================================================
%                txt文本中24bit数据还原为彩色图片
%==========================================================================
clear all;
clc;
%--------------------------------------------------------------------------
ROW = 272;  %高度
COL = 480;  %宽度
N   = 3;    %维度
post_img = uint8(zeros(ROW,COL,N));
%--------------------------------------------------------------------------
fid = fopen('gray_img.txt','r');
for i = 1:ROW
    for j = 1:COL
        value = fscanf(fid,'%s',1);
        %------------------------------------------
        post_img(i,j,1) = uint8(hex2dec(value(1:2)));
        post_img(i,j,2) = uint8(hex2dec(value(3:4)));
        post_img(i,j,3) = uint8(hex2dec(value(5:6)));  
    end 
end
fclose(fid);
%--------------------------------------------------------------------------
pre_img = imread('pre_img.jpg');
subplot(121);imshow(pre_img), title('处理前');
subplot(122);imshow(post_img),title('处理后');
%--------------------------------------------------------------------------
imwrite(post_img,'gray_img.jpg');   %处理后的图片输出为jpg格式

以下是效果图： 

由于图片有空洞、噪声等缺陷，所以后面要进行中值滤波、闭运算（先膨胀后腐蚀）等算法处理，然后再对人脸进行框选，最后显示出来。

中值滤波图片 

 

闭运算（先膨胀后腐蚀）图片 

 

框选后，最终的成像是下面这样的。

小熊在忙fpga
关注
  • 7
    点赞
  • 踩
  • 14
    收藏
    觉得还不错? 一键收藏
  • 2
    评论
专栏目录
FPGA图像识别与目标跟踪系统
11-10
文档介绍了 运用FPGA技术和图像处理技术，在目标跟踪系统中的应用！
基于fpga的图像识别与跟踪系统的说明文档
04-24
基于fpga的图像识别与跟踪系统的说明文档，对基于fpga的图像识别与跟踪系统的设计做了比较详尽的说明。
基于FPGA的人脸识别系统（纯Verilog，有注释）
10-19
1、工程用的是Altera的EP4CE10芯片，纯Verilog设计，可以移植到任何FPGA 2、ov7725摄像头，VGA显示屏，可以直接烧录，看现象 3、所有代码均有注释。 4、Quartus II工程 可用毕设或者竞赛项目
基于FPGA的实时图像边缘检测系统设计（上）
07-03 5292
今天给大侠带来基于FPGA的实时图像边缘检测系统设计，由于篇幅较长，分三篇。今天带来第一篇，上篇，话不多说，上货。 导读 随着科学技术的高速发展，FPGA在系统结构上为数字图像处理带来了新的契机。图像中的信息并行存在，因此可以并行对其施以相同的操作，使得图像处理的速度大大提高，这正好适合映射到FPGA架构中用硬件算法得以实现。 本篇阐述了基于FPGA设计一个能够实时采集、实时处理并实时显示的数字图像处理系统的设计思想和流程，分析了摄像头接口的时序；阐述了图像...
基于肤色模型的人脸识别FPGA实现,包含tb测试文件和MATLAB辅助验证
最新发布
MATLAB,verilog,python,opencv,tensorflow,caffe,C,C++
05-01 878
肤色模型通常定义在特定的颜色空间中，常见的有RGB、HSV、YCbCr、Lab等。在这些颜色空间中，YCbCr因其能较好地分离亮度（Y）和色度信息（Cb和Cr），常被用于肤色检测。肤色模型可以是简单的阈值方法，也可以是复杂的概率模型，如高斯模型或混合高斯模型。对于给定的像素点Cbi​,Cri​)，可以通过计算其在肤色模型下的概率密度值来判断是否属于肤色区域。如果该值超过某一阈值T，则认为该像素属于肤色区域：在肤色检测之前，通常需要对图像进行预处理，如灰度化、去噪、光照补偿等，以减少环境因素的干扰。
FPGA高端项目：FPGA帧差算法图像识别+目标跟踪，提供11套工程源码和技术支持
qq_41667729的博客
11-04 8336
FPGA高端项目：FPGA帧差算法图像识别+目标跟踪，提供7套工程源码和技术支持
基于FPGA的图像边缘检测
zhangningning1996的博客
04-09 5810
Sobel算法的FPGA实现项目简洁图像边缘Sobel算法介绍Sobel算法的FPGA实现3x3矩形窗的构建矩阵构建模块代码Sobel算法实现及代码Sobel模块的测试代码仿真结果项目程序实验结果总结 项目简洁 图像的边缘检测在图像处理中非常常见，因为可以去除一些冗余的信息，然后给后续的处理带来方便。本次实验的主要内容是，PC机通过千兆网发送一副1024*768分辨率的图片到FPGA开发板的DDR...
FPGA|数字图像处理实现口罩识别——二值化
mintshoot_的博客
10-19 1332
二值化即将灰度值（光亮值）和设定的阈值比较，比较结果以0和1的形式存入monoc中。0和1只是比较的结果，不是像素的实际灰度值。我们在前面使用了一个时钟周期进行二值化，相应的同步信号也应该延迟一个时钟周期，从而实现数据的同步。表示扫描1帧的开始，一帧也就是LCD显示的一个画面。PCLK：像素时钟，时最小时钟单位，控制整个程序的运行进程。（还有一种方法是一个自适应阈值二值化方法，在这里未使用）ENABLE：数据使能，为1时才能接受数据，为0时不能。HSYNC：行同步信号。表示扫描1行的开始。
基于FPGA的人脸识别工程源码
07-21
基于FPGA的人脸识别工程源码
图像二值化开运算 fpga
04-26
开运算就是先进行腐蚀然后进行膨胀，这样操作后可以使得原本连接在一起的区域，变成了不连通的区域。主要针对细小的突起、细的连接线、图像中的弯口、孤立的小块或齿状物体的效果明显
FPGA实现目标识别
09-05
通过FPGA实现目标的检测，利用FPGA的并行处理能力实现大量数据的吞吐，体现了FPGA的价值与硬件特点，相比较与单片机的优势
[b115]FPGA上运行人脸识别源代码.zip
07-11
FPGA上运行人脸识别源代码，This project attempts to realize a face detector using Voila-Jones algorithm. The reference C model is borrowed from [5kk73 GPU Assignment 2012](https://sites.google.com/site/5kk73gpu2012/assignment/viola-jones-face-detection), with some modify to fit hardware implementation and fixed some bug. The code is written by Verilog/SystemVerilog and Synthesized on Xilinx KintexUltrascale FPGA using Vivado. This code is just experimental for function, a lot of optimization can further be done.
基于FPGA的人脸位置定位的仿真实现
11-27
基于FPGA的人脸识别，在复杂环境中识别人脸肤色，并且提取肤色，完成人脸位置的定位。
基于FPGA的图像处理方法
11-23
基于FPGA的图像识别常用算法的设计，Sobel边缘检测，肤色识别算法，腐蚀膨胀算法，中值滤波算法，均值滤波
基于FPGA的图像识别与跟踪系统 (2013年)
05-13
设计了以FPGA为主芯片对目标物体进行识别与跟踪的系统。采用MT9M011数字图像摄像头采集初始图像;利用基于模型匹配的Sobel边缘检测算法实现对目标物体的识别;运用基于边缘特征检测和基于区域特征检测相结合的跟踪算法实现对目标物体的稳定跟踪。测试结果表明,整个系统能够有效稳定地对目标物体实施跟踪。
FPGA实现人脸识别算法
06-20
FPGA 人脸识别
智能人脸识别算法及其FPGA的实现
05-11
智能人脸识别算法及其FPGA的实现
FPGA驱动摄像头实现人脸识别(基于肤色)
qq_23103023的博客
08-04 7187
FPGA驱动摄像头实现人脸识别(基于肤色) 验证平台：黑金AX309 OV5640 时至今日图像处理已经得到了广泛应用，今天我们来讲一讲利用FPGA结合摄像头来实现一个简单的人脸识别（当然误检率很高，因为是基于肤色的，颜色相近就会被检测）。 话不多说咱们先来简单的分析一下整个检测的流程。咱们是采用VGA进行最终的识别结果显示，也就是画框。摄像头驱动部分就不在多说。流程如下。 #mermaid-svg-cevJgUfsiaeHDOpv .label { font-family: 'trebuch
FPGA 人脸识别 安路
10-07
FPGA（现场可编程门阵列）是一种用于实现数字逻辑电路的可编程芯片。它具有可重构的特性，可以根据不同的应用需求进行灵活配置和重新编程。FPGA被广泛应用于人脸识别领域，因为它具有高度的并行性和计算能力，可以更快地处理复杂的图像数据。在人脸识别应用中，FPGA可以实现图像采集、预处理、特征提取和模式匹配等关键功能，从而实现高效准确的人脸识别。 关于FPGA人脸识别方面的硬件设计方案，有多种选择。其中瑞芯微的RK3399/RK3588 FPGA硬件加速设计方案通过PCIE与FPGA对接，实现了高性能的人脸识别功能。而Intel的Arria 10 FPGA系列也是业界先进的支持DDR4存储器接口的FPGA，可提供更高的存储器性能和数据速率，适合于实现人脸识别应用。 在回答完问题后，以下是几个相关问题: 相关问题: 1. FPGA在人脸识别中的具体应用有哪些？ 2. 除了RK3399/RK3588和Arria 10 FPGA，还有哪些适合人脸识别的FPGA芯片？ 3. FPGA相比其他硬件加速方案，在人脸识别中有哪些优势？

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值