摘自:http://longdinghan.blog.sohu.com/
GDB(GNU Debugger)是GCC的调试工具。其功能强大,现描述如下:
GDB主要帮忙你完成下面四个方面的功能:1.启动你的程序,可以按照你的自定义的要求随心所欲的运行程序。
2.可让被调试的程序在你所指定的调置的断点处停住。(断点可以是条件表达式)
3.当程序被停住时,可以检查此时你的程序中所发生的事。
4.动态的改变你程序的执行环境。
如 果不打开-g或者-ggdb(GDB专用)调试开关,GCC编译时不会加入调试信息,因为这会增大生成代码的体积。GCC采用了分级调试,通过在-g选项 后附加数字1、2或3来指定在代码中加入调试信息量。默认的级别是2(-g2),此时调试信息包括扩展的符号表、行号、局部或外部变量信息。级别 3(-g3)包含级别2中的调试信息和源代码中定义的宏。级别1(-g1)不包含局部变量和与行号有关的调试信息,只能用于回溯跟踪和堆栈转储之用。[ 回溯跟踪指的是监视程序在运行过程中的函数调用历史,堆栈转储则是一种以原始的十六进制格式保存程序执行环境的方法,两者都是经常用到的调试手段。] 。
例如编译foo.c时生成有调试信息的执行文件:
$ gcc –g –o foo foo.c
然后我们就可以使用GDB来跟踪了。GDB使用方法如下:
1. GDB的启动:
1、 gdb <program>
program也就是你的执行文件,一般在当前目录下。
2、 gdb <program> core
用gdb同时调试一个运行程序和core文件,core是程序非法执行后core dump后产生的文件。
3、 gdb <program> <进程ID>
如果你的程序是一个服务程序,那么你可以指定这个服务程序运行时的进程ID。gdb会自动attach上去,并调试他。program应该在PATH环境变量中搜索得到。
GDB启动时,可以加上一些GDB的启动开关,详细的开关可以用gdb -help查看。下面先说几条常用的命令:
直接按下回车表示上一条命令
break 设置断点,
break 10 设置断点,在源程序第10行
break func 设置断点,在func函数入口处
info break 查看断点信息
run 运行程序,可简写为r
next 单步跟踪,函数调用当作一条简单语句执行,可简写为n
step 单步跟踪,函数调进入被调用函数体内,可简写为s
stepi 或 si单步跟踪一条机器指令
nexti 或 ni单步跟踪一条机器指令
continue 继续运行程序,可简写为 c
print 打印变量、字符串、表达式等的值,可简写为p
p count 打印count的值
p cou1+cou2+cou3 打印表达式值
bt 查看函数堆栈
finish 退出函数
quit 退出GDB
shell 不退出GDB就使用shell命令
make <make-args>不退出GDB就重新编译程序
set args指定运行时参数。(如:set args 10 20 30 40 50)
show args查看设置好的运行参数。
path <dir>设定程序的运行路径。
show paths 查看程序的运行路径。
set environment varname [=value] 设置环境变量。如:set env USER=hchen
show environment [varname] 查看环境变量。
cd <dir> 相当于shell的cd命令。
pwd 显示当前的所在目录。
info terminal 显示程序用到的终端模式。
tty指写输入输出的终端设备。如:tty /dev/ttyb
until在一个循环体内单步跟踪时,该命令运行程序到退出循环体。简写u
2. 调试已运行的程序
两种方法:
1、 在UNIX下用ps查看正在运行的程序的PID(进程ID),然后用gdb <program> PID格式挂接正在运行的程序。
2、 先用gdb <program>关联上源代码,并进行gdb,在gdb中用attach命令来挂接进程的PID。并用detach来取消挂接的进程。
3. 暂停 / 恢复程序运行
GDB可以方便地设置程序在哪行停住,在什么条件下停住,在收到什么信号时停往等等。以便于查看运行时的变量,以及运行时的流程。
当进程被gdb停住时使用info program 来查看程序的是否在运行,进程号,被暂停的原因。
GDB有以下几种暂停方式:断点(BreakPoint)、观察点(WatchPoint)、捕捉点(CatchPoint)、信号(Signals)、线程停止(Thread Stops)。要恢复程序运行,使用continue(简写c)命令。详细介绍如下:
1). 设置断点(BreakPoint)
用break命令来设置断点。设置断点的方法如下:
break <function>
在进入指定函数时停住。C++中可以使用class::function或function(type,type)格式来指定函数名。
break <linenum>
在指定行号停住。
break +offset
break -offset
在当前行号的前面或后面的offset行停住。offiset为自然数。
break filename:linenum
在源文件filename的linenum行处停住。
break filename:function
在源文件filename的function函数的入口处停住。
break *address
在程序运行的内存地址处停住。
break
break命令没有参数时,表示在下一条指令处停住。
break ... if <condition>
...可以是上述的参数,condition表示条件,在条件成立时停住。比如在循环境体中,可以设置break if i=100,表示当i为100时停住程序。
查看断点使用info命令,如下所示:(注:n表示断点号)
info breakpoints [n]
info break [n]
2). 设置观察点(WatchPoint)
观察点一般用来观察某个表达式(变量也是一种表达式)的值是否发生了变化,如果有变化,马上停住程序。设置观察点方法如下:
watch <expr>
为表达式(变量)expr设置一个观察点。当表达式值有变化时,马上停住程序。
rwatch <expr>
表达式(变量)expr被读时,停住程序。
awatch <expr>
表达式(变量)的值被读或被写时,停住程序。
info watchpoints
列出当前所设置了的所有观察点。
3). 设置捕捉点(CatchPoint)
设置捕捉点来捕捉程序运行时的一些事件。如:载入共享库(动态链接库)或是C++的异常。设置捕捉点的格式如下:
catch <event>
当event发生时,停住程序。event可以是下面的内容:
1、throw 一个C++抛出的异常。(throw为关键字)
2、catch 一个C++捕捉到的异常。(catch为关键字)
3、exec 调用系统调用exec时。(exec为关键字,目前此功能只在HP-UX下有用)
4、fork 调用系统调用fork时。(fork为关键字,目前此功能只在HP-UX下有用)
5、vfork 调用系统调用vfork时。(vfork为关键字,目前此功能只在HP-UX下有用)
6、load 或 load <libname> 载入共享库(动态链接库)时。(load为关键字,目前此功能只在HP-UX下有用)
7、unload 或 unload <libname> 卸载共享库(动态链接库)时。(unload为关键字,目前此功能只在HP-UX下有用)
tcatch <event>
只设置一次捕捉点,当程序停住以后,应点被自动删除。
4). 维护停止点
GDB中的停止点只有上述的三类。当已定义好的停止点没有用时可以使用
delete、clear、disable、enable这几个命令来进行维护。详细如下:
clear
清除所有的已定义的停止点。
clear <function>
clear <filename:function>
清除所有设置在函数上的停止点。
clear <linenum>
clear <filename:linenum>
清除所有设置在指定行上的停止点。
delete [breakpoints] [range...]
删 除指定的断点,breakpoints为断点号。如果不指定断点号,则表示删除所有的断点。range 表示断点号的范围(如:3-7)。其简写命令为d。比删除更好的一种方法是disable停止点,disable了的停止点,GDB不会删除,当你还需要 时,enable即可,就好像回收站一样。
disable [breakpoints] [range...]
disable所指定的停止点,breakpoints为停止点号。如果什么都不指定,表示disable所有的停止点。简写命令是dis.
enable [breakpoints] [range...]
enable所指定的停止点,breakpoints为停止点号。
enable [breakpoints] once range...
enable所指定的停止点一次,当程序停止后,该停止点马上被GDB自动disable。
enable [breakpoints] delete range...
enable所指定的停止点一次,当程序停止后,该停止点马上被GDB自动删除。
5). 停止条件维护
前 面在说到设置断点时,提到过可以设置一个条件,当条件成立时,程序自动停止,这是一个非常强大的功能,这里专门说说这个条件的相关维护命令。一般来说,为 断点设置一个条件,我们使用if关键词,后面跟其断点条件。并且,条件设置好后,我们可以用condition命令来修改断点的条件。(只有break和 watch命令支持if,catch目前暂不支持if)
condition <bnum> <expression>
修改断点号为bnum的停止条件为expression。
condition <bnum>
清除断点号为bnum的停止条件。
ignore <bnum> <count>
指定程序运行时,忽略断点号为bnum的停止条件count次。
6). 为停止点设定运行命令
GDB提供command命令来设置停止点的运行命令。也就是说,当运行的程序被停止住时,可以让其自动运行一些别的命令,这很有利行自动化调试。对基于GDB的自动化调试是一个强大的支持。详细如下:
commands [bnum]
... command-list ...
end
为断点号bnum指写一个命令列表。当程序被该断点停住时,gdb会依次运行命令列表中的命令。
例如:
break foo if x>0
commands
printf "x is %d\n",x
continue
end
断点设置在函数foo中,断点条件是x>0,如果程序被断住后,也就是,一旦x的值在foo函数中大于0,GDB会自动打印出x的值,并继续运行程序。
如果你要清除断点上的命令序列,那么只要简单的执行一下commands命令,并直接在打个end就行了。
7). 断点菜单
在 C++中,可能会重复出现同一个名字的函数若干次(函数重载),在这种情况下,break <function>不能告诉GDB要停在哪个函数的入口。这时可以使用break <function(type)>也就是把函数的参数类型告诉GDB,以指定一个函数。否则的话,GDB会给你列出一个断点菜单供你选择你所 需要的断点。你只要输入你菜单列表中的编号就可以了。如:
(gdb) b String::after
[0] cancel
[1] all
[2] file:String.cc; line number:867
[3] file:String.cc; line number:860
[4] file:String.cc; line number:875
[5] file:String.cc; line number:853
[6] file:String.cc; line number:846
[7] file:String.cc; line number:735
> 2 4 6
Breakpoint 1 at 0xb26c: file String.cc, line 867.
Breakpoint 2 at 0xb344: file String.cc, line 875.
Breakpoint 3 at 0xafcc: file String.cc, line 846.
Multiple breakpoints were set.
Use the "delete" command to delete unwanted
breakpoints.
(gdb)
可见,GDB列出了所有after的重载函数,你可以选一下列表编号就行了。0表示放弃设置断点,1表示所有函数都设置断点。
8). 恢复程序运行和单步调试
程序被停住后用continue命令恢复程序的运行直到程序结束,或下一个断点到来。也可以使用step或next命令单步跟踪程序。
continue [ignore-count]
c [ignore-count]
fg [ignore-count]
恢复程序运行,直到程序结束,或是下一个断点到来。ignore-count表示忽略其后的断点次数。continue,c,fg三个命令都是一样的意思。
step <count>
单步跟踪,有函数调用时进入该函数。进入函数的前提是,此函数被编译有debug信息。后面可以加count也可以不加,不加表示一条条地执行,加表示执行后面的count条指令,然后再停住。
next <count>
单步跟踪,有函数调用不会进入该函数。后面可以加count也可以不加,不加表示一条条地执行,加表示执行后面的count条指令,然后再停住。
set step-mode
set step-mode on
打开step-mode模式,于是,在进行单步跟踪时,程序不会因为没有debug信息而不停住。这个参数有很利于查看机器码。
set step-mod off
关闭step-mode模式。
finish
运行程序,直到当前函数完成返回。并打印函数返回时的堆栈地址和返回值及参数值等信息。
until 或 u
在一个循环体内单步跟踪时,这个命令可以运行程序直到退出循环体。
stepi 或 si
nexti 或 ni
单步跟踪一条机器指令!一条程序代码有可能由数条机器指令完成,stepi和nexti可以单步执行机器指令。与之一样有相同功能的命令是“display/i $pc” ,当运行完这个命令后,单步跟踪会在打出程序代码的同时打出机器指令(也就是汇编代码)
9). 信号(Signals)
信 号是一种软中断,是一种处理异步事件的方法。一般来说,操作系统都支持许多信号。比较重要应用程序一般都会处理信号。UNIX定义了许多信号,比如 SIGINT表示中断字符信号,也就是Ctrl+C的信号,SIGBUS表示硬件故障的信号;SIGCHLD表示子进程状态改变信号;SIGKILL表示 终止程序运行的信号,等等。信号量编程是UNIX下非常重要的一种技术。GDB调试可以处理任何一种信号,可以让GDB收到所指定的信号时,马上停住正在 运行的程序。详细如下:
handle <signal> <keywords...>
在 GDB中定义一个信号处理。信号<signal>可以以SIG开头或不以SIG开头。可以定义一个需要处理信号的范围(如:SIGIO- SIGKILL,表示处理从SIGIO信号到SIGKILL的信号,其中包括SIGIO,SIGIOT,SIGKILL三个信号),也可以使用关键字 all来标明要处理所有的信号。一旦被调试的程序接收到信号,GDB会马上停止运行程序,以供调试。其<keywords>可以是以下几种关 键字的一个或多个:
nostop
当被调试的程序收到信号时,GDB不会停住程序的运行,但会打出消息告知收到这种信号。
stop
当被调试的程序收到信号时,GDB停住程序。
当被调试的程序收到信号时,GDB显示出一条信息。
noprint
当被调试的程序收到信号时,GDB不显示收到信号的信息。
pass
noignore
当被调试的程序收到信号时,GDB不处理信号但会把这个信号交给被调试程序处理。
nopass
ignore
被调试的程序收到信号时,GDB不会让被调试程序处理这个信号。
info signals
info handle
查看有哪些信号在被GDB检测中。
10). 线程(Thread Stops)
对于多线程程序,GDB可以定义断点是否在所有的线程上,或是在某个特定的线程。详细如下:
break <linespec> thread <threadno>
break <linespec> thread <threadno> if ...
linespec 指定断点所在源程序的行号。threadno指定了线程的ID。这个ID是GDB分配的,通过“info threads”命令来查看正在运行程序中的线程信息。如果不指定thread <threadno>则表示断点设在所有线程上面。还可以为某线程指定断点条件。如:
(gdb) break frik.c:13 thread 28 if bartab > lim
当程序被GDB停住时,所有的运行线程都会被停住。这方便查看运行程序的总体情况。恢复程序运行时,所有的线程也会被恢复运行。那怕是主进程在被单步调试时。
11). 查看栈信息
程序被停住后需要查看程序是哪里停住的。程序调用了一个函数时函数的地址、参数和函数内的局部变量都会被压入“栈”(Stack)中。用GDB命令查看当前的栈中信息的命令如下:
backtrace 简洁bt
打印当前的函数调用栈的所有信息。如:
(gdb) bt
#0 func (n=250) at tst.c:6
#1 0x08048524 in main (argc=1, argv=0xbffff674) at tst.c:30
#2 0x400409ed in __libc_start_main () from /lib/libc.so.6
从上可以看出函数的调用栈信息:
__libc_start_main --> main() --> func()
backtrace <n>
bt <n>
n是一个正整数,表示只打印栈顶上n层的栈信息。
backtrace <-n>
bt <-n>
-n表一个负整数,表示只打印栈底下n层的栈信息。
要查看某一层的信息需要切换当前的栈,一般来说,程序停止时,最顶层的栈就是当前栈。如果要查看栈下面层的详细信息,首先要做的是切换当前栈。
frame <n>
f <n>
n是一个从0开始的整数,是栈中的层编号。
比如:frame 0,表示栈顶,frame 1,表示栈的第二层。
up <n>
向栈的上面移动n层,可以不打n,表示向上移动一层。
down <n>
向栈的下面移动n层,可以不打n,表示向下移动一层。
上面的命令都会打印出移动到的栈层的信息。如果你不想让其打出信息则用这三个命令:
select-frame <n> 对应于 frame 命令。
up-silently <n> 对应于 up 命令。
down-silently <n> 对应于 down 命令。
查看当前栈层的信息,你可以用以下GDB命令:
frame 或 f
打印出栈的层编号,当前的函数名,函数参数值,函数所在文件及行号,函数执行到的语句。
info frame
info f
打印出更为详细的当前栈层的信息,只不过,大多数都是运行时的内地址。比如:函数地址,调用函数的地址,被调用函数的地址,目前的函数是由什么样的程序语言写成的、函数参数地址及值、局部变量的地址等等。如:
(gdb) info f
Stack level 0, frame at 0xbffff5d4:
eip = 0x804845d in func (tst.c:6); saved eip 0x8048524
called by frame at 0xbffff60c
source language c.
Arglist at 0xbffff5d4, args: n=250
Locals at 0xbffff5d4, Previous frame's sp is 0x0
Saved registers:
ebp at 0xbffff5d4, eip at 0xbffff5d8
info args
打印出当前函数的参数名及其值。
info locals
打印出当前函数中所有局部变量及其值。
info catch
打印出当前的函数中的异常处理信息。
4. 查看源程序
1、显示源代码
查看源代码的GDB命令如下:
list <linenum>
显示程序第linenum行的周围的源程序。
list <function>
显示函数名为function的函数的源程序。
list
显示当前行后面的源程序。
list -
显示当前行前面的源程序。
list <first>, <last>
显示从first行到last行之间的源代码。
list , <last>
显示从当前行到last行之间的源代码。
list +
往后显示源代码。
一般是打印当前行的上5行和下5行,也可以定制显示的范围,命令如下:
set listsize <count>
设置一次显示源代码的行数。
show listsize
查看当前listsize的设置。
一般来说在list后面可以跟以下这们的参数:
<linenum> 行号。
<+offset> 当前行号的正偏移量。
<-offset> 当前行号的负偏移量。
<filename:linenum> 哪个文件的哪一行。
<function> 函数名。
<filename:function> 哪个文件中的哪个函数。
<*address> 程序运行时的语句在内存中的地址。
2、搜索源代码
GDB源代码搜索命令:
forward-search <regexp>
search <regexp>
向前面搜索。
reverse-search <regexp>
全部搜索。
其中,<regexp>是正则表达式,(一个字符串的匹配模式)
3、指定源文件的路径
GDB指定源文件路径的命令:
directory <dirname ... >
dir <dirname ... >
加一个源文件路径到当前路径的前面。如果你要指定多个路径,UNIX下你可以使用“:”,Windows下你可以使用“;”。
directory
清除所有的自定义的源文件搜索路径信息。
show directories
显示定义了的源文件搜索路径。
4、源代码的内存
用info line命令来查看源代码在内存中的地址。info line后面可以跟“行号”,“函数名”,“文件名:行号”,“文件名:函数名”,这个命令会打印出所指定的源码在运行时的内存地址,如:
(gdb) info line tst.c:func
Line 5 of "tst.c" starts at address 0x8048456 <func+6> and ends at 0x804845d <func+13>.
命令disassemble查看源程序的当前执行时的机器码,这个命令会把目前内存中的指令dump出来。如下面的示例表示查看函数func的汇编代码。
(gdb) disassemble func
Dump of assembler code for function func:
0x8048450 <func>: push %ebp
0x8048451 <func+1>: mov %esp,%ebp
0x8048453 <func+3>: sub $0x18,%esp
0x8048456 <func+6>: movl $0x0,0xfffffffc(%ebp)
0x804845d <func+13>: movl $0x1,0xfffffff8(%ebp)
0x8048464 <func+20>: mov 0xfffffff8(%ebp),%eax
0x8048467 <func+23>: cmp 0x8(%ebp),%eax
0x804846a <func+26>: jle 0x8048470 <func+32>
0x804846c <func+28>: jmp 0x8048480 <func+48>
0x804846e <func+30>: mov %esi,%esi
0x8048470 <func+32>: mov 0xfffffff8(%ebp),%eax
0x8048473 <func+35>: add %eax,0xfffffffc(%ebp)
0x8048476 <func+38>: incl 0xfffffff8(%ebp)
0x8048479 <func+41>: jmp 0x8048464 <func+20>
0x804847b <func+43>: nop
0x804847c <func+44>: lea 0x0(%esi,1),%esi
0x8048480 <func+48>: mov 0xfffffffc(%ebp),%edx
0x8048483 <func+51>: mov %edx,%eax
0x8048485 <func+53>: jmp 0x8048487 <func+55>
0x8048487 <func+55>: mov %ebp,%esp
0x8048489 <func+57>: pop %ebp
0x804848a <func+58>: ret
End of assembler dump.
[以后尚未整理部分,打印出来看完再说]
5. 查看运行时数据
程序被停住时,用print命令(简写命令为p),或是同义命令inspect来查看当前程序的运行数据。print命令的格式是:
print <expr>
print /<f> <expr>
<expr>是表达式,是所调试程序语言的表达式(GDB可以调试多种编程语言),<f>是输出的格式,比如,如果要把表达式按16进制的格式输出,那么就是/x。
1、表达式
print接受一个表达式,GDB会根据当前的程序运行的数据来计算这个表达式,表达式可以是当前程序运行中的const常量、变量、函数等内容。但是GDB不能使用程序中定义的宏。
表达式中几种GDB支持的操作符:
@ 是一个和数组有关的操作符,在后面会有更详细的说明。
:: 指定一个在文件或是一个函数中的变量。
{<type>} <addr>
表示一个指向内存地址<addr>的类型为type的一个对象。
2、程序变量
GDB随时查询三种变量的值:
1)、全局变量(所有文件可见的)
2)、静态全局变量(当前文件可见的)
3)、局部变量(当前Scope可见的)
如果你的局部变量和全局变量发生冲突(也就是重名),一般情况下是局部变量会隐藏全局变量。此时查看全局变量的值用“::”操作符标记:
file::variable
function::variable
可以通过这种形式指定待查看的变量是哪个文件中的或是哪个函数中的。例如,查看文件f2.c中的全局变量x的值:
gdb) p 'f2.c'::x
当然,“::”操作符会和C++中的发生冲突,但GDB能自动识别“::” 是否C++的操作符,所以调试C++程序时不会出现异常。
另 外,如果程序编译时开启了优化选项,那么在用GDB调试被优化过的程序时,可能会发生某些变量不能访问,或是取值错误码的情况。这个是很正常的,因为优化 程序会删改你的程序,整理你程序的语句顺序,剔除一些无意义的变量等,所以在GDB调试这种程序时,运行时的指令和编写的指令有所不同,也就会出现想象不 到的结果。对付这种情况时,需要在编译程序时关闭编译优化。用“-gstabs”选项来关闭GNU/GCC编译器优化功能。关于编译器的参数,还请查看编 译器的使用说明文档。
3、数组
有时候需要查看一段连续的内存空间的值。比如数组的一段,或是动态分配的数据的大小。这时可以用GDB的“@”操作符,“@”的左边是第一个内存的地址的值,“@”的右边则你你想查看内存的长度。例如,程序中有这样的语句:
int *array = (int *) malloc (len * sizeof (int));
GDB调试时用如下命令显示出这个动态数组的取值:
p *array@len
@的左边是数组的首地址的值,也就是变量array所指向的内容,右边则是数据的长度,其保存在变量len中,其输出结果,大约是下面这个样子的:
(gdb) p *array@len
$1 = {2, 4, 6, 8, 10, 12, 14, 16, 18, 20, 22, 24, 26, 28, 30, 32, 34, 36, 38, 40}
静态数组可以直接用print数组名来显示数组中所有数据的内容。
4、输出格式
GDB的数据显示格式:
x 按十六进制格式显示变量。
d 按十进制格式显示变量。
u 按十六进制格式显示无符号整型。
o 按八进制格式显示变量。
t 按二进制格式显示变量。
a 按十六进制格式显示变量。
c 按字符格式显示变量。
f 按浮点数格式显示变量。
(gdb) p i
$21 = 101
(gdb) p/a i
$22 = 0x65
(gdb) p/c i
$23 = 101 'e'
(gdb) p/f i
$24 = 1.41531145e-43
(gdb) p/x i
$25 = 0x65
(gdb) p/t i
$26 = 1100101
5、查看内存
examine命令(简写x)查看内存地址中的值。x命令的语法如下所示:
x/<n/f/u> <addr>
n、f、u是可选的参数。
n 是一个正整数,表示显示内存的长度,也就是说从当前地址向后显示几个地址的内容。
f 表示显示的格式,参见上面。如果地址所指的是字符串,那么格式可以是s,如果是指令地址,那么格式可以是i。
u 表示从当前地址往后请求的字节数,如果不指定的话,GDB默认是4个bytes。u参数可以用下面的字符来代替,b表示单字节,h表示双字节,w表示四字 节,g表示八字节。当我们指定了字节长度后,GDB会从指内存定的内存地址开始,读写指定字节,并把其当作一个值取出来。
<addr>表示一个内存地址。
n/f/u三个参数可以一起使用。例如:
命令:x/3uh 0x54320 表示,从内存地址0x54320读取内容,h表示以双字节为一个单位,3表示三个单位,u表示按十六进制显示。
6、自动显示
程序停住单步跟踪时变量自动显示。相关命令是display。
display <expr>
display/<fmt> <expr>
display/<fmt> <addr>
expr是一个表达式,
fmt表示显示的格式,
addr表示内存地址,
用display设定好了一个或多个表达式后,只要程序被停下来GDB就会自动显示你所设置的这些表达式的值。
格式i和s同样被display支持,一个非常有用的命令是:
display/i $pc
$pc是GDB的环境变量,表示着指令的地址,/i则表示输出格式为机器指令码,也就是汇编。于是当程序停下后,就会出现源代码和机器指令码相对应的情形,这是一个很有意思的功能。
下面是一些和display相关的GDB命令:
undisplay <dnums...>
delete display <dnums...>
删除自动显示,dnums意为所设置好了的自动显式的编号。如果要同时删除几个,编号可以用空格分隔,如果要删除一个范围内的编号,可以用减号表示(如:2-5)
disable display <dnums...>
enable display <dnums...>
disable和enalbe不删除自动显示设置而是让其失效和恢复。
info display
查看display设置的自动显示的信息。GDB会打出一张表格,向你报告当然调试中设置了多少个自动显示设置,其中包括,设置的编号,表达式,是否enable。
7、设置显示选项
GDB中关于显示的选项比较多,这里我只例举大多数常用的选项。
CODE
set print address
set print address on
打开地址输出,当程序显示函数信息时,GDB会显出函数的参数地址。系统默认为打开的,如:
(gdb) f
#0 set_quotes (lq=0x34c78 "<<", rq=0x34c88 ">>")
at input.c:530
530 if (lquote != def_lquote)
set print address off
关闭函数的参数地址显示,如:
(gdb) set print addr off
(gdb) f
#0 set_quotes (lq="<<", rq=">>") at input.c:530
530 if (lquote != def_lquote)
show print address
查看当前地址显示选项是否打开。
set print array
set print array on
打开数组显示,打开后当数组显示时,每个元素占一行,如果不打开的话,每个元素则以逗号分隔。这个选项默认是关闭的。与之相关的两个命令如下,我就不再多说了。
set print array off
show print array
set print elements <number-of-elements>
这个选项主要是设置数组的,如果你的数组太大了,那么就可以指定一个<number-of-elements>来指定数据显示的最大长度,当到达这个长度时,GDB就不再往下显示了。如果设置为0,则表示不限制。
show print elements
查看print elements的选项信息。
set print null-stop <on/off>
如果打开了这个选项,那么当显示字符串时,遇到结束符则停止显示。这个选项默认为off。
set print pretty on
如果打开printf pretty这个选项,那么当GDB显示结构体时会比较漂亮。如:
$1 = {
next = 0x0,
flags = {
sweet = 1,
sour = 1
},
meat = 0x54 "ork"
}
set print pretty off
关闭printf pretty这个选项,GDB显示结构体时会如下显示:
$1 = {next = 0x0, flags = {sweet = 1, sour = 1}, meat = 0x54 "ork"}
show print pretty
查看GDB是如何显示结构体的。
set print sevenbit-strings <on/off>
设置字符显示,是否按“\nnn”的格式显示,如果打开,则字符串或字符数据按\nnn显示,如“\065”。
show print sevenbit-strings
查看字符显示开关是否打开。
set print union <on/off>
设置显示结构体时,是否显式其内的联合体数据。例如有以下数据结构:
typedef enum {Tree, Bug} Species;
typedef enum {Big_tree, Acorn, Seedling} Tree_forms;
typedef enum {Caterpillar, Cocoon, Butterfly}
Bug_forms;
struct thing {
Species it;
union {
Tree_forms tree;
Bug_forms bug;
} form;
};
struct thing foo = {Tree, {Acorn}};
当打开这个开关时,执行 p foo 命令后,会如下显示:
$1 = {it = Tree, form = {tree = Acorn, bug = Cocoon}}
当关闭这个开关时,执行 p foo 命令后,会如下显示:
$1 = {it = Tree, form = {...}}
show print union
查看联合体数据的显示方式
set print object <on/off>
在C++中,如果一个对象指针指向其派生类,如果打开这个选项,GDB会自动按照虚方法调用的规则显示输出,如果关闭这个选项的话,GDB就不管虚函数表了。这个选项默认是off。
show print object
查看对象选项的设置。
set print static-members <on/off>
这个选项表示,当显示一个C++对象中的内容是,是否显示其中的静态数据成员。默认是on。
show print static-members
查看静态数据成员选项设置。
set print vtbl <on/off>
当此选项打开时,GDB将用比较规整的格式来显示虚函数表时。其默认是关闭的。
show print vtbl
查看虚函数显示格式的选项。
8、历史记录
GDB 的print查看程序运行时的数据时GDB会以$1, $2, $3 .....这样的方式为每一个print命令编上号。以后可以用这个编号访问以前的表达式,如$1。比如先前输入了一个比较长的表达式,过一会后还想查看 这个表达式的值,那么就而已用历史记录来访问,省去了重复输入。
9、GDB环境变量
GDB的调试环境中可以定义自己的变量,用来保存一些调试程序中的运行数据。使用GDB的set命令可定义这类变量。GDB的环境变量和UNIX一样,也是以$起头。如:
set $foo = *object_ptr
使用环境变量时,GDB在第一次使用时创建这个变量,而在以后的使用中,则直接对其賦值。环境变量没有类型,可以给环境变量定义任一的类型。包括结构体和数组。
show convenience
查看当前所设置的所有的环境变量。
这是一个比较强大的功能,环境变量和程序变量的交互使用,将使得程序调试更为灵活便捷。例如:
set $i = 0
print bar[$i++]->contents
于是就不必,print bar[0]->contents, print bar[1]->contents地输入命令了。输入这样的命令后,只用敲回车,重复执行上一条语句,环境变量会自动累加,从而完成逐个输出的功能。
10、查看寄存器
命令如下:
info registers
查看寄存器的情况。(除了浮点寄存器)
info all-registers
查看所有寄存器的情况。(包括浮点寄存器)
info registers <regname ...>
查看所指定的寄存器的情况。
寄存器中放置了程序运行时的数据,比如程序当前运行的指令地址(ip),程序的当前堆栈地址(sp)等等。可以使用print命令来访问寄存器的情况,只需要在寄存器名字前加一个$符号就可以了。如:p $eip。