poj3187 数字三角形(dfs)

数字三角形

题目描述

FJ and his cows enjoy playing a mental game. They write down the numbers from 1 to N (1 <= N <= 10) in a certain order and then sum adjacent numbers to produce a new list with one fewer number. They repeat this until only a single number is left. For example, one instance of the game (when N=4) might go like this:

    3   1   2   4
      4   3   6
        7   9
         16

Behind FJ's back, the cows have started playing a more difficult game, in which they try to determine the starting sequence from only the final total and the number N. Unfortunately, the game is a bit above FJ's mental arithmetic capabilities.

Write a program to help FJ play the game and keep up with the cows.

有这么一个游戏：

写出一个1～N的排列a[i]，然后每次将相邻两个数相加，构成新的序列，再对新序列进行这样的操作，显然每次构成的序列都比上一次的序列长度少1，直到只剩下一个数字位置。下面是一个例子：

3 1 2 4

4 3 6

7 9 16 最后得到16这样一个数字。

现在想要倒着玩这样一个游戏，如果知道N，知道最后得到的数字的大小sum，请你求出最初序列a[i]，为1～N的一个排列。若答案有多种可能，则输出字典序最小的那一个。

[color=red]管理员注：本题描述有误，这里字典序指的是1，2，3，4，5，6，7，8，9，10，11，12

而不是1，10，11，12，2，3，4，5，6，7，8，9

分析：该数字三角对应着杨辉三角，第N层相应位置的数值相乘之和就是SUM。于是先预处理好杨辉三角，再按字典序从小到大进行深度优先搜索。

代码

const
  maxn=100;
var
  a:array[0..maxn] of longint;
  f:array[0..maxn] of boolean;
  b:array[0..maxn,0..maxn] of longint;
  n,sum:longint;


procedure init;
var
  i,j:longint;
begin
  readln(n,sum);
  for i:=1 to n do
    b[i,1]:=1;
  for i:=2 to n do
    for j:=2 to i do
      b[i,j]:=b[i-1,j]+b[i-1,j-1];
end;


procedure dfs(dep,s:longint);
var
  i:longint;
begin
  if s>sum then exit;
  if dep>n then
    begin
      if sum=s then
        begin
          for i:=1 to n do
            write(a[i],' ');
          halt;
        end;
      exit;
    end;
  for i:=1 to n do
    if not f[i] then
      begin
        f[i]:=true;
        a[dep]:=i;
        dfs(dep+1,s+b[n,dep]*i);
        f[i]:=false;
      end;
end;


begin
  init;
  dfs(1,0);
end.