如何使用 Director 编写“拼图游戏”

原创 2004年07月15日 20:52:00


如何使用 Director 编写“拼图游戏”






如今,世界上很多大公司都使用 Director 制作自己的多媒体教学光盘。.这其中包括微软公司,苹果公司,Adobe 公司等等(尽管这些公司不是多媒体制作公司)。最近,二十世纪福克斯公司推出的“X Files Unrestricted Access”(我最喜欢的电视剧《X 档案》的资料光盘)中也使用了 Director 和 QuikTime VR 技术。不仅在国外使用 Director 编写多媒体光盘的人越来越多,国内也有不少人在从事 Director 的编程工作。Director 如今已成为多媒体制作工具事实上的标准。可是比较起来,我们对 Director 使用还处于较低的水平。看过很多国内多媒体公司制作的光盘,大多数的交互控制很简单,无非是闪动的按钮和图像,单击可进入其它场景,有如幻灯片。估计里面使用了无数的 goto xx 语句,和充斥了美工制作的大量的二维动画。这种光盘还不如使用 PowerPoint 来制作(只是个玩笑)。其中原因有很多,其中最重要的是我们的编程人员对 Lingo 语言没有很好地掌握,这直接影响到对创意的取舍,如果编程人员用 Director 无法实现创意,很多原先的构思将被撤消,因此,编程人员对 Lingo 语言的运用直接影响到最终产品优劣。这需要更多的 Director 编程人员充分掌握 Lingo 。我仅在此抛砖引玉,将我使用 Director 制作小游戏的经验与众多的 Director 爱好者分享。



很多人都玩过“拼图游戏”,我很早以前就是个“拼图游戏”的爱好者,.最早是玩苹果电脑(Macintosh)上拼图游戏 puzzle 。后来,一个很偶然的机会,我得到一张苹果版的 Adobe Illustrator 的安装光盘。意外的发现上面有一个维娜斯头像(此为 Illustrator 的启动屏幕)的拼图游戏,并发现它是使用 Director 编写的(香港方面用 Director 4.0 制作的《和刘小慧的一个星期》也设计了一个拼图游戏)。当时我已经开始使用 Director 编写多媒体演示程序(那是 1995 年),但是缺少对 Lingo 的高级功能的掌握,往往我所编写的程序使用了不少函数,而对列表和对象这样的数据结构却从未使用过。在某些情况下,这种编程经常是事倍功半。三年前,我使用 Director 编写了第一个“拼图游戏”,这个版本费了我很长时间(大约一个星期),程序代码很长,也很乱。后来连我自己都有些看不懂了。随着我对 Lingo 的日益了解,逐渐发现在以前编写的程序中没有使用列表是多么的愚蠢。几天前,我重新用 Director 编写了新版本的“拼图游戏”。不仅原代码减小了(更易于理解),而且仅花费了两个小时。现在我们逐步分析如何用 Director 编写“拼图游戏”。

 




使用列表是编写“拼图游戏”的关键,可以说列表在 Lingo 编程中比对象更为关键。因为使用 Lingo 面向对象功能的用户要比使用其传统数据结构功能的用户要少(国外使用 Lingo 对象的用户很多)。我所编写“拼图游戏”的界面如下图:image001.gif

 


首先,我制作了 16 个 BMP 格式的拼图,每个为每个为 100 * 100 像素大小。分别代表上图中 16 个小拼图,命名为 1.bmp,2.bmp,3.bmp,4.bmp,5.bmp,…..。并将这 16 个文件导入

Director 中。它们分别是角色库中的 1 到 16 位的角色。如下图:image003.gif






同时,我们将这 16 个拼图依次排列在 1 到 16 号通道上,如下图:image005.gif

现在,我们要讨论使用 Director 编写“拼图游戏”的思路。Lingo 中的在线替换角色函数the memberNum of sprite 是其中所用到的最重要的函数。我们正是通过鼠标单击在相应的精灵通道上时,将所单击的精灵的角色替换为 16 个拼图中唯一的一个空白位图角色。这其中有几个难点需要注意。第一,这种替换并非是任意的,只有空白周围垂直和水平方向的拼图才可以移动。举例说明,见下图:


image007.gif

上图空白块的周围只有数字为 6,9,7,14 的拼图才可以移动。而其它拼图在单击时,将不会与空白处相互替换。这需要建立空白块在不同通道时的可以移动通道列表。这里用到了一个全局变量 gEmpty,它用来存储角色为空白的通道号;第二,每次启动该“拼图游戏”时,必须随机排列此拼图,而且每次图案都不相同。这就必须建立一个每个通道的角色列表;第三,必须建立一个判定条件,最终玩家拼出如第一个图所示的图案,则表明玩家已经成功地拼出图形。这需要建立一个列表,即最终图案中各个通道中的角色库列表,也就是列表 Finish = [1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16]。为了和最终列表 Finish 比较,在当前帧循环时,每次退出当前帧都要生成一个临时的各个通道的角色列表;还有一点,第一次进入循环帧时需要根据随机列表作所有通道的角色替换,而以后几次循环时每次进入循环帧则不需要,因此需要一个判定变量以判定是否为第一次进入循环帧。


看起来很复杂,但实际做一遍并没有那么麻烦,相对使用别的高级语言来编写此程序,Lingo 需要您使用新的思路来考虑编程。它使您不用涉及许多编程细节,而更多的考虑解决问题的方法,而它又没有传统脚本语言那么功能贫乏。


首先,我们需要自己编写几个函数(或个人句柄)。


第一个函数是生成 16 个随机列表的函数 generateList。

它的具体代码如下:

on generateList

global gEmpty,randomList

set randomList = []

repeat with x = 1 to 16

addAt(randomList,random(x),x)

end repeat

end


因为 Lingo 没有提供对列表随机排列的功能,所以这里使用了来自 Tab Julius 先生的《Lingo !高级指南》中的一段代码,它非常巧妙地通过循环语句中使用 addAt(),random()函数生成随机列表。它在循环中先随机产生列表位置,并将其赋予 1-16 中的值,当 addAt()函数向列表中相同位置添加值时,它会将位置推后,这种特殊的工作方式将不会出现重复现象。


第二个函数也是最重要的一个函数 exchange()。 它有一个参数,.此参数为通道号。当在一个与空白垂直或水平相邻的拼图上单击时,应将二者的角色对换,即,空白所在的通道将角色换为被单击的通道的角色,而单击的通道的角色换为空白。并将被单击的通道号赋予标识空白所在通道的变量 gEmpty。函数中的变量 x 为临时变量,用于作替换时暂存数据。

on exchange n

global gEmpty

set x to the memberNum of sprite gEmpty

set the memberNum of sprite gEmpty to the memberNum of sprite n

set the memberNum of sprite n to x

updatestage

set gEmpty = n

end


此函数用在每个循环帧中 1-16 号通道,用法如下:


on mouseup

if inList(1) then

exchange 1

puppetsound "click"

end if

end


这里用到了另一个编写的函数 inList(),此函数用于判别当前被单击的通道是否在可移动列表 M 中,如果是在列表 M 中,则返回 TRUE。


函数 inList() 代码如下:

on inList cnt

set countnum = count(M)

repeat with x = 1 to countnum

if cnt = getAt(M,x) then

return TRUE

exit repeat

end if

end repeat

end

其中 M 为当前可移动通道号列表,首先函数使用 count()函数计算列表 M 中成员的个数,并将其赋予变量 countnum,变量 countnum 为循环检测的终止变量。循环语句中,判定 inList() 的参数 cnt 是否在列表 M 中。如果在其中,则返回 TRUE,并退出循环。


另外一个函数是 move(),它将返回当前可移动通道列表。


on move sth

return getAt(mList,sth)

end


它根据空白所在通道号来返回当前可移动拼图通道号列表。这里我使用了一个二维列表 mList = [m1,m2,m3,m4,m5,m6,m7,m8,m9,m10,m11,m12,m13,m14,m15,m16],其中 m1,m2,m3,……为空白在 1,2,3,4,5,…..时,可移动通道号列表。举例,如第一张图,当空白处为 16 号通道,可以移动的通道为 12 和 15 ,即,m16 = [12,15]。所有这些列表将在on startmovie 事件句柄中初始化。具体代码如下:


on startMovie

global gEmpty,randomList,First,Finish,Tmp,m1,m2,m3,m4,m5,m6,m7,m8,m9,m10,m11,m12,m13,m14,m15,m16,mList,M

set M = []

set Tmp = []

set Finish = [1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16]

set m1 = [2,5]

set m2 = [1,3,6]

set m3 = [2,4,7]

set m4 = [3,8]

set m5 = [1,6,9]

set m6 = [2,5,7,10]

set m7 = [3,6,8,11]

set m8 = [4,7,12]

set m9 = [5,10,13]

set m10 = [6,9,11,14]

set m11 = [7,10,12,15]

set m12 = [8,11,16]

set m13 = [9,14]

set m14 = [10,13,15]

set m15 = [11,14,16]

set m16 = [12,15]

set mList = [m1,m2,m3,m4,m5,m6,m7,m8,m9,m10,m11,m12,m13,m14,m15,m16]

set First = 0

generateList

set gEmpty = getOne(randomList,16)

repeat with i = 1 to 16

puppetsprite i,TRUE

end repeat

end startMovie


这段代码有几点需要说明:首先,初始化了列表和许多全局变量。其中 First 变量赋予值 为 0 ,第一次进入循环帧时,需要根据 generateList 函数生成的随机角色列表 randomList 来更新各个通道的角色,以产生每次进入游戏的随机图案;其次,使用 getOne() 函数获取全局变量 randomList 列表中 16 号角色(即,空白角色)所在的通道号;最后,将所有 1 到 16 号通道木偶化。


我已经讲述了所有编写的函数,剩下的一步是最后的,也是最关键的一步。即,在循环帧的帧脚本中调用这些函数。

具体帧脚本如下:


global gEmpty,randomList,First,Finish,Tmp,m1,m2,m3,m4,m5,m6,m7,m8,m9,m10,m11,m12,m13,m14,m15,m16,mList,M

on enterframe

if First = 0 then

repeat with i = 1 to 16

puppetsprite i,TRUE

set the memberNum of sprite i to getAt(randomList,i)

end repeat

set First = 1

end if

if Finish = Tmp then

go the frame + 1

else

set tmp = []

end if

set M = move(gEmpty)

end

在进入帧事件句柄 on enterframe 中,首先根据变量 First 来判定是否第一次进入当前循环帧,判定条件是 First 是否为 0。如果是,则根据 randomList 列表中的值来更新通道 1 - 16 的角色。更新后,将变量 First 赋值为 1 。以免下次在执行此操作。然后比较最终列表 Finish 与 临时列表 Tmp 之间是否相同,如果相同则,拼图结束。跳到结束帧。否则继续在当前帧循环,并将 tmp 列表赋值为空,以免在 tmp 列表因 on exitFrame 的操作而叠加。最后取得空白在当前通道时的可移动列表 M。


on exitFrame

repeat with x = 1 to 16

addAt(Tmp,the memberNum of sprite x )

end repeat

go the frame

end


在退出帧事件句柄 on exitFrame 中,通过循环生成当前各个通道的角色临时列表 Tmp,并用 go the frame 在当前帧循环。



所有程序代码都已讲述完毕。如果将这 16 张图片换成您喜爱的图片的拼图,你可以生成自己风格的拼图游戏。通过上面的讲述,您会发现 Lingo 编程的确与众不同。这样的游戏可以用如此简单的代码在很短的时间内编写完毕。此程序虽然不复杂,但它包含了许多 Lingo 的使用技巧。

拼图游戏---java实现

游戏说明: 设计一款拼图游戏,要求点击图片按钮,实现图片按钮的移动,直到每一个按钮都到达指定位置游戏终止退出。 游戏设计思路: 1.准备一张图像文件; 2.创建N个按钮图标,每个按钮图标里面存...
  • angry_youth
  • angry_youth
  • 2017年05月08日 11:35
  • 3116

java学习心得 关于如何设计一个拼图游戏

拼图游戏的设计可以分为如下几个部分:1)ui设计,2)键盘监听,事件处理,3)游戏逻辑。ui设计较为简单,继承panel类即可实现;键盘监听功能继承KeyAdapter类或者实现KeyLisener接...
  • nufangn
  • nufangn
  • 2016年01月19日 20:58
  • 2033

用Qt图形视图框架开发拼图游戏

用Qt的图形视图框架(Graphics View Framework)做了一个拼图游戏DEMO,演示了:QGraphicsView、QGraphicsScene、QGraphicsItem的基本用法;...
  • foruok
  • foruok
  • 2016年10月14日 07:10
  • 4935

拼图游戏-从基础到应用玩转手势变化。

相信大家在小的时候都玩过拼图游戏,现如今,手机普及,能在手机上玩的游戏越来越多,于是乎,重温小时候,编写这个简易拼图游戏,而且也能进一步加深android的一些基础知识。 老规矩,先是效果图~:...
  • yyh448522331
  • yyh448522331
  • 2016年10月28日 09:40
  • 1625

纯C语言写的拼图游戏源码

#include #include #include #include int step=0; void map()//游戏菜单函数。 { printf("▇▇▇▇▇▇▇▇▇▇▇▇▇▇\n")...
  • u011131296
  • u011131296
  • 2013年12月12日 17:44
  • 2519

Android应用开发入门篇-拼图游戏

前一段时间为了学习android应用开发,尝试写了个简单的拼图应用,在此记录下实现流程的核心部分,同时也希望给其他开发者入门参考带来帮助。 1. 基本的界面设计     首先应该设计出各个...
  • u010666109
  • u010666109
  • 2014年04月01日 20:38
  • 1845

速度挑战 - 2小时完成HTML5拼图小游戏

初学lufylegend.js之日,我用lufylegend.js开发了第一个HTML5小游戏——拼图游戏,还写了篇博文来炫耀一下:HTML5小游戏《智力大拼图》发布,挑战你的思维风暴。不过当时初学游...
  • yorhomwang
  • yorhomwang
  • 2016年08月11日 19:32
  • 8004

Cinema Director 教程——unity制作过程动画,剧情等

来自:http://magicbullet.hatenablog.jp/entry/UnityAsset_CinemaDirector_en In this blog, main target ...
  • zhaoguanghui2012
  • zhaoguanghui2012
  • 2016年12月01日 14:48
  • 5109

Android拼图游戏开发全纪录1

今天我们继续来讲解Android拼图游戏全纪录的第二篇,今天要完成的任务比较简单:界面布局和资源文件 1资源文件: 我们在开发一个项目的时候,首先要定下这个App的基调,是小清新呢还是重口...
  • x359981514
  • x359981514
  • 2014年01月31日 11:39
  • 22416

cocos2dx3.2 整体概览(二)—— Director(导演)

导演一词让人联想到了拍电影,没错,我们所制作的游戏,就相当于给游戏玩家安排体验了一场电影,而导演就是控制整场“电影”流程的关键所在。 引擎中每一个类的功能都很强大,因此我在学习的时候,把每一个类的功...
  • m294955408
  • m294955408
  • 2014年09月26日 11:05
  • 680
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:如何使用 Director 编写“拼图游戏”
举报原因:
原因补充:

(最多只允许输入30个字)