洛谷P1434 滑雪(记忆化)

滑雪

题目描述

Michael喜欢滑雪。这并不奇怪，因为滑雪的确很刺激。可是为了获得速度，滑的区域必须向下倾斜，而且当你滑到坡底，你不得不再次走上坡或者等待升降机来载你。Michael想知道在一个区域中最长的滑坡。区域由一个二维数组给出。数组的每个数字代表点的高度。下面是一个例子：

1 2 3 4 5

16 17 18 19 6

15 24 25 20 7

14 23 22 21 8

13 12 11 10 9

一个人可以从某个点滑向上下左右相邻四个点之一，当且仅当高度减小。在上面的例子中，一条可行的滑坡为24－17－16－1（从24开始，在1结束）。当然25－24－23―┅―3―2―1更长。事实上，这是最长的一条。

输入输出格式

输入格式：

输入的第一行为表示区域的二维数组的行数R和列数C（1≤R，C≤100）。下面是R行，每行有C个数，代表高度(两个数字之间用1个空格间隔)。

输出格式：

输出区域中最长滑坡的长度。

分析：记忆化搜索，搜索的时候顺便记录每个点的最大值。

代码

const

  maxn=101;
  dx:array[1..4] of -1..1=(-1,0,1,0);
  dy:array[1..4] of -1..1=(0,1,0,-1);
var
  f,a:array[0..maxn,0..maxn] of longint;
  i,j,n,m,ans:longint;


function check(i,j:longint):boolean;
begin
  check:=true;
  if (i>n) or (i<1) or (j>m) or (j<1) then exit(false);
end;


function max(i,j:longint):longint;
begin
  if i>j then exit(i) else exit(j);
end;


function dfs(x,y:longint):longint;
var
  i,t,p:longint;
begin
  if f[x,y]>0 then exit(f[x,y]);
  t:=1;
  for i:=1 to 4 do
    if (a[x,y]<a[x+dx[i],y+dy[i]]) and (check(x+dx[i],y+dy[i])) then
      begin
        p:=dfs(x+dx[i],y+dy[i])+1;
        if p>t then t:=p;
      end;
  f[x,y]:=t;
  exit(f[x,y]);
end;


begin
  readln(n,m);
  for i:=1 to n do
    for j:=1 to m do
      read(a[i,j]);
  for i:=1 to n do
    for j:=1 to m do
      begin
        f[i,j]:=dfs(i,j);
        if f[i,j]>ans then ans:=f[i,j];
      end;
  writeln(ans);
end.