Autodesk官方最新的.NET教程（四）（vb.net版）

 

第 4 章  数据库基础2:  添加自定义数据

 

在这一章中，我们将创建一个新的字典对象，它用来表示我们雇员就职的 ‘Acme 公司‘（呵呵，当然是虚构的一家公司）的部门。这个“部门”字典对象将包含一个表示部门经理的记录。我们还会加入代码到雇员创建过程，这个过程会加入一个索引到雇员工作的部门。

我们要说明的是如何在DWG文件中创建自定义数据，包括“每个图形”的自定义数据和“每个实体”的自定义数据。“每个图形”的自定义数据是指只在整个图形中加入一次的数据，它表示对象可以引用的单一类型或特性。“每个实体”的自定义数据是指是为特定的对象或数据库中的实体加入的数据。

在下面的示例中，我们将加入“每个图形”的自定义数据到命名对象字典(简称NOD)。NOD存在于每一个DWG文件中。“每个实体”的自定义数据加入到一个名为“扩展字典”的字典（可选）中，它表示每一个雇员。每一个由DBObject派生的对象都拥有存储自定义数据的扩展字典。而在我们的示例中将包含这种自定义数据如名字、薪水和部门。

因此这一章的重点是字典对象和扩展记录（XRecord），它们是我们用来表示自定义数据的容器。

首先让我们来创建表示公司的条目。在本章的前几个步骤中，我们将创建如下所示的部门层次结构：

  NOD－命名对象字典

     ACME_DIVISION－自定义公司字典

               销售(Sales) －部门字典

                       部门经理－部门条目

 

请打开Lab4文件夹下的Lab4工程，或接着Lab3的代码。

1)                   我们首先要做的是定义一个新的函数，它用来在命名对象字典(NOD)中创建公司字典对象。为这个函数取名为

CreateDivision(),，并使用命令属性来定义CREATEDIVISION命令。

下面是这个函数的代码，它的形式非常简单，只是用来在NOD中创建一个ACME_DIVISION（用来表示公司）

    <CommandMethod("CREATEDIVISION")> _

        Public Function CreateDivision()

        Dim db = HostApplicationServices.WorkingDatabase

        Dim trans As Transaction = db.TransactionManager.StartTransaction()

        Try

            '首先，获取NOD……

            Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForWrite, False)

            '定义一个公司级别的字典

            Dim acmeDict As DBDictionary

            Try

                '如果ACME_DIVISION不存在，则转到catch块，这里什么也不做

                acmeDict = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)

            Catch

                '如果ACME_DIVISION不存在，则创建它并把它加入到NOD中……

                acmeDict = New DBDictionary()

                NOD.SetAt("ACME_DIVISION", acmeDict)

                trans.AddNewlyCreatedDBObject(acmeDict, True)

            End Try

            trans.Commit()

        Finally

            trans.Dispose()

        End Try

    End Function

 

请仔细阅读一下上面的代码块的结构，可以通过注释来了解相关的细节。特别要注意的是我们是如何用一个try-catch块来处理ACME_DIVISION是否存在？如果ACME_DIVISION字典不存在，GetObject()将会抛出异常，catch块被执行，它会创建一个新的字典。

运行这个函数来看它是否可行。可以使用数据库查看工具来检查字典是否已被加入（建议使用ARX SDK的ArxDbg工具）

2)                   接下来，我们要在ACME_DIVISION字典中加入销售(Sales)条目。销售(Sales)条目同样也是一个字典。由于销售(Sales)与ACME_DIVISION字典的关系如同ACME_DIVISION字典与NOD，所以代码是类似的。定义下面的代码部分在ACME_DIVISION字典中创建一个名为’Sales’的字典。

代码提示：

Code hint:

 

                   Dim divDict As DBDictionary

                   Try

                divDict = trans.GetObject(acmeDict.GetAt("Sales"), OpenMode.ForWrite)

                   Catch

          …

 

运行函数来看‘Sales’条目是否已加入到ACME_DIVISION字典。

 

3)                     现在我们要在这个字典中加入一个特殊的记录，它可以包含任意的自定义数据。我们要加入的数据类型为扩展记录（XRecord），它可以包含任何东西，因此我们可以让它包含ResultBuffer类的对象（就是有些人可能非常熟悉的‘resbuf’）。ResultBuffer可以存储不同类型的预定义数据。扩展记录存储任意数目的ResultBuffer关系列表，因此可能会很大。下表是可以包含在ResultBuffer中一些数据类型（位于Database类的DxfCode枚举中）：

 

Start	0
Text	1
XRefPath	1
ShapeName	2
BlockName	2
AttributeTag	2
SymbolTableName	2
MstyleName	2
SymTableRecName	2
AttributePrompt	3
DimStyleName	3
LinetypeProse	3
TextFontFile	3

 

在下面的代码部分，我们将创建只包含一个ResultBuffer的扩展记录。这个ResultBuffer包含一个单一的的字符串值，它表示’Sales’部门的部门经理的名字。我们使用和加入字典一样的方法加入扩展记录。唯一的区别是扩展记录与字典的不同：

             mgrXRec = New Xrecord()

mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))

 

请看一下我们是怎样使用new来创建一个新的扩展记录。但我们也使用了New来创建一个ResultBuffer，传入的参数是一个名为‘TypedValue’的对象。‘TypedValue’对象和C++中resbuf的成员‘restype’是类似的。这个对象一般表示一个特定类型的DXF值，我们使用它来组装诸如扩展数据或扩展记录之类的通用数据容器。在这里，我们简单地使用DxfCode.Text键值和“Randolph P. Brokwell”数据值来定义一个TypedValue，然后把它作为单一的参数传入ResultBuffer构造函数(由new来调用)中。

XRecord的’Data’属性实际上正是扩展记录链的第一个ResultBuffer，我们使用它来表示扩展记录链是从什么地方开始的。

所以接下来的代码块看起来和前面两个非常相似：

                   Dim mgrXRec As Xrecord

                   Try

                mgrXRec = trans.GetObject(divDict.GetAt("Department Manager"), OpenMode.ForWrite)

                   Catch

                mgrXRec = New Xrecord()

                mgrXRec.Data = New ResultBuffer(New TypedValue(DxfCode.Text, "Randolph P. Brokwell"))

                divDict.SetAt("Department Manager", mgrXRec)

                trans.AddNewlyCreatedDBObject(mgrXRec, True)

              End Try

 

运行函数并使用数据库查看工具来确定部门经理已被加入到’Sales’字典。

 

4)    我们已经定义了公司字典，现在我们要把每个雇员的数据加入到前一章定义的块索引中。我们要加入的数据是：名字、薪水和雇员所属的部门。要加入这些数据，我们要同前几个步骤一样使用扩展记录。因为我们要加入三个条目，所以我们要使扩展记录可以把这些数据联系在一起。

一般来说，扩展记录只能存在于字典中。而我们要为每个雇员加入这些数据（就是本章开头所讲的“每个图形”的自定义数据和“每个实体”的自定义数据），那应该怎么做呢？答案就是：每一个对象或AutoCAD中的实体实际上都有一个名为’扩展字典（Extension Dictionary）’的可选字典。我们可以把扩展记录直接加入到这个字典中。

请回到我们在上一章创建的CreateEmployee()函数。这个函数是我们创建块索引的地方。

让我们像前面的步骤一样来创建一个新的扩展记录。因为我们要加入3个条目，因此我们既可以使用ResultBuffer的Add方法（它会在扩展记录链中加入一个链接），也可以利用ResultBuffer的构造函数（它的一种构造函数可以输入可变数量的参数）。

无论用哪一种方法，请在CreateEmployee()函数中使用ResultBuffer来创建一个新的XRecord，ResultBuffer包括以下的类型和值：

       Text – “Earnest Shackleton”        (或是你选择的其它雇员的名字)

       Real – 72000                或者更多的薪水J

       Text – “Sales”               雇员所在的部门

5)    要把上面的扩展记录加入到块索引，我们必须把它加入到扩展字典。通常这个字典是不存在的，除非它被明确地创建，块索引就是这种情况。要给一个对象创建扩展字典，你要调用它的成员‘CreateExtensionDictionary()’。这个函数不返回任何值，所以要访问它创建的扩展字典，你还得使用对象的‘ExtensionDictionary’属性。你可以使用类似于以下的代码来创建并访问扩展字典：

 

            br.CreateExtensionDictionary()

            Dim brExtDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForWrite, False)

 

由于扩展字典也是字典，我们可以和第3步一样在扩展字典中加入扩展记录。请完成有关的代码来创建和访问块索引的扩展字典，加入你在第4步中创建的扩展记录，然后把扩展记录加入到事务处理。

 

6)    返回到NOD……因为在NOD中创建公司字典只需要一次（就像创建Employee块一样），因此我们应该把CreateDivision函数的命令属性去掉，而在CreateEmployeeDefinition()中调用这个函数。请自己完成这些改变。当所有这些都做完后，当CREATE命令第一次运行的时候，所有的函数都会被调用。

7)    下面的步骤和上面的无关。我们将创建一个函数来遍历模型空间，以用来查找加入的Employee对象（这里其实是块索引）的数目。在VB.NET 或C#中，我们可以把模型空间块表记录（ModelSpace BlockTableRecord）当作一个集合，这样就可以使用For Each(C#是foreach)来遍历它。请仔细研究一下下面的代码片断：

            Dim id As ObjectId ‘首先，定义一个For循环要使用的ObjectId变量。

            For Each id In btr

                Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) '打开当前的对象!

 

一旦我们获得模型空间对象，你们就可以定义一个ObjectId变量，然后把它用于For Each循环(C#是foreach)。

现在，我们需要使用一些方法来筛选雇员。我们知道模型空间中的对象都是实体，但不全是雇员。我们需要使用一些方法来加以区分。在这里，我们可以使用VB.NET的TypeOf关键字并用CType进行类型转换（C#是GetType函数和typeof）：

 

                If TypeOf ent Is BlockReference Then

              Dim br As BlockReference = CType(ent, BlockReference)

              …

 

上面讲的概念对于AutoCAD编程是很重要的，因为容器对象经常包含不同类型的对象。你会在AutoCAD程序的开发中经常碰到这种类型转化。

请定义一个名为EmployeeCount()的函数，函数的结构如上所示，它用来统计模型空间中的块索引的数目。这个函数不会输出任何东西，但你可以使用逐步调试程序来查看整数变量的增加（每发现一个块索引对象）。

 

8)  接下来，为了把结果输出到命令行，我们需要使用Application.DocumentManager.MdiActiveDocument.Editor对象的服务。要使用它，请加入下面的代码：

Imports Autodesk.AutoCAD.EditorInput

Imports Autodesk.AutoCAD.ApplicationServices

 

在函数的内部：

 

Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

最后，在循环的后面确定找到了多少个块索引：

 

ed.WriteMessage("Employees Found: {0}" + ControlChars.Lf, nEmployeeCount.ToString())

 

End of Lab 4:

 

第四章结束

 

下面的代码片断演示了怎样获取Employee对象的所有内容，包括ACME_DIVISION字典中的部门经理的名字。这部分要在后面的章节中使用，但因为它和本章有关，因此我们把它放在本章作介绍。如果有时间的话，请阅读一下其中的代码来看看它是怎么使用的。它可以被直接放到你的类中并可以运行。命令的名字是PRINTOUTEMPLOYEE。ListEmployee()函数接收一个ObjectId参数，它通过一个ref类型的字符串数组返回值（包含相应的雇员数据）。调用它的PrintoutEmployee()函数只是用来在命令行中输出这些数据。

 

        '我们需要一个遍历并显示所有雇员数据的命令。

    Public Shared Sub ListEmployee(ByVal employeeId As ObjectId, ByRef saEmployeeList() As String)

        Dim nEmployeeDataCount As Integer

        Dim db = HostApplicationServices.WorkingDatabase

        Dim trans As Transaction = db.TransactionManager.StartTransaction() '开始事务处理。

        Try

            Dim ent As Entity = trans.GetObject(employeeId, OpenMode.ForRead, False) '打开当前对象!

            If TypeOf ent Is BlockReference Then

                '不是所有的块索引都有雇员数据，所以我们要处理错误

                Dim bHasOurDict As Boolean = True

                Dim EmployeeXRec As Xrecord

                Try

                    Dim br As BlockReference = CType(ent, BlockReference)

                    Dim extDict As DBDictionary = trans.GetObject(br.ExtensionDictionary(), OpenMode.ForRead, False)

                    EmployeeXRec = trans.GetObject(extDict.GetAt("EmployeeData"), OpenMode.ForRead, False)

                Catch

                    bHasOurDict = False '出现了错误……字典或扩展记录不能访问

                End Try

                If bHasOurDict Then '如果获得扩展字典，而又有扩展记录……

                    '调整雇员列表的大小来使得它能放三个条目...

                    ReDim Preserve saEmployeeList(saEmployeeList.GetUpperBound(0) + 4)

                    '加入雇员的名字

                    Dim resBuf As TypedValue = EmployeeXRec.Data.AsArray(0)

 

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

 

                    '加入雇员的薪水

                    resBuf = EmployeeXRec.Data.AsArray(1)

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

 

                    '加入雇员所在的部门

                    resBuf = EmployeeXRec.Data.AsArray(2)

                    Dim str As String = resBuf.Value()

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

 

 

                    '现在，让我们从公司字典中获取老板的名字

                    '在NOD中找到.

                    Dim NOD As DBDictionary = trans.GetObject(db.NamedObjectsDictionaryId, OpenMode.ForRead, False)

                    Dim acmeDict As DBDictionary = trans.GetObject(NOD.GetAt("ACME_DIVISION"), OpenMode.ForRead)

                    '注意我们直接使用扩展数据...

                    Dim salesDict As DBDictionary = trans.GetObject(acmeDict.GetAt(EmployeeXRec.Data.AsArray(2).Value), OpenMode.ForRead)

                    Dim salesXRec As Xrecord = trans.GetObject(salesDict.GetAt("Department Manager"), OpenMode.ForRead)

                    '最后，把雇员的数据输出到命令行

                    resBuf = salesXRec.Data.AsArray(0)

                    saEmployeeList.SetValue(String.Format("{0}" + ControlChars.Lf, resBuf.Value), nEmployeeDataCount)

                    nEmployeeDataCount += 1

                End If

            End If

            trans.Commit()

        Finally

            trans.Dispose()

        End Try

    End Sub

 

 

    <CommandMethod("PRINTOUTEMPLOYEE")> _

    Public Shared Function PrintoutEmployee()

        Dim ed As Editor = Application.DocumentManager.MdiActiveDocument.Editor

 

        Dim nEmployeeCount As Integer = 0

 

        Dim nEmployeeDataCount As Integer

        '声明我们将在下面使用的工具...

        Dim db = HostApplicationServices.WorkingDatabase

        Dim trans As Transaction = db.TransactionManager.StartTransaction() 'Start the transaction.

        Try

            '首先，获取块表和模型空间块表记录

            Dim bt As BlockTable = trans.GetObject(HostApplicationServices.WorkingDatabase.BlockTableId, OpenMode.ForRead)

            Dim btr As BlockTableRecord = trans.GetObject(bt(btr.ModelSpace), OpenMode.ForRead)

            '现在，我们需要把内容输出到命令行。这里可以有一个对象帮助我们：

            '下面的部分，我们将遍历模型空间:

            Dim id As ObjectId ' – 首先，定义一个ObjectId对象，用于For循环。

            For Each id In btr

                Dim ent As Entity = trans.GetObject(id, OpenMode.ForRead, False) '打开当前对象!

                If TypeOf ent Is BlockReference Then

                    Dim saEmployeeList(-1) As String '这是正确的...它被重新定义。

                    ListEmployee(id, saEmployeeList)

                    Dim sEmployeeData As String

 

                    If (saEmployeeList.Length = 4) Then

                        ed.WriteMessage("Employee Name: {0}", saEmployeeList(0))

                        ed.WriteMessage("Employee Salary: {0}", saEmployeeList(1))

                        ed.WriteMessage("Employee Division: {0}", saEmployeeList(2))

                        ed.WriteMessage("Division Manager: {0}", saEmployeeList(3))

                    End If

                End If

            Next

        Finally

        End Try

    End Function