week07day04(powerbi 概况指标体系)

最新推荐文章于 2024-07-11 16:34:57 发布

wawaXixiY

最新推荐文章于 2024-07-11 16:34:57 发布

阅读量396

点赞数 3

分类专栏： python数据分析（正式版）文章标签： powerbi 大数据

本文链接：https://blog.csdn.net/weixin_46659095/article/details/136730958

版权

python数据分析（正式版）专栏收录该内容

28 篇文章 0 订阅

订阅专栏

一. 概况指标体系

1. 经营概况定义：

经营概况是表述公司经营现状的集中性反映，可以让管理决策层快速了解宏观的基本信息，了解当前情况是否是健康的。

2. 业绩类指标

Core 销售额 = SUM('事实 销售信息表'[金额]) 

销售完成率 = 销售额/目标额度

当前存在的问题：

目标额度目前不知道，任务信息表存储了每一天的销售任务，但是日期到了12月
销售表数据截止到2019//8/20，而任务表截止到2019/12/27，两表日期不匹配
所有需要提前计算报表的截止日期

MAXX ( <表>, <表达式> ) 对表中 表达式 找最大值
MAX ( <列名或标量值 1>, [<标量值 2>] ) 写列名，计算一列中的最大值

销售完成率计算：销售额 / 销售目标额

折扣率计算：销售金额 / 吊牌价

Core 销售额 = SUM('事实 销售信息表'[金额])

# 这样写是为了 不受 切片器的影响
最后报表日期 = MAXX(ALL('事实 销售信息表'),'事实 销售信息表'[日期])

Core 销售目标 = SUM('事实 任务信息表'[任务])

# 这是对 任务表的销售目标排的日期进行筛选，以便和销售信息表日期一致
Core 销售目标 View = CALCULATE(
	[Core 销售目标],
	FILTER(
		'维度 日期时间表',
		'维度 日期时间表'[日期] <= [最后报表日期]
	)
)

#计算销售完成率 
Core 销售完成率 = DIVIDE([Core 销售额] , [Core 销售目标 View])

# 折扣率 = 销售金额 / 吊牌价
# SUMX（表，表达式），对表达式那一列进行求和
# SUMX(Sales, Sales[Quantity] * Sales[UnitPrice])

Core 吊牌金额 = SUMX('事实 销售信息表',[吊牌价]*[数量])

Core 折扣率 = DIVIDE([Core 销售额],[Core 吊牌金额])

3. 四核指标

1. 件单价：

每件商品平均卖多少钱

2. 单据数(订单数)：

单据数，企业内部退单会形成订单记录,购买也会形成订单记录，赠品也会形成订单记录，换货也有订单记录

3. 客单价：

平均每个用户一单花多少钱

4. 连带率：

每个客户平均每个订单买多少件

计算口径(量度方法):

全效法 : 所有的订单都要计算 (订单数过多)
负单扣除法 : 把所有的订单数计算 - 负数订单的数量
正单有效法 : 要求计算的时候,只统计有效的整数量的订单数

单据数正单有效法

#销量
Core 销量 = SUM('事实 销售信息表'[数量])


#Core 销量> 0  赠品不计算   Core 销量 >=0 计算赠品价值

单据数 正单有效法 = CALCULATE(
	DISTINCTCOUNT('事实 销售信息表'[订单ID]),
	-- VALUES返回类型是个表,去除重复值
	FILTER(
		VALUES(
			'事实 销售信息表'[订单ID]
         ),
		[Core 销量] > 0
	)
)

客单价正单有效法

# 客单价 = 销售额 / 单据数
# Core 销售额 不管是正单还是 负担 全部计算过的
#单据数 正单有效法  剔除了负单 和 0， [Core 销售额] 是全效法
这两者计算口径不一致



销售额 正单有效法 = CALCULATE(
	[Core 销售额],
	FILTER(
		VALUES(
			'事实 销售信息表'[订单ID]
		),
		[Core 销量] > 0
	)
)


客单价 正单有效法 = DIVIDE([销售额 正单有效法],[单据数 正单有效法])

件单价正单有效法

#件单价 : 销售额 正单有效法 / 销量 正单有效法
销量 正单有效法 = CALCULATE(
	[Core 销量],
	FILTER(
     -- 这里的 values 相当于sql的 group by
		VALUES(
			'事实 销售信息表'[订单ID]
		),
		[Core 销量] > 0
	)
)

-- select 订单ID,sum(数量) as Core 销量 from table group by 订单ID having 销量 > 0;
销量 demo = CALCULATE(
	[Core 销量],
	FILTER( 
		VALUES(
			'事实 销售信息表'[订单ID]
		),
		[Core 销量] > 0
	)
)

件单价 正单有效法 = DIVIDE([销售额 正单有效法] , [销量 正单有效法])

连带率正单有效法

销量 / 订单数（单据数）

#连带率 : 每个用户平均每笔订单 买了 多少件商品
连带率 正单有效法 = DIVIDE([销量 正单有效法],[单据数 正单有效法])

==注意==

如果是不同口径的指标一起混算,那么是错误指标

4. 线下三效指标

店效：
- 总销售额 / 店铺数量
人效
- 总销售额 /总人数
坪效
- 总销售额/ 面积平方

可比店 :

门店开业时间小于或等于当前年份前一年 1月1日前开店的 (2019/8/20,2018/1/1 <=)

不可比店 :

门店开业时间大于或等于当前年份前一年 1月1日前开店的 (2019/8/20,2018/1/1 >)(满年店 , 不满年店)

- 满年店 :

满一年的 (2019/8/20 ~ 2018/8/21)

- 不满年店:

没满一点

-- 新建计算列 放在 '维度 门店信息表'

-- 跨年的店(比如现在是 2024年 , 店铺在2023/12/31号开也算)

可比类型 = 
VAR CurYear = YEAR( [最后报表日期] )
RETURN 
    SWITCH( TRUE(), 
        [开业日期] <= DATE( CurYear-1, 1, 1 ), "可比店",
        [开业日期] <= DATE( CurYear, 1, 1 ), "满年店",
        "非满年店"
    )
    
-- 满年店
可比类型 = 
	VAR CurYear = YEAR( [最后报表日期] )
	VAR MaxDate = MAX('事实 销售信息表'[日期])
	RETURN
		SWITCH(
			TRUE(),
			[开业日期] <= DATE(CurYear-1, 1,1) , "可比店 ",
			[开业日期] <= DATE(YEAR(MaxDate)-1,MONTH(MaxDate),DAY(MaxDate)+1)    ,"满年店",
			"不满年店"
		)

店效代码：

-- 综合的店效 : 销售 / 店铺数量

店效 = CALCULATE(
	DIVIDE([销售额 正单有效法],COUNTROWS('维度 门店信息表'))
)

-- 门店的新手保护期 

店效 可比店  = CALCULATE(
	DIVIDE([销售额 正单有效法],COUNTROWS('维度 门店信息表')),
	'维度 门店信息表'[可比类型] = "可比店",
	'维度 门店信息表'[门店状态] = "营业中"
)

坪效代码：

-- 坪效 = 销售额 / 平方

坪效 可比店  = CALCULATE(
	DIVIDE([销售额 正单有效法],SUM('维度 门店信息表'[门店面积])),
	'维度 门店信息表'[可比类型] = "可比店",
	'维度 门店信息表'[门店状态] = "营业中"
)

人效代码：

-- 人效效 = 销售额 / 人数

人效 可比店  = CALCULATE(
	DIVIDE([销售额 正单有效法],SUM('维度 门店信息表'[店员标配人数])),
	'维度 门店信息表'[可比类型] = "可比店",
	'维度 门店信息表'[门店状态] = "营业中"
)

5.扩展指标

-- 门店数量 : 把 关店去除
-- BLANK() : 空值  NULL
-- 假设当前是2024年  我看的是2023年的数据 ,在2024年的1 2 月份新开了店

门店数 当前 = CALCULATE(
	DISTINCTCOUNT('维度 门店信息表'[门店ID]),
	'维度 门店信息表'[门店状态] = "营业中"
)

门店数 = 
  VAR MaxDate = MAX('维度 日期时间表'[日期]) 
  RETURN
  CALCULATE(		
      [门店数 当前],
      '维度 门店信息表'[开业日期] <= MaxDate,
      OR(
          '维度 门店信息表'[撤店日期] > MaxDate, 
          '维度 门店信息表'[撤店日期] = BLANK()   
      )
  )

6.同期指标

#同期销售额  今年-去年 /去年
-- SAMEPERIODLASTYEAR : 自动返回上一年度 的 同一日期


销售额 PY = CALCULATE(
		[Core 销售额],
		SAMEPERIODLASTYEAR('维度 日期时间表'[日期])
	)