拼装组合sql时如何使用绑定变量

最新推荐文章于 2023-03-02 16:38:26 发布
最新推荐文章于 2023-03-02 16:38:26 发布
阅读量688 收藏
点赞数
分类专栏： 数据库开发 文章标签： sql object date session null integer
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/zhaosj1726/article/details/6069540
版权

数据库版本:10.2.0.4
create table zsj_objs as select * from dba_objects;

*************************

方法一
使用本地动态SQL实现:
 create or replace function f_zsj_cursor(v_owner varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   type t_strlist is table of varchar2(100);
   v_strlist t_strlist:=t_strlist();
   v_nls_date_format NLS_SESSION_PARAMETERS.value%type;
begin
   v_sql:='select * from zsj_objs where ';
   if(v_owner is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=upper(v_owner);
       v_sql:=v_sql||'owner=:'||v_strlist.count||' and ';
   end if;
   if(v_object_type is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=upper(v_object_type);
       v_sql:=v_sql||'object_type=:'||v_strlist.count||' and ';
   end if;
   if(v_object_id is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=v_object_id;
       v_sql:=v_sql||'object_id>=:'||v_strlist.count||' and ';
   end if;
   if(v_created is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=to_char(v_created,'yyyy-mm-dd hh24:mi:ss');
       v_sql:=v_sql||'created>=:'||v_strlist.count;
   end if;
   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');
   SELECT VALUE into v_nls_date_format

      FROM NLS_SESSION_PARAMETERS

   WHERE PARAMETER='NLS_DATE_FORMAT';  
   execute immediate 'alter session set nls_date_format=''yyyy-mm-dd hh24:mi:ss''';

   --下面这部分是静态的,而不是动态的,在最大绑定变量数量可知的情况下,代码冗长些,但至少还可以实现,但如果最大绑定变量数量都不确定的话,这里的代码实现不了
   case v_strlist.count
       when 0 then
            open v_cursor for v_sql;
       when 1 then
            open v_cursor for v_sql using v_strlist(1);
       when 2 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2);
       when 3 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2),v_strlist(3);
       when 4 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2),v_strlist(3),v_strlist(4);
   end case;
   execute immediate 'alter session set nls_date_format='''||v_nls_date_format||'''';
   /*不是太明白nls_变量是open cursor时起作用还是fetch cursor时起作用,如果是fetch cursor时起作用的话,也只能是在调用这个函数的客户端关闭这个引用游标之后把这个nls_变量改回原来的设置值了*/
   return v_cursor;

/*这里object_id,created列上的索引都是可供使用的,因为这些列上并不会应用任何表达式的
where object_id>='50000' 实际上执行的是where object_id>=to_number('50000')
where created>='2009-07-26 12:00:00' 实际上执行的是where created>=to_date(' 2009-07-26 12:00:00','syyyy-mm-dd hh24:mi:ss')
*/
end;
/
********************************

方法二

使用dbms_sql实现

使用dbms_sql实现的话,确实要灵活得多.但在11g前,dbms_sql好像还不支持sys_refcursor,所以如果要使用dbms_sql实现上面的逻辑的话,我现在只能使用一个临时表了,不知道是否还有好的实现方式.

CREATE GLOBAL temporary TABLE zsj_objs_temp

ON COMMIT PRESERVE rows

AS SELECT * FROM zsj_objs WHERE 1=0;

create or replace function f_zsj_cursor2(v_owner varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   type t_strlist is table of varchar2(100);
   v_strlist t_strlist:=t_strlist();
   v_nls_date_format NLS_SESSION_PARAMETERS.value%type;
   l_theCursor  INTEGER;
   l_status     INTEGER;
BEGIN
   DELETE FROM zsj_objs_temp;
   v_sql:='insert into zsj_objs_temp select * from zsj_objs where ';
   if(v_owner is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=upper(v_owner);
       v_sql:=v_sql||'owner=:'||v_strlist.count||' and ';
   end if;
   if(v_object_type is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=upper(v_object_type);
       v_sql:=v_sql||'object_type=:'||v_strlist.count||' and ';
   end if;
   if(v_object_id is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=v_object_id;
       v_sql:=v_sql||'object_id>=:'||v_strlist.count||' and ';
   end if;
   if(v_created is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=to_char(v_created,'yyyy-mm-dd hh24:mi:ss');
       v_sql:=v_sql||'created>=:'||v_strlist.count;
   end if;
   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');
   SELECT VALUE into v_nls_date_format

      FROM NLS_SESSION_PARAMETERS

   WHERE PARAMETER='NLS_DATE_FORMAT';  
   execute immediate 'alter session set nls_date_format=''yyyy-mm-dd hh24:mi:ss''';
   l_theCursor:=Dbms_Sql.OPEN_cursor;
   Dbms_Sql.parse(c=>l_theCursor,STATEMENT=>v_sql,language_flag=>Dbms_Sql.native);
   FOR i IN 1..v_strlist.Count
   LOOP
      Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||i,Value=>v_strlist(i));
   END LOOP;
   l_status:=Dbms_Sql.EXECUTE(l_theCursor);
   COMMIT;
   execute immediate 'alter session set nls_date_format='''||v_nls_date_format||''''; --alter session操作不会commit的
   OPEN v_cursor FOR SELECT * FROM zsj_objs_temp;
   return v_cursor;
end;
/

下面这个执行报错,因为顺序不对,应该是解析后才能绑定变量的.
CREATE OR REPLACE function f_zsj_cursor3(v_owner varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   l_theCursor  INTEGER;
   l_status     INTEGER;
   v_var_num    INTEGER:=0;
BEGIN
   DELETE FROM zsj_objs_temp;

   v_sql:='insert into zsj_objs_temp select * from zsj_objs where ';
   if(v_owner is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'owner=:'||v_var_num||' and ';
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>upper(v_owner));
   end if;

   if(v_object_type is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_type=:'||v_var_num||' and ';
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>upper(v_object_type));
   end if;

   if(v_object_id is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_id>=:'||v_var_num||' and ';
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>v_object_id);
   end if;

   if(v_created is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'created>=:'||v_var_num;
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>v_created);
   end if;

   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');


   l_theCursor:=Dbms_Sql.OPEN_cursor;
   Dbms_Sql.parse(c=>l_theCursor,STATEMENT=>v_sql,language_flag=>Dbms_Sql.native);

   l_status:=Dbms_Sql.EXECUTE(l_theCursor);

   COMMIT;

   OPEN v_cursor FOR SELECT * FROM zsj_objs_temp;
   return v_cursor;
end;
/

使用dbms_sql,应用重载函数,什么样类型的变量就给它绑定什么类型的变量,这样就不需要任何的类型转换了,该用的索引就都可以使用了.
 但我觉得代码还是冗长了些,是否可以像我上面那种错误的方法一样实现的简洁些,不要每个if都要写两遍
create or replace function f_zsj_cursor4(v_owner varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   l_theCursor  INTEGER;
   l_status     INTEGER;
   v_var_num    INTEGER:=0;
BEGIN
   DELETE FROM zsj_objs_temp;
   v_sql:='insert into zsj_objs_temp select * from zsj_objs where ';
   if(v_owner is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'owner=:'||v_var_num||' and ';
   end if;
   if(v_object_type is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_type=:'||v_var_num||' and ';
   end if;
   if(v_object_id is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_id>=:'||v_var_num||' and ';
   end if;
   if(v_created is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'created>=:'||v_var_num;
   end if;
   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');

   l_theCursor:=Dbms_Sql.OPEN_cursor;
   Dbms_Sql.parse(c=>l_theCursor,STATEMENT=>v_sql,language_flag=>Dbms_Sql.native);
   v_var_num:=0;
   if(v_owner is not null) then
       v_var_num:=v_var_num+1;
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>upper(v_owner));
   end if;
   if(v_object_type is not null) then
       v_var_num:=v_var_num+1;
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>upper(v_object_type));
   end if;
   if(v_object_id is not null) then
       v_var_num:=v_var_num+1;
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>v_object_id);
   end if;
   if(v_created is not null) then
       v_var_num:=v_var_num+1;
       Dbms_Sql.bind_variable(c=>l_theCursor,NAME=>':'||v_var_num,Value=>v_created);
   end if;
   l_status:=Dbms_Sql.EXECUTE(l_theCursor);
   COMMIT;
   OPEN v_cursor FOR SELECT * FROM zsj_objs_temp;
   return v_cursor;
end;
/
***************************************
方法三
使用context,sys_context来实现
先是授权:
sys> grant create any context to btocuser;                                                                                    
Grant succeeded.
btocuser> create context zsj_cursor_context using f_zsj_cursor5;  
-- 创建context,并与f_zsj_cursor5关联起来(只能在这个名称的包,函数,过程里使用dbms_session.set_context来设置它的属性值)

CREATE OR REPLACE function f_zsj_cursor5(v_owner varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   v_nls_date_format NLS_SESSION_PARAMETERS.value%type;
   v_var_num INTEGER:=0;
begin
   v_sql:='select * from zsj_objs where ';
   if(v_owner is not null) THEN
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'owner=sys_context(''zsj_cursor_context'',''n'||v_var_num||''') and ';
       dbms_session.set_context('zsj_cursor_context','n'||v_var_num,upper(v_owner));
   end if;
   if(v_object_type is not null) THEN
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_type=sys_context(''zsj_cursor_context'',''n'||v_var_num||''') and ';
       dbms_session.set_context('zsj_cursor_context','n'||v_var_num,upper(v_object_type));
   end if;
   if(v_object_id is not null) then
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'object_id>=sys_context(''zsj_cursor_context'',''n'||v_var_num||''') and ';
       dbms_session.set_context('zsj_cursor_context','n'||v_var_num,v_object_id);
   end if;
   if(v_created is not null) THEN
       v_var_num:=v_var_num+1;
       v_sql:=v_sql||'created>=sys_context(''zsj_cursor_context'',''n'||v_var_num||''')';
       dbms_session.set_context('zsj_cursor_context','n'||v_var_num,To_Char(v_created,'yyyy-mm-dd hh24:mi:ss'));
   end if;
   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');
   SELECT VALUE into v_nls_date_format FROM NLS_SESSION_PARAMETERS WHERE PARAMETER='NLS_DATE_FORMAT';
   execute immediate 'alter session set nls_date_format=''yyyy-mm-dd hh24:mi:ss''';
   open v_cursor for v_sql;
   execute immediate 'alter session set nls_date_format='''||v_nls_date_format||'''';
   return v_cursor;
end;
/
上面这个实现里也存在着和f_zsj_cursor同样的注意点:
就是dbms_session.set_context设置的属性值都是varchar2的,sys_context的返回值都是varchar2的.
所以需要一些特殊设置,可以在你传入的值端进行隐式的类型转换,而不是在表字段端进行类型转换.
**********************************
补充一个in串的实现(使用绑定变量的),只写本地动态SQL的实现形式了
这里不讨论绑定变量实现的优劣.

CREATE OR REPLACE TYPE t_strtable IS TABLE OF VARCHAR2(256);

CREATE OR REPLACE FUNCTION seperate_str(p_str IN VARCHAR2) RETURN t_strTable
IS
   l_str   LONG DEFAULT p_str||',';
   l_n     NUMBER;
   l_data  t_strTable:=t_strTable();
BEGIN
   LOOP
      l_n:=InStr(l_str,',');
      EXIT WHEN (Nvl(l_n,0)=0);
      l_data.extend();
      l_data(l_data.count):=LTrim(RTrim(SubStr(l_str,1,l_n-1)));
      l_str:=SubStr(l_str,l_n+1);
   END LOOP;
   RETURN l_data;
END;
/

create or replace function f_zsj_cursor8(v_owners varchar2,v_object_type varchar2,v_object_id number,v_created date) return sys_refcursor
is
   --v_owners可能是sys 或者sys,system,scott之类的形式
   v_cursor sys_refcursor;
   v_sql varchar2(32000);
   type t_strlist is table of varchar2(100);
   v_strlist t_strlist:=t_strlist();
   v_nls_date_format NLS_SESSION_PARAMETERS.value%type;
begin
   v_sql:='select * from zsj_objs where ';
   if(v_owners is not null) then
   --这里一个owner和多个(两个及两个以上)owner分开处理了
       if( instr(v_owners,',')>0 ) then
           --这里假定owner的数据分布是均匀的,且典型输入情况下是输入5个owner连成的串,所以使用了cardinality(5)的提示
           v_strlist.extend();
           v_strlist(v_strlist.count):=upper(v_owners);
           v_sql:=v_sql||'owner in(select /*+ cardinality(5)*/column_value from TABLE(seperate_str(:'||v_strlist.count||'))) and ';           
       else
           v_strlist.extend();
           v_strlist(v_strlist.count):=upper(v_owners);
           v_sql:=v_sql||'owner=:'||v_strlist.count||' and ';
       end if;
   end if;

   if(v_object_type is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=upper(v_object_type);
       v_sql:=v_sql||'object_type=:'||v_strlist.count||' and ';
   end if;

   if(v_object_id is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=v_object_id;
       v_sql:=v_sql||'object_id>=:'||v_strlist.count||' and ';
   end if;

   if(v_created is not null) then
       v_strlist.extend();
       v_strlist(v_strlist.count):=to_char(v_created,'yyyy-mm-dd hh24:mi:ss');
       v_sql:=v_sql||'created>=:'||v_strlist.count;
   end if;

   v_sql:=regexp_replace(v_sql,' and $');
   v_sql:=regexp_replace(v_sql,' where $');

   SELECT VALUE into v_nls_date_format
      FROM NLS_SESSION_PARAMETERS
   WHERE PARAMETER='NLS_DATE_FORMAT';  

   execute immediate 'alter session set nls_date_format=''yyyy-mm-dd hh24:mi:ss''';

   case v_strlist.count
       when 0 then
            open v_cursor for v_sql;
       when 1 then
            open v_cursor for v_sql using v_strlist(1);
       when 2 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2);
       when 3 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2),v_strlist(3);
       when 4 then
            open v_cursor for v_sql using v_strlist(1),v_strlist(2),v_strlist(3),v_strlist(4);
   end case;

   execute immediate 'alter session set nls_date_format='''||v_nls_date_format||'''';

   return v_cursor;
end;
/

zhaosj1726
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
Oracle实现动态SQL的拼装要领
09-10
主要介绍了Oracle实现动态SQL的拼装要领,对于Oracle的进一步学习来说非常重要,需要的朋友可以参考下
SQL语句拼装工具V2
03-19
写java程序时用来拼装sql语句时使用的小工具，在.net 4.0环境下运行。 跟前一版本比较，增加了前缀和空格位置的自定义，并增加了一个配置文件，保存自定义项 例如将 select a, b, c from abc where a like('3') ...
日期格式问题NLS_DATE_FORMAT = ''yyyy-mm-dd HH24:MI:SS''
roc_phoneix的专栏
09-06 2242
oracle 11.2.0.2以后的NLS_DATE_FORMAT 设置 conn /as sysdba   CREATE OR REPLACE TRIGGER LOGINTRG  AFTER LOGON ON DATABASE  BEGIN EXECUTE IMMEDIATE 'ALTER SESSION SET  NLS_DATE_FORMAT = ''yyyy-m
PLSQL调用JAVA存储过程实现修改系统日期及时间
zzy93421的专栏
05-10 1075
PLSQL调用JAVA存储过程实现修改系统日期及时间 Author:张志远 mail:[email protected] 1.        以用户SCOTT登录，在PLSQL中执行如下脚本，即编译JAVA SOURCE： create or replace and compile java source named exesyscommand as import java.io.*; imp...
Oracle SQL调优系列之绑定变量用法简介
Nicky's blog
09-20 3389
继上一篇博客Oracle的cursor学习笔记：[Oracle的游标Cursor原理简介](https://smilenicky.blog.csdn.net/article/details/99946785)，再介绍oracle的绑定变量 介绍绑定变量之前，先介绍SQL执行过程和硬解析的概念： 执行sql的过程，会将sql的 /*通过性能视图查询*/ select a.*, b.name from v$sesstat a, v$statname b where a.stat
oracle sql调优之绑定变量用法举例
力哥讲技术
03-02 3050
的集的势非常大（也就是有个值在字段中出现的比例特别的大）的情况下，使用绑定变量可能会导致查询计划错误，因而会使查询效率非常低。绑定变量只是起到占位的作用，同名的绑定变量并不意味着在它们是同样的，在传递时要考虑的是传递的值与绑定变量出现顺序的对位，而不是绑定变量的名称。绑定变量不能当作嵌入的字符串来使用，只能当作语句中的变量来用。）资源，严重的影响系统的规模的扩大（即限制了系统的并发行）， 而且引起的问题不能通过增加内存条和。语句的开发者来说，掌握绑定变量的用法是非常重要的。语句中的常量的替代变量。
加工支座组合夹具虚拟拼装设计培训文件
06-30
加工支座组合夹具虚拟拼装设计培训文件
易语言SQL拼装1.1 链式编程, 拼装SQL方法
06-01
于是决定用易语言模仿一个, 这个版本只支持 "生成拼装SQL", 下次准备结合ad0o对象. 允许直接操作数据库。制作这么一个东西的初衷是为了 "更快更高效的开发程序", 我们往往在SQL上耽搁了太多时间. 并不是它难. 而是...
Java如何使用Query动态拼接SQL详解
08-26
主要给大家介绍了关于Java如何使用Query动态拼接SQL的相关资料，文中通过示例代码介绍的非常详细，对大家的学习或者工作具有一定的参考学习价值，需要的朋友们下面随着小编来一起学习学习吧
关于NLS_DATE_FORMAT的设置
shaozengwei的专栏
10-28 2954
Oracle的日期格式默认设置是DD-MON-YY，很多时候我们需要修改这种格式以满足我们的需求。     可以通过设置NLS_DATE_FORMAT来改变日期格式，为了让这种改变永久生效，介绍下面的几种方法：     1、修改glogin.sql文件，这个文件的路径：     Windows下，%ORACLE_HOME%\sqlplus\admin     UNIX下，$ORACLE_H
oracle11g升级12c后，日期格式显示不对？
sqlora的专栏
08-26 839
oracle11g升级12c后，日期格式显示不对 11.2.0.1=》12.2.0.1 原11g下： 新12c下： 对比nls参数结果： 12c: 11g下： 发现11g下没有做任何设置。 尝试修改sys下登录触发器： CREATE OR REPLACE TRIGGER LOGINTRG AFTER LOGON ON DATABASE BEGIN EXECU...
修改ORACLE-NLS_DATE_FORMAT时间格式的四种方式
还不算晕的专栏
09-05 5911
改变ORACLE中时间显示格式的显示有以下方式： 1.可以在用户环境变量中指定（LINUX)。 在用户的.bash_profile中增加两句： export NLS_LANG=AMERICAN       ---要注意这一句必须指定，不然下一句不生效。 export NLS_DATE_FORMAT='yyyy/mm/dd hh24:mi:ss' 2.在SQLPLUS的glogin
oracle修改session日期格式,使用JDBC改变Oracle的session参数 NLS_DATE_FORMAT
weixin_29476767的博客
04-08 398
最近项目除1个问题，场景大概是这样的，项目在国外开发，在项目开发进程中使用了大量的http://www.wfuyu.com/oracle/函数TO_DATE，但是开发人员没有写第2个参数。所以项目在国外的http://www.wfuyu.com/server/上可以正常运行，可是在国内的http://www.wfuyu.com/server/上就不能正常运行了。通过调查是由于，TO_DATE函数的...
PL/SQL拼接和使用绑定变量
weixin_30263073的博客
12-24 191
begin for iin1 ..1000000loop executeimmediate'insert into p1 values(' || i || ',' || i ||')'; commit; endloop; end; 可以看到动态使用拼接的是使用的常值 begin for iin1 ....
什么是SQL绑定变量，如何实现绑定变量？
java开发指南博客 【转载】
06-14 1234
1. 认识绑定变量： 绑定变量是为了减少解析的，比如你有个语句这样 select aaa,bbb from ccc where ddd=eee; 如果经常通过改变eee这个谓词赋值来查询，像如下 select aaa,bbb from ccc where ddd=fff; select aaa,bbb from ccc where ddd=ggg; select aaa,bbb from...
c++宏定义拼装变量名
最新发布
03-22
下面是一个示例，展示了如何使用宏定义来拼装变量名： ```cpp #include using namespace std; #define CONCAT(a, b) a##b int main() { int num1 = 10; int num2 = 20; int CONCAT(result, 1) = num1 + num...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值