在Visual FoxPro中创建Web服务

在Visual FoxPro中创建Web服务

注：该文章节选自作者的《Visual FoxPro程序设计参考手册》

创建一个Web服务是一个复杂的过程，这涉及到要使用Internet信息服务（IIS）、Visual FoxPro COM服务程序和简单对象访问协议（SOAP）。在这节中将结合上节中介绍的XMLAdapter和在20.4节中介绍的CursorAdapter来建立一个可以通过HTTP进行获取和修改SQL Server 2000附带示例数据库Northwind中Customers表的Web服务实例。该Web服务的流程图18-11所示。可以看出，这是一个3层架构的客户/服务器模式。

图18-11 Web服务流程图

18.4.1 建立COM服务程序

创建Web服务，首先要建立一个COM服务程序，然后才可以使用Visual FoxPro的Web服务发布向导将COM升迁为Web服务。

1．建立项目和类

新建一个名为MyWebService的项目，然后在项目中使用以下代码创建一个叫做MyClass的.prg文件，在其中建立了一个ChangeCustomer类。

DEFINE CLASS ChangeCustomer AS Session OLEPUBLIC

    DataSession=2       &&私有数据工作期

   

    PROCEDURE Init

        SET MULTILOCKS ON

    ENDPROC

   

    PROCEDURE GetCustomerInfo HelpString "获取客户信息"

        LOCAL oXMLAdapter AS XMLAdapter,oCA AS String,cXML AS String

        oCA=CREATEOBJECT("MyCursorAdapter")    &&建立CursorAdapter对象

        oCA.CursorFill()                            &&按oCA的Alias属性指定的名称生成临时表

        oXMLAdapter=NEWOBJECT("XMLAdapter")   &&建立XMLAdapter

        oXMLAdapter.AddTableSchema(oCA.Alias)      &&加载临时表到XMLAdapter对象

        oXMLAdapter.ToXML("cXML")               &&生成XML字符串

        RELEASE oXMLAdapter,oCA                 &&释放对象实例

        RETURN cXML                            &&返回XML字符串

    ENDPROC

 

    PROCEDURE UpdateCustomer(cXML AS String) HelpString "更新客户信息"

        LOCAL oXMLAdapter AS XMLAdapter,oCA AS CursorAdapter

        oXMLAdapter=NEWOBJECT("XMLAdapter")     &&建立XMLAdapter

        oXMLAdapter.UTF8Encoded=.F.

        oXMLAdapter.IsDiffGram=.T.

        oXMLAdapter.LoadXML(cXML,.F.)              &&加载XML

              

        oCA=CREATEOBJECT("MyCursorAdapter")

        oXMLAdapter.Tables(1).ChangesToCursor(oCA.Alias) &&还原缓冲表

        oCA.CursorAttach(oCA.Alias)                    &&将还原出的缓冲表与CursorAdapter建立关联

        =TABLEUPDATE(.T.)                          &&发送更新

        RELEASE oXMLAdapter,oCA

    ENDPROC    

   

    PROCEDURE Error(nError AS Integer,cMethod AS String,nLine AS Integer)

        LOCAL cText AS String

        cText=cMethod+" 错误号="+LTRIM(STR(nError,5))+" 行号="+LTRIM(STR(nLine,8))+" "+MESSAGE()

        COMRETURNERROR(cText,_VFP.ServerName)

    ENDPROC

ENDDEFINE    

 

*!* 建立基于CursorAdapter的子类，用于连接到SQL Server

DEFINE CLASS MyCursorAdapter AS CursorAdapter

    Alias="Customer"

    BreakOnError= .F.

    DataSourceType="ODBC"

    Tables="Customers"

    SendUpdates=.T.

    AllowDelete=.T.

    AllowInsert=.T.

    AllowUpdate=.T.