30天自制操作系统第3天harib00d

30天自制操作系统

第3天进入32位模式并导入 C 语言

读入 10 个柱面

harib00d

准备材料（windows环境）

• VMware Workstation
• Visual Studio Code
• 程序和源代码：https://pan.baidu.com/s/1bFGAYgnA0m9KB7tzFrMD5g
  提取码：d210
• Makefile
• windows 批处理

开始实验

1. 在tolset文件夹下创建子文件侠harib00d;

2. 打开记事本，输入以下代码并另存为 !cons_nt.bat文件（windows 批处理），存放在harib00d文件夹中;

cmd.exe

ps:当然也可以直接使用 win + r 快捷键也可以，不过最好还是创建一个比较好。因为以后打开时不需要再麻烦了。

3. 打开 VC code 创建 ipl.nas 文件，输入以下代码，也存放的harib00d中；

; haribote-ipl
; TAB=4

CYLS	EQU		10				; 要读到什么程度

		ORG		0x7c00			; 启动装载程序

; 以下记述用于标准FAT12格式软盘

		JMP		entry
		DB		0x90
		DB		"HARIBOTE"		; 磁盘名称（可以是任意字符串）
		DW		512				; 每个扇区的大小（必须是512）
		DB		1				; 簇的大小（必须为一个扇区）
		DW		1				; FAT12的起始位置（一般从第一个扇区开始
		DB		2				; FAT的个数（必须为2）
		DW		224				; 根目录的大小（一般设成224项）
		DW		2880			; 该磁盘的大小（必须是2880扇区）
		DB		0xf0			; 该磁盘的种类（必须是0xf0
		DW		9				; FAt的长度（必须是9扇区）
		DW		18				; 一个磁道有几个扇区（必须是18）
		DW		2				; 磁头数（必须是2）
		DD		0				; 不使用分区，必须是0
		DD		2880			; 磁盘大小
		DB		0,0,0x29		; 意义不明固定
		DD		0xffffffff		; （可能是）卷标号码
		DB		"HARIBOTEOS "	; 磁盘的名称（11字节）
		DB		"FAT12   "		; 磁盘格式名称（8字节）
		RESB	18				; 先空出18字节

; 程序主体

entry:
		MOV		AX,0			; 初始化寄存器
		MOV		SS,AX
		MOV		SP,0x7c00
		MOV		DS,AX

; 坊磁盘

		MOV		AX,0x0820
		MOV		ES,AX
		MOV		CH,0			; 柱面 0
		MOV		DH,0			; 磁头 0
		MOV		CL,2			; 扇区 2
readloop:
		MOV		SI,0			; 记录失败次数的寄存器
retry:
		MOV		AH,0x02			; AH=0x02 : 读入磁盘
		MOV		AL,1			; 1 个扇区
		MOV		BX,0
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 调用磁盘BIOS
		JNC		next			; 没出错时跳转到next
		ADD		SI,1			; SI 加 1
		CMP		SI,5			; 比较 SI 与 5
		JAE		error			; SI >= 5 时，跳转到error
		MOV		AH,0x00
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 重置驱动器
		JMP		retry
next:
		MOV		AX,ES			; 把内存地址后移0x200
		ADD		AX,0x0020
		MOV		ES,AX			; 因为没有 ADD ES,0x020 指令，所以这里稍微绕个弯
		ADD		CL,1			; CL 加 1
		CMP		CL,18			; 比较 CL 与 18
		JBE		readloop		; 如果 CL <= 18，则跳转至readloop 
		MOV		CL,1
		ADD		DH,1
		CMP		DH,2
		JB		readloop		; 如果 DH < 2， 则跳转到readloop
		MOV		DH,0
		ADD		CH,1
		CMP		CH,CYLS
		JB		readloop		; 如果 CH < CYLS，则跳转至readloop

; 虽然读完了，但是因为暂时没有要做的事所以停止等待指令

fin:
		HLT						; 让CPu停止，等待指令
		JMP		fin				; 无限循环

error:
		MOV		SI,msg
putloop:
		MOV		AL,[SI]
		ADD		SI,1			; SI 加 1
		CMP		AL,0
		JE		fin
		MOV		AH,0x0e			; 显示一个文字
		MOV		BX,15			; 指定字符颜色
		INT		0x10			; 调用显卡BIOS
		JMP		putloop
msg:
		DB		0x0a, 0x0a		; 换行两次
		DB		"load error"
		DB		0x0a			; 换行
		DB		0

		RESB	0x7dfe-$		; 重复0x00一直到0x7dfe

		DB		0x55, 0xaa

		

4. 打开记事本，输入以下代码，另存为 make.bat, 同样放到harib00d中；

..\z_tools\make.exe %1 %2 %3 %4 %5 %6 %7 %8 %9

5. 创建 Makefile,并输入以下代码并存放到harib00d中;

TOOLPATH = ../z_tools/
MAKE     = $(TOOLPATH)make.exe -r
NASK     = $(TOOLPATH)nask.exe
EDIMG    = $(TOOLPATH)edimg.exe
IMGTOL   = $(TOOLPATH)imgtol.com
COPY     = copy
DEL      = del

# 默认操作

default :
	$(MAKE) img

# 文件生成规则

ipl.bin : ipl.nas Makefile
	$(NASK) ipl.nas ipl.bin ipl.lst

haribote.img : ipl.bin Makefile
	$(EDIMG)   imgin:../z_tools/fdimg0at.tek \
		wbinimg src:ipl.bin len:512 from:0 to:0   imgout:haribote.img

# 命令

asm :
	$(MAKE) ipl.bin

img :
	$(MAKE) haribote.img

run :
	$(MAKE) img
	$(COPY) haribote.img ..\z_tools\qemu\fdimage0.bin
	$(MAKE) -C ../z_tools/qemu

install :
	$(MAKE) img
	$(IMGTOL) w a: haribote.img

clean :
	-$(DEL) ipl.bin
	-$(DEL) ipl.lst

src_only :
	$(MAKE) clean
	-$(DEL) haribote.img

编译及运行

1. 双击 !cons_nt.bat,并在打开的命令行中输入 make run
   

2. VMware中运行结果，如下图
   
   ps: 结果就是这样，因为本次实验的目的是读入 10 个柱面,而且什么都没输出。
   好的今天到这里harib00d就张结束了，请大家多多支持！！！