flex&bison-一个简单计算器程序

导读

flex : 用于生成词法分析的程序，可以生成lex.yy.c文件。
bison：用于生成语法分析的程序，可以生成*.tab.h 和 *.tab.c文件。

flex规则

flex文件内容主要分为三段，每一段用%%分割，calc.l如下

%{
#include "calc.tab.h"
%}

%option noyywrap

%%
"("     { return OB; }
")"     { return CB; }
"+"     { return ADD; }
"-"     { return SUB; }
"*"     { return MUL; }
"/"     { return DIV; }
[0-9]+  { yylval = atoi(yytext); return NUM; }
\n      { return EOL; }
[ \t]   { }

%%

第一段： %{ %}部分会原封不动放入到yy.lex.c
第二段：是匹配模式，规则 动作，规则可以使正则表达式， 动作是C语言代码段。
第三段：可以放一些C代码。

bison规则

bison文件内容主要分为三段，每一段用%%分割，calc.y如下

%{
#include <stdio.h>
%}
%token NUM
%token ADD SUB MUL DIV
%token EOL
%token OB CB

%%

expr: factor { $$ = $1;}
    | expr ADD factor { $$ = $1 + $3; }
    | expr SUB factor { $$ = $1 - $3;}
    | expr EOL { printf("result : %d\n", $1);}
    ;

factor: term { $$ = $1; }
    | factor MUL term { $$ = $1 * $3; }
    | factor DIV term { $$ = $1 / $3; }
    ;

term: NUM { $$ = $1;}
    | OB expr CB { $$ = $2; }
    ;

%%

int
main(int argc, char *argv[])
{
        yyparse();
        return 0;
}


void 
yyerror(char * e)
{
        printf("%s\n", e);
}

第一段：%{ %}用来编写一些代码段，%token用于声明记号给词法分析程序使用。
第二段：BNF规则，其中|表示或，每条规则以符号;结束，规则表达式后面可以跟一个动作，动作是一段C语言代码段。
第三段：可以放一些c代码，这里yyparse会调用词法分析程序处理字符流并根据返回的记号执行响应的动作。

makefile文件

calc:
        bison -d calc.y
        flex calc.l
        cc -o calc calc.tab.c lex.yy.c

效果

zhangliang[zhangl@localhost ~/test/bison/calc]$ echo "1+3*(2+2)/(3-1)+13" | ./calc
result : 20