2006河南省赛第一试 旅行

2006河南省赛第一试 旅行

Time Limit:2000MS  Memory Limit:65536K
Total Submit:132 Accepted:47

Description

　　Z小镇是一个景色宜人的地方，吸引来自各地的观光客来此旅游观光。Z小镇附近共有N个景点（编号为1,2,3,…,N），这些景点被M条道路连接着，所有道路都是双向的，两个景点之间可能有多条道路。也许是为了保护该地的旅游资源，Z小镇有个奇怪的规定，就是对于一条给定的公路Ri，任何在该公路上行驶的车辆速度必须为Vi。速度变化太快使得游客们很不舒服，因此从一个景点前往另一个景点的时候，大家都希望选择行使过程中最大速度和最小速度的比尽可能小的路线，也就是所谓最舒适的路线。

Input

第一行包含两个正整数，N和M。 
接下来的M行每行包含三个正整数：x，y和v。表示景点x到景点y之间有一条双向公路，车辆必须以速度v在该公路上行驶。 
最后一行包含两个正整数s，t，表示想知道从景点s到景点t最大最小速度比最小的路径。s和t不可能相同。 

Output

如果景点s到景点t没有路径，输出“IMPOSSIBLE”。否则输出一个数，表示最小的速度比。如果需要，输出一个既约分数。 

Sample Input

样例1
4 2
1 2 1
3 4 2
1 4

样例２
3 3
1 2 10
1 2 5
2 3 8
1 3

样例3
3 2
1 2 2
2 3 4
1 3

Sample Output

样例1
IMPOSSIBLE

样例2
5/4

样例3
2

Hint

【数据范围】 
1＜N＜＝500 
1＜＝x,y＜＝N，0＜v＜30000，x≠y 

0＜M＜＝5000 

分析：按速度从大到小排序，枚举最大边，把当前两边加入并查集后如果s与t相通就判断。

时间复杂度：O(n^2)

代码

var
  n,m,i,s,t,xi,yi,flag:longint;
  fa:array[0..500]of longint;
  x,y,v:array[0..5000]of longint;
procedure sort(l,r:longint);
var
  i,j,t,z:longint;
begin
  i:=l;
  j:=r;
  z:=v[random(r-l)+l];
  repeat
    while v[i]>z do
      inc(i);
    while v[j]<z do
      dec(j);
    if i<=j then
    begin
      t:=x[i];
      x[i]:=x[j];
      x[j]:=t;
      t:=y[i];
      y[i]:=y[j];
      y[j]:=t;
      t:=v[i];
      v[i]:=v[j];
      v[j]:=t;
      inc(i);
      dec(j);
    end;
  until i>j;
  if i<r then sort(i,r);
  if j>l then sort(l,j);
end;
function find(son:longint):longint;
begin
  if fa[son]=son then exit(son);
  fa[son]:=find(fa[son]);
  exit(fa[son]);
end;
procedure try(step:longint);
var
  i:longint;
begin
  for i:=1 to n do
    fa[i]:=i;
  for i:=step to m do
    begin
      fa[find(x[i])]:=find(y[i]);
      if find(s)=find(t) then
      begin
        inc(flag);
        if flag=1 then
        begin
          xi:=v[step];
          yi:=v[i];
        end;
        if (v[step]/v[i])<(xi/yi) then
        begin
          xi:=v[step];
          yi:=v[i];
        end;
      end;
    end;
end;
function gcd(a,b:longint):longint;
begin
  if b=0 then exit(a);
  exit(gcd(b,a mod b));
end;
procedure print;
begin
  if (xi mod yi)=0 then
  begin
    write(xi div yi);
    exit;
  end;
  write(xi div gcd(xi,yi),'/',yi div gcd(xi,yi));
end;
begin
  randomize;
  read(n,m);
  for i:=1 to m do
    read(x[i],y[i],v[i]);
  read(s,t);
  sort(1,m);
  for i:=1 to m do
    try(i);
  if flag=0 then write('IMPOSSIBLE')
  else print;
end.