Tcl 读写文件

Tcl 文件命令假定所处理的文件是文本文件。不过，Tcl也提供了对二进制文件进行读、写以及数据修改的能力。

一、基本文件I/O

如下代码和Unix的grep程序相似，传入两个参数，正则表达式模式和文件名，输出指定文件中域指定模式匹配的行。

if {$argc != 2} {
    error "Usage: tgrep pattern fileName"
}

set f [open [lindex $argv 1] r]
set pat [lindex $argv 0]
while {[gets $f line] >= 0} {
    if {[regexp -- $pat $line]} {
        puts $line
    }
}
close $f

访问模式

模式	含义
r	只读，指定文件必须存在
r+	可读写，指定文件必须存在
w	只写，如文件存在则将其清空；如文件不存在则新创建空文件
w+	可读写。如文件存在，将其情况；不存在则新创建空文件
a	只写。将初始访问位置设为文件尾。如文件不存在则新建
a+	可读写。将初始访问位置设为文件尾。如文件不存在则新建

open 命令返回如file3这样的字符串，作为文件描述符。
有三个文件描述符有定义好的名称，且总是可用。分别是stdin/stdout/stderr，分别指向标准输入、标准输出和错误信息通道。

gets命令一次一行地读取文件内容。通常获取两个参数，文件描述符和一个变量名。它读取打开的文件的下一行，抛弃行尾的一个或多个连续的行结束符，将一行地内容存放到指定变量中，返回存放到变量中的字符个数（不包含行结束符）。如读取到文件尾，gets存放一个空字符串，返回-1。
puts命令通常获取两个参数，分别是文件描述符和要输出的字符串。puts为字符串添加一个行结束符，然后将一行输出到指定文件。如未指定文件描述符，默认使用stdout。

二、输出缓冲区

tcl使用C标准I/O库的缓冲方案，传递给puts的信息可能不会立即在目标文件中出现。输出信息缓冲存在在内存，直到缓冲区累积到一定数量，才一次写操作把所有数据写入到文件。文件关闭时，也会将缓冲区数据写入文件。如数据需要立即出现在文件中可以使用flush命令。

flush $f

三、行结束符

Linux等系统使用换行符\n结尾（ASCII码0xa）。
Windows系统使用两个字符\r\n表示换行：一个回车紧接一个换行符。

puts 命令会根据平台自动地将换行符转化为适当地字符或字符序列。可以在Tcl脚本中总是使用\n表示一行地结束。
如下脚本使用read一次将整个文件加载到内存，效率较高，适合文件较小的场景。

if {$argc != 2} {
    error "Usage: tgrep pattern fileName"
}

set f [open [lindex $argv 1] r]
set pat [lindex $argv 0]
set content [read $f]
close $f

foreach line [split $content "\n"] {
    if {[regexp -- $pat $line]} {
        puts $line
    }
}

四、处理二进制文件

Tcl默认处理的是文本文件，对于二进制文件，需做如下设置。

chan configure $fid -translation binary

set data [read $fid 12]
# 读取文件并解包
binary scan $data iiss int1 int2 short1 short2
# 写二进制文件
set data [binary format s3 {3 -7 1}]
puts -nonewline $fid $data

五、随机访问文件

文件I/O默认为书序的，即每条gets 或read 命令返回上一条gets或read命令后面的字节，每一条puts命令将数据写到前一条puts命令输出的数据后面。
可以使用chan seek、chan tell和chan eof命令非顺序地访问文件。打开文件时，根据open指定的访问模式，访问位置被设置到文件头或文件尾。每次读或写操作后，访问位置会根据处理的字节数进行移动。

# 指定从文件的2000个字节处开始
chan seek $f 2000
#指定偏移起始点 start/current/end
chan seek $f -100 end
# 返回指定文件描述符的当前访问位置
chan tell $f
# 判断最近一次对文件的gets或read操作遇到文件尾，返回1，否则返回0
chan eof $f

六、复制文件内容

file copy 命令使用方便，但它创建的目标文件是源文件逐个字节复制的副本，且只能应用于磁盘上的文件。一个更广泛的选择是chan copy 命令，允许在复制时进行一些改变，如改变使用的字符编码，可用于任何Tcl通道类型，如管道、套接字及磁盘文件。

set input [open $inFile r]
chan config $input -encoding euc-jp
set output [open $outFile w]
chan config $output -encoding shiftjis
chan copy $input $output
close $input
close $output

七、虚拟文件系统

从Tcl8.4开始，Tcl的文件命令支持虚拟文件系统。Tcl扩展程序可以把增加的服务作为文件系统呈现给Tcl。如，对FTP网络文件的访问，可以呈现给Tcl命令glob或file，或访问ZIP压缩包中的文件，就如同文件系统中的独立文件一样。