分享Visual SVN Hook Script——只允许用户修改自己的日志，超级用户可以修改其他人的日志

版本库生成后，hooks目录下就存在一些钩子脚本的模板，用户可以作为参考。

把pre-revprop-change.tmpl复制为pre-revprop-change.bat，再修改里面的脚本，钩子就设置好了。

 

包括以下功能：
1、只允许用户修改自己的日志。可以设置超级用户，超级用户可以修改其他人的日志，其他人只能修改自己的日志。
2、只允许对日志进行操作，不允许对其它属性操作。
3、只允许对日志进行修改，不允许增加、删除日志。 

 

@ECHO OFF

REM 限制日志文件的个数采用修改项目属性的tsvn:logminsize，不在脚本中限制

REM 参数
set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5

REM 设置超级用户，超级用户可以修改其他人的日志，其他人只能修改自己的日志
set superUser=zewoo 

REM 只允许日志svn:log的修改
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME

REM 只允许修改日志，增加、删除等操作不允许
if /I not '%action%'=='M' goto ERROR_ACTION

REM 只允许用户修改自己的日志
for /f  "usebackq"   %%k in   (`"C:/Program Files/VisualSVN Server/bin/svnlook.exe" author %repos% -r %rev%`)   do   @set  var=%%k

set rightUser=0
if "%3" == "%superUser%"  set rightUser=1
if "%3" == "%var%" set rightUser=1

if %rightUser% == 0 goto ERROR_USER

goto :SUCCESS_EXIT

:ERROR_USER
echo 只允许用户修改自己的日志 >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo 只有日志信息能被修改 >&2
goto ERROR_EXIT

:ERROR_ACTION
echo 只允许修改日志，不允许增加、删除等操作 >&2
goto ERROR_EXIT

:ERROR_EXIT
exit 1

:SUCCESS_EXIT
exit 0

 

ref: 分享Visual SVN Hook Script——检查提交时必须填写大于N个字符的日志信息