一篇分析RISC-V Linux汇编启动过程

最新推荐文章于 2023-08-30 17:59:46 发布
最新推荐文章于 2023-08-30 17:59:46 发布
阅读量1.2k 收藏 8
点赞数 4
文章标签： linux 运维 服务器
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/youzhangjing_/article/details/129708982
版权

RISC-V Linux的汇编启动部分比较简单，不算复杂。有两个部分比较核心：页表创建和重定向。页表创建是用C语言写的，今天先分析汇编部分，先带大家分析整体汇编启动流程，然后分析重定向。

注意：本文基于linux5.10.111内核

汇编启动流程

先从整体分析汇编做的事情，有个大体框架。

路径：arch/riscv/kernel/head.S，入口是ENTRY(_start_kernel)

从ENTRY(_start_kernel)开始进行启动前的一些初始化，建立页表前的主要工作：

  • 关闭所有中断
/* 关闭所有中断 */
    csrw CSR_IE, zero
    csrw CSR_IP, zero
  • 加载全局指针gp
/* 加载全局指针gp */
.option push
.option norelax
    la gp, __global_pointer$
.option pop
  • disable FPU
/* 禁用 FPU 以检测内核空间中浮点的非法使用*/
    li t0, SR_FS
    csrc CSR_STATUS, t0
  • 选择一个核启动
/* 选择一个核启动 */
    la a3, hart_lottery
    li a2, 1
    amoadd.w a3, a2, (a3)
    bnez a3, .Lsecondary_start
  • 清楚bss段
/* 清除bss */
    la a3, __bss_start
    la a4, __bss_stop
    ble a4, a3, clear_bss_done
  • 保存hart id和dtb地址
/* 保存hatr id和dtb地址，hart id保存到a0，dtb地址保存到a1 */
    mv s0, a0
    mv s1, a1
    la a2, boot_cpu_hartid
  • 设置sp指针
la sp, init_thread_union + THREAD_SIZE
  • 上述工作完成，会开始临时页表的创建，跳转到C函数setup_vm建立临时页表
mv a0, s1
    call setup_vm // 跳转到C函数setup_vm，setup_vm会创建临时页表
  • 重定向
#ifdef CONFIG_MMU
    la a0, early_pg_dir
    call relocate	//重定向，实际就是开启MMU
#endif
  • 设置异常向量地址，重载C环境
call setup_trap_vector
/* 重载C环境 */
    la tp, init_task
    sw zero, TASK_TI_CPU(tp)
    la sp, init_thread_union + THREAD_SIZE
  • 最后跳转到C函数start_kernel，开始C语言部分初始化，汇编部分执行完毕
tail start_kernel

完整_start_kernel汇编代码：

ENTRY(_start_kernel)
	/* 关闭所有中断 */
	csrw CSR_IE, zero
	csrw CSR_IP, zero

	/* 在源码中，这里有一个M模式处理的宏，这里没有用到，直接跳过*/

	/* 加载全局指针gp */
.option push
.option norelax
	la gp, __global_pointer$
.option pop

	/* 禁用 FPU 以检测内核空间中浮点的非法使用*/
	li t0, SR_FS
	csrc CSR_STATUS, t0

#ifdef CONFIG_SMP
	li t0, CONFIG_NR_CPUS
	blt a0, t0, .Lgood_cores
	tail .Lsecondary_park
.Lgood_cores:
#endif

	/* 选择一个核启动 */
	la a3, hart_lottery
	li a2, 1
	amoadd.w a3, a2, (a3)
	bnez a3, .Lsecondary_start

	/* 清除bss */
	la a3, __bss_start
	la a4, __bss_stop
	ble a4, a3, clear_bss_done
clear_bss:
	REG_S zero, (a3)
	add a3, a3, RISCV_SZPTR
	blt a3, a4, clear_bss
clear_bss_done:

	/* 保存hatr id和dtb地址，hart id保存到a0，dtb地址保存到a1 */
	mv s0, a0
	mv s1, a1
	la a2, boot_cpu_hartid
	REG_S a0, (a2)

	/* 初始化页表，然后重定向到虚拟地址 */
	la sp, init_thread_union + THREAD_SIZE
	mv a0, s1
	call setup_vm // 跳转到C函数setup_vm，setup_vm会创建临时页表
#ifdef CONFIG_MMU
	la a0, early_pg_dir
	call relocate	//重定向，实际就是开启MMU
#endif /* CONFIG_MMU */

	call setup_trap_vector
	/* 重载C环境 */
	la tp, init_task
	sw zero, TASK_TI_CPU(tp)
	la sp, init_thread_union + THREAD_SIZE

#ifdef CONFIG_KASAN
	call kasan_early_init
#endif
	/* Start the kernel */
	call soc_early_init
	tail start_kernel	//跳转到C函数start_kernel，开始C语言部分初始化

汇编中非常重要的一个部分就是页表的创建，关乎着后面的程序能不能继续往下跑。setup_vm创建页表后就会开始执行relocate重定向，这个重定向主要开启mmu，下面分析relocate的汇编。

资料直通车：Linux内核源码技术学习路线+视频教程内核源码

学习直通车：Linux内核源码内存调优文件系统进程管理设备驱动/网络协议栈

relocate

relocate重定向，就是在开启mmu。开启mmu的操作就是将一级页表的地址以及权限写到satp寄存器中，这就算开启mmu了。

#ifdef CONFIG_MMU
    la a0, early_pg_dir //跳转到relocate前，先把第一级页表early_pg_dir的地址存入a0
    call relocate		//跳转到relocate,开启MMU
#endif

relocate有两次开启mmu的操作，第一次开启mmu使用的是setup_vm()建立的trampoline_gd_dir页表，这页表保存的是kernel的前2M内存。第二次开启MMU使用的是early_pg_dir页表，这个页表映射了整个kernel内存以及dtb的4M空间。

如果trampoline_pg_dir或者early_pg_dir这两个页表的映射没弄好的话，开启MMU的时候就会失败，所以页表的建立十分关键。页表创建后续再深究，下面分析relocate汇编代码。

  • 计算返回地址返回地址就是ra加上虚拟地址和物理地址之间的偏移量，这个是固定偏移量。PAGE_OFFSET是kernel入口地址对应的虚拟地址，_start就是kernel入口地址的虚拟地址，PAGE_OFFSET - _start就得到它们之间的偏移，然后再和ra相加，就是返回地址。
/* Relocate return address */
	li a1, PAGE_OFFSET
	la a2, _start
	sub a1, a1, a2
	add ra, ra, a1
  • 将异常入口1f的虚拟地址写入stvec寄存器因为一旦开启MMU，地址都变成了虚拟地址，原来访问的都是物理地址，开启MMU时，地址发生了改变，VA != PA，从而进入异常，所以要先设置异常入口地址，此时的异常入口为1f。
/* Point stvec to virtual address of intruction after satp write */
	la a2, 1f
	add a2, a2, a1
	csrw CSR_TVEC, a2
  • 提前计算切换到early_pg_dir页表要写入satp的值

再进入relocate之前，就已经把early_pg_dir赋值给a0了，所以a0是early_pg_dir。srl是逻辑右移，mmu使用的是sv39，虚拟地址39位，物理地址56位：

低12位是偏移量，所以PAGE_SHIFT等于12，将early_pg_dir地址右移12位存到a2。根据satp寄存器定义：

MODE等于0x8代表使用sv39 mmu，0x0代表不进行地址翻译，即不开启MMU。这里STAP_MODE为sv39，即0x8。将early_pg_dir地址和SATP_MODE进行或运算后，即可得到写入satp寄存器的值，最后保存到a2。

/* Compute satp for kernel page tables, but don't load it yet */
	srl a2, a0, PAGE_SHIFT
	li a1, SATP_MODE	//sv39 mmu
	or a2, a2, a1
  • 第一次开启MMU，使用trampoline_pg_dir页表

satp值的计算和上述是一样的。开启MMU之前，通过sfence.vma命令先刷新TLB。此时开启MMU，就会进入下面的标号为1的汇编段

la a0, trampoline_pg_dir
	srl a0, a0, PAGE_SHIFT
	or a0, a0, a1
	sfence.vma
	csrw CSR_SATP, a0

进入异常1f段，重新设置异常入口为.Lsecondary_park，然后切换到early_pg_dir页表，相当于第二次开启MMU。此时，如果之前建立的early_pg_dir页表不对，则会就进入.Lsecondary_park。.Lsecondary_park里面是个wfi指令，是个死循环。

完整relocate汇编代码：

relocate:
	/* Relocate return address */
	li a1, PAGE_OFFSET
	la a2, _start
	sub a1, a1, a2
	add ra, ra, a1

	/* Point stvec to virtual address of intruction after satp write */
	la a2, 1f
	add a2, a2, a1
	csrw CSR_TVEC, a2

	/* Compute satp for kernel page tables, but don't load it yet */
	srl a2, a0, PAGE_SHIFT
	li a1, SATP_MODE
	or a2, a2, a1

	/*
	 * Load trampoline page directory, which will cause us to trap to
	 * stvec if VA != PA, or simply fall through if VA == PA.  We need a
	 * full fence here because setup_vm() just wrote these PTEs and we need
	 * to ensure the new translations are in use.
	 */
	la a0, trampoline_pg_dir
	srl a0, a0, PAGE_SHIFT
	or a0, a0, a1
	sfence.vma
	csrw CSR_SATP, a0
.align 2
1:
	/* Set trap vector to spin forever to help debug */
	la a0, .Lsecondary_park
	csrw CSR_TVEC, a0

	/* Reload the global pointer */
.option push
.option norelax
	la gp, __global_pointer$
.option pop

	/*
	 * Switch to kernel page tables.  A full fence is necessary in order to
	 * avoid using the trampoline translations, which are only correct for
	 * the first superpage.  Fetching the fence is guarnteed to work
	 * because that first superpage is translated the same way.
	 */
	csrw CSR_SATP, a2
	sfence.vma

	ret

总结

以上就是RISC-V Linux的汇编启动流程，虽说RISC-V的指令不复杂，但要理解这个汇编启动的部分，还是需要一点基础和时间。另外，大多数人工作中基本用不上汇编，只有真正用上了理解才会比较深。希望本文能够帮助到有需要的人。

 

Linux内核站
关注
  • 4
    点赞
  • 踩
  • 8
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
RISC-V Linux 内核兴趣小组协作仓库.rar
07-12
众所周知，当前最火的两大芯片架构，分别是X86和ARM，X86垄断PC产业，ARM垄断移动领域。而除了这两大架构之外，虽然还有alpha、MIPS、RISC-V等，但都与X86、ARM有点差距。 就拿RISC-V来说，基于其开源免费的优势，这几年非常火，但更多的还是用于中低端的IoT领域，至于进军PC、或者移动Soc等领域，不管是性能，还是生态，都还差很多火候。 不过，很多人都认为，随着RISC-V的发展，未来RISC-V一定能够与ARM、X86等分庭抗礼，甚至取代他们也不是不可能。 而近日，随着阿里高性能RISC-V芯片平台“无剑600”的发布，我们发现接下来RISC-V的芯片，要取代intel的X86芯片，甚至高通的ARM芯片，也不是不可能啊。 在2022 RISC-V中国峰会上，阿里平头哥在RISC-V架构上，又秀了一波技，发布了首个高性能RISC-V芯片平台“无剑600”，不仅发布了这个平台，还给IC厂商们打了个样，基于这个平台推出了一颗SoC原型“曳影1520”。
rars:RARS-RISC-V汇编程序和运行时模拟器
05-14
RARS-RISC-V汇编程序和运行时模拟器 RISC-V汇编器，模拟器和运行时RARS将汇编和模拟RISC-V汇编语言程序的执行。 它的主要目标是为开始使用RISC-V的人们提供一个有效的开发环境。 特征 RISC-V IMFDN基础（riscv32和riscv64） 多个匹配MARS或SPIKE行为的系统调用。 支持使用断点和/或ebreak进行调试 从伪指令到机器码的中间步骤并排比较 使用打开的文件或目录的多文件程序集 文献资料 可在上找到有关受支持的，，等的文档。 可以通过帮助菜单访问下载内容中包含的文档。 下载 RARS作为可执行jar分发。 您至少需要Java 8才能运行它。 可以在找到最新的稳定版本，可以在找到具有最新发展的，并且包含以前所有带有发行说明的稳定发行版。 或者，如果您希望制作自己的jar和/或修改代码，则应使用git clone https://gith
XV6-RISCV多核启动及ls命令内容简述
pipixiaaa的博客
02-19 1305
XV6-RISCV多核启动及ls命令内容简述 多核启动 使用make qemu命令启动xv6是单核启动，如果要使用多个CPU,需要使用以下命令启动，其中 -smp n为设置核心个数的选项，n为要启动的核心个数。 qemu-system-riscv64 -machine virt -bios none -kernel kernel/kernel -m 128M -smp 4 -nographic -drive file=fs.img,if=none,format=raw,id=x0 -device virti
RISC-V Linux 内核剖析
06-23
致力于剖析 Linux 内核的 RISC-V 架构相关支持并开展相应的开发、移植和 Upstream 工作
RISC-V U-Boot启动流程图.pdf
06-01
RISC-V U-Boot启动流程图.pdf
RISC-V MCU启动文件分析
Zhu_zzzzzz的博客
06-15 752
启动文件由汇编语言编写，是MCU上电复位后第一个执行的程序。主要执行以下内容：CH32V103启动文件如下：
汇编程序伪操作指令
Eddy的博客
11-29 2957
汇编程序伪操作 汇编程序的 . 伪操作 汇编程序中以.开头的名称并不是指令的助记符，不会被翻译成机器指令，而是给汇编器一些特殊指示，称为汇编指示（Assembler Directive）或伪操作（Pseudo-operation） .section指示把代码划分成若干个段（Section），程序被操作系统加载执行时，每个段被加载到不同的地址，操作系统对不同的页面设置不同的读、写、执行权限。 .section .text .text段保存代码，是只读和可执行的，后面那些指令都属于.text段。 .se
RISC-V CSR 相关指令集
u011728490的博客
07-19 5705
CSRRW(Atomic Read/Write CSR) 指令原子性的交换CSR和寄存器中的值。 CSRRW指令读取在CSR中的旧值，将其零扩展到32位，然后写入整数寄存器rd中，rs1寄存器中的值将被写入CSR中。如果rd为x0，则不对csr执行读操作 示例： csrrw t6，mscratch，t6 t6=mscratch mscratch=t6 伪指令csrw csr rs <==> csrrw x0, csr.
riscv linux 汇编,RISC-V汇编快速入门
weixin_31440211的博客
05-20 2268
当今，强大的编译器将C或者更高级的语言编译成机器码后，其效能损失已经很小了，再加上芯片的性能越来越强，让汇编语言显得可有可无。但对于嵌入式来说至少在下面两种情况还需要汇编：1是启动代码，2是OS的上下文切换。另外在极端情况下使用汇编提高效率也是有必要的，例如芯片内核非常新编译器优化不够好可以在非常清楚CPU的微结构下进行指令集编码提高性能。因此学习一种新的体系结构，了解其汇编语言是非常有必要的。实...
高性能编程专题-JVM--指令码
puwan4207的博客
09-25 660
指令码 常量入栈指令 局部变量值转载到栈中指令 将栈顶值保存到局部变量中指令 wide指令 通用（无类型）栈操作指令 类型转换指令 整数运算 浮点运算 逻辑运算 控制流指令——条件跳转指令 控制流指令——比较指令 控制流指令——无条件跳转指令 控制流指令——表跳转指令 控制流指令——异常和finally 对象操作指令 数组操作指令 方法调用指令 方法返回指令 线程同步指令 ...
riscv-asm:risc-v汇编语言
03-19
Tcl中的risc-v汇编程序 这个简单的risc-v汇编程序支持带有几个标准扩展的rv32和rv64。它的输出是一个原始列表，列出了源代码行，地址和字节（以十六进制表示）。当前不支持编写ELF。 指令集和扩展名： rv32G（IMAFD_Zicsr_Zifencei） rv64G（IMAFD_Zicsr_Zifencei） C-压缩指令 E-16寄存器 Q-四重浮子 Zfinx-X寄存器中的浮点数 其中包含一个非常简单的example.rva。尝试make example $ make example ./rva.tcl -march rv32gc example.rva 00005 0100 00C58533 add a0 a1 a2 00006 0104 FFFFC297 auipc t0 top 00006 0108 12E1 addi t0 t0
基于qemu-riscv从0开始构建嵌入式linux系统ch3. 添加中断控制器、串口、pflash支持
Quard_D的博客
07-09 2221
基于qemu-riscv从0开始构建嵌入式linux系统ch3. 添加中断控制器、串口、pflash支持 添加串口支持 真实板卡的初期调试中，串口打印可谓神器，几乎所以的IC都会带有串口这个外设，因此我们也需要添加串口到我们的定义中。 首先添加三个串口基地址，之所以添加三个的目的是为了后面我们可能会在多个权限域空间内跑不同的系统因此可能需要不同权限的串口打印输出。 { [QUARD_STAR_UART0] = { 0x10000000, 0x100 }, [QUARD_S
使用qemu运行riscv64 linux
u010451780的专栏
10-13 1632
使用qemu运行riscv64 linux qemu运行riscv64 linux_Quard_D的博客-CSDN博客 本文使用qemu运行riscv64 linux旨在与真实硬件板保持一致，因此不使用qemu提供的任何直接加载elf文件的方式启动，而是从头到尾均加载原始的bin文件程序给qemu，使其完整的执行opensbi、u-boot、kernel。如读者想利用qemu加载elf文件直接启动内核，是更为容易的，也不必再阅读本文。 本文Ver1.0编写于2021.6.6，经笔者测试所...
linux设置redhart内核,构建riscv上运行的linux系统
weixin_29938387的博客
05-08 554
在qemu上启动linuxkernel总述最终目标仍是要在RTL上跑linux系统，但作这个以前第一步先把系统工具链整清楚很重要，因此先在qemu上把相关的工具链，镜像搞定。node为了彻底这项任务，咱们须要安装几个工具， qemu for riscv, linux kernel, boot loader,toolboxlinuxlevelendcodingNameAbbreviatio...
RISC-V(2)——特权级及特权指令集
最新发布
口袋里的跳跳糖
08-30 2304
一个 RISC-V 硬件线程（）是运行在某个特权级上的，这个特权级被编码到一个或者多个控制和状态寄存器）中的一种模式。当前定义了四种特权级，如下所示。特权级的作用现象机器级是最高级特权，也是 RISC-V 硬件平台唯一必须的特权级。所有硬件实现必须提供M-mode，因为这是唯一的模式，可以不受限制地访问整个机器。最简单的RISC-V实现可以仅提供M-mode，虽然这样做不能为防止不正确的、恶意应用代码提供保护。
RISC-V Linux汇编启动过程分析
嵌入式Linux充电站
11-06 1313
RISC-V Linux的汇编启动部分比较简单，不算复杂。有两个部分比较核心：页表创建和重定向。页表创建是用C语言写的，今天先分析汇编部分，先带大家分析整体汇编流程，然后分析重定向。
RISC-v 启动流程
relax33的博客
12-15 2125
risc-v 启动流程
RISCV--汇编指令
yuqian20122013的博客
01-26 2349
la a0, _start //把 _start地址放到a0 li a1, 1 // 把立即数1 放到a1 slli a1, a1, 29 //这里的值是 a1的值<<29 值放到a1 bleu a1, a0, _start0800 // a1 < a0,跳转到_start0800 srli a1, a1, 2 // a1 >>2 a1的值 右移2 后值放到a1 lw: 从数据存储器中取数据写进寄存器 sw:将寄存器中的值写入数据存储器 ...
RISC-V 汇编指令学习 -- 基于启动文件startup.S / startup.s
weixin_50212044的博客
03-04 1853
汇编，RISC-V, startup.S,startup.s 启动文件
RISC-V汇编语言开发工具
03-31
1. RISC-V GCC：RISC-V GCC是一个GNU Compiler Collection的扩展，它支持RISC-V架构。使用RISC-V GCC，用户可以用C/C++语言编写RISC-V程序，并将其编译成RISC-V汇编代码。 2. RISC-V汇编器：RISC-V汇编器是一个将RISC-V汇编代码转换为机器码的工具。它可以将用户编写的RISC-V汇编代码转换为可执行的二进制文件。 3. RISC-V模拟器：RISC-V模拟器是一个用于模拟RISC-V处理器的工具。它可以帮助用户在不需要实际硬件的情况下测试和调试RISC-V程序。 4. RISC-V调试器：RISC-V调试器可以帮助用户在运行时调试RISC-V程序。它提供了一系列调试功能，如断点调试、变量监视、内存查看等。 5. RISC-V开发板：RISC-V开发板是一个集成了RISC-V处理器的硬件平台。它提供了一系列接口和外设，可以帮助用户快速开发RISC-V应用程序。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值