Tcl 过程

一个Tcl过程就是Tcl脚本定义的一个命令。可以使用proc命令定义新的过程。Tcl还提供了处理变量作用域的特殊命令，这些命令允许使用引用而非值传递参数，并能把新的Tcl控制结构实现为过程。

一、proc与return

过程由proc命令创建, 其中参数{a b} 中的大括号表示将参数作为列表传递。
如一个过程在执行完全部脚本前就提前返回，可以调用return命令。

proc plus {a b} {expr {$a + $b}}

二、局部和全局变量

Tcl处理过程块时，会使用与调用者不同的变量集，这些变量称为局部变量，仅由这个过程访问。
过程之外的定义的变量称为全局变量，仅在明确删除后才会消失。
过程可以使用global命令引用全局变量。如
global x y
global 命令把它的每一个参数作为全局变量的名称对待，将过程中的这些变量名的引用定向到全局变量。

三、参数变量数目和默认设置

3.1 参数列表指定空字符串

参数列表指定为一个空字符串，这种情况下过程不获取参数，如带参数调用会产生错误。

3.2 部分或全部参数设置默认值

proc inc {value {increment 1}} {
    expr $value + $increment
}

如果一个特定参数设置了默认值，那么列表中它后面的所有参数都必须设置默认值。

3.3 可变数量参数

如参数列表中最后一个元素是特殊名称args，那么调用过程时可以给可变数量参数。
过程的局部变量args会被设置成一个列表，其元素就是这些更多的参数。如没有过更多的参数，args会设置为空字符串。

proc sum {args} {
    set total 0
    foreach val $args {
        set total [expr {$total + $val}]
    }
    return $total
}

四、传引用调用：upvar

upvar 命令提供访问当前过程上下文范围之外的变量的通用机制。可以用于访问全局变量、命名空间变量以及其他活动中的过程内的局部变量。
它更常见的使用则是模拟传引用调用的行为，这对数组特别有用。

proc printArray {name} {
    upvar $name a
    foreach el [lsort [array names a]] {
        puts "$el = $a($el)"
    }
}

set info(age) 37
set info(position) "Vice President"
printArray info

调用printArray 时，给出数组的名称作为参数。upvar命令使得过程可以通过变量a访问这个数组。
upvar的第一个参数是过程的调用环境可见的变量。这可以是一个全局变量，也可以是一个命名空间变量，或调用过程的内部变量。第二个参数是一个局部变量名称。
upvar命令把对局部变量a的返回值重定向到调用环境中名为name的变量。
upvar命令的第一个变量名默认指向当前过程的调用者的上下文环境。不过，它也可以访问堆栈中任意层级的变量，包括全局层级。如
upvar #0 other x
使用全局变量other可以通过局部变量x访问（参数#0指明other应该解释为全局变量，无论现在已经激活了多少层嵌套过程），而
upvar 2 other x
使得当前过程的调用者的调用者的上下文环境中的other可以通过通过局部变量x访问（2指明other应该在比当前调用堆栈高2个层级的环境中）。

五、创建新的控制结构：uplevel

uplevel命令像是eval和upvar的结合。使用uplevel可以用Tcl过程定义新的控制结构。不作详述。

六、应用匿名过程

Tcl欧诺个的过程不仅提供了模块化编程的机制，还可以提升性能。当希望提升某个过程的性能或把它更好地封装，但这个过程只会被使用一次或有限几次的情况。如代码回调，如对组件命令和文件事件处理程序的回调，以及只用一次的转换函数就是典型的例子。

apply 命令提供了把参数集合应用于匿名过程的功能。

apply {argList body ?namespace?} ?arg1 arg2 ...?

apply 的第一个参数是过程定义，有包含两个或三个元素的列表构成。第一个元素是过程的形式参数，定义方式与proc相同，第二个元素是实现过程块的Tcl脚本，第三个元素是可选的，如提供就指明运行过程的命名空间。

apply {{args} {
    set total 0
    foreach val $args {
        set total [expr {$total + $val}]
    }
    return $total
}} 1 2 3 4 5 6 7

再看下例，对一个列表依据各元素的字符串长度进行排序的任务。lsort命令没有按照元素的长度排序的选项，但可以用-command选项指定自己的排序过程。这个过程接受两个元素

set states {California Delaware Hawaii Indiana Iowa}
lsort -command {apply {{e1 e2} {
    expr {[string length $e1] - [string length $e2]}
}}} $states