DGL库的使用Demo

最新推荐文章于 2024-03-18 13:24:46 发布
最新推荐文章于 2024-03-18 13:24:46 发布
阅读量5.9k 收藏 1
点赞数
分类专栏： Delphi泛型库DGL 文章标签： integer delphi div interface string
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/housisong/article/details/1338731
版权

                         DGL库的使用Demo
                                      HouSisong@GMail.com

tag:Delphi泛型库,DGL,泛型,DGL Demo,STL

(Delphi泛型库DGL 下载)   (DGL的安装方法是把DGL所在的目录设置到Delphi的搜索路径中)

(todo: 算法使用的Demo / 具现化容纳自定义类型的容器的Demo )


要运行Demo,需要： uses  DGL_Pointer,DGL_Byte,DGL_Integer,_DGLMap_String_Integer,DGL_String;


//Demo uses IIntVector ---------------------------------------------------------
procedure TFormDGLDemo.btn_IIntVectorClick(Sender: TObject);
var
  intVector : IIntVector; //interface type ; Vector use as delphi's array;
  i,Sum : integer;
begin
  intVector :=TIntVector.Create;

  for i:=0 to 100-1 do
    intVector.PushBack(i);
  Assert(intVector.Size()=100);

  Sum:=0;
  for i:=0 to intVector.Size()-1 do
    Sum:=Sum+intVector.Items[i];
  Assert(Sum=(0+99)*100 div 2);

  // intVector is interface type not need free;
end;


//Demo uses TIntVector ---------------------------------------------------------
procedure TFormDGLDemo.btn_TIntVectorClick(Sender: TObject);
var
  intVector : TIntVector; //class type
  i,Sum : integer;
begin
  intVector :=TIntVector.Create;
  try
    for i:=0 to 100-1 do
      intVector.PushBack(i);
    Assert(intVector.Size()=100);

    Sum:=0;
    for i:=0 to intVector.Size()-1 do
      Sum:=Sum+intVector.Items[i];
    Assert(Sum=(0+99)*100 div 2);

  finally
    intVector.Free;  //intVector is class type;
    //use class type is maybe faster than interface type;
    //recommend priority use DGL container as interface by most time;
  end;

end;


//Demo uses IIntDeque ----------------------------------------------------------
procedure TFormDGLDemo.btn_IIntDequeClick(Sender: TObject);
var
  intDeque : IIntDeque;
  i,Sum : integer;
begin
  intDeque :=TIntDeque.Create;

  for i:=0 to 100-1 do
    intDeque.PushBack(i);
  Assert(intDeque.Back()=99);Assert(intDeque.Front()=0);
  Assert(intDeque.Size()=100);

  for i:=0 to 100-1 do
    intDeque.PushFront(i); //Deque's PushFront and PushBack is the same fast;
  Assert(intDeque.Back()=99);Assert(intDeque.Front()=99);
  Assert(intDeque.Size()=200);

  Sum:=0;
  for i:=0 to intDeque.Size()-1 do
    Sum:=Sum+intDeque.Items[i];
  Assert(Sum=((0+99)*100 div 2)*2);
end;


//Demo uses IPointerList -------------------------------------------------------
procedure TFormDGLDemo.btn_IPointerListClick(Sender: TObject);
var
  piList : IPointerList;
  it : IPointerIterator;
  i,Sum : integer;
begin
  piList :=TPointerList.Create;

  for i:=0 to 100-1 do
    piList.PushBack(Pointer(i));
  for i:=0 to 100-1 do
    piList.PushFront(Pointer(i));

  it:=piList.ItBegin.Clone(100); //it is pointer to piList's middle;
  for i:=0 to 100-1 do
    piList.Insert(it,Pointer(i));
  //List's PushFront and PushBack and insert at any pos is the same fast;
  Assert(piList.Size()=300);

  Sum:=0;
  it:=piList.ItBegin; //it is pointer to piList's first;
  for i:=0 to piList.Size()-1 do
  begin
    Sum:=Sum+integer(it.Value);
    it.Next;
  end;
  Assert(it.IsEqual(piList.ItEnd));
  Assert(Sum=((0+99)*100 div 2)*3);
end;


//Demo uses IIntSerialContainer ------------------------------------------------
procedure TFormDGLDemo.btn_IIntSerialContainerClick(Sender: TObject);
  procedure SetVaues(const Container:IByteSerialContainer);
  var
    i : integer;
  begin
    for i:=0 to 100-1 do
      Container.PushBack(i);
  end;

  procedure CheckSum(const Container:IByteSerialContainer);
  var
    it : IByteIterator;
    Sum : integer;
  begin
    it:=Container.ItBegin;
    Sum :=0;
    while (not it.IsEqual(Container.ItEnd)) do
    begin
      sum:=sum+it.Value;
      it.Next;
    end;
    Assert(Sum=(0+99)*100 div 2);
  end;

var
  BVector : IByteVector;
  BDeque  : IByteDeque;
  BList   : IByteList;
  it: IByteIterator;
begin
  BVector :=TByteVector.Create;
  BDeque  :=TByteDeque.Create;
  BList   :=TByteList.Create;

  SetVaues(BVector);
  CheckSum(BVector);
  SetVaues(BDeque);
  CheckSum(BDeque);
  SetVaues(BList);
  CheckSum(BList);
end;


//Demo uses IPointerSet --------------------------------------------------------
procedure TFormDGLDemo.btn_IPointerSetClick(Sender: TObject);
var
  piSet : IPointerSet;
  it : IPointerIterator;
  i,Sum : integer;
begin
  piSet :=TPointerHashSet.Create;

  for i:=0 to 200-1 do
    piSet.Insert(Pointer(i div 2)); //values is [0,1,..99]
  Assert(piSet.size()=100);

  Sum:=0;
  it:=piSet.ItBegin;
  for i:=0 to piSet.Size-1 do
  begin
    inc(Sum,integer(it.Value));
    it.Next;
  end;
  Assert(Sum=((0+99)*100 div 2));

  for i:=0 to 100-1 do
  begin
    it:=piSet.Find(Pointer(i));
    Assert(not it.IsEqual(piSet.ItEnd));
    Assert(it.Value=Pointer(i));
  end;

  for i:=0 to 100-1 do
    piSet.EraseValue(Pointer(i)); //== piSet.Erase(piSet.Find(Pointer(i)));
  Assert(piSet.IsEmpty());
  Assert(piSet.Size()=0);

end;


//Demo uses IPointerMultiSet ---------------------------------------------------
procedure TFormDGLDemo.btn_IPointerMultiSetClick(Sender: TObject);
var
  piMSet : IPointerMultiSet;
  it,itt : IPointerIterator;
  i,Sum : integer;
begin
  piMSet :=TPointerHashMultiSet.Create;

  for i:=0 to 200-1 do
    piMSet.Insert(Pointer(i div 2)); //values is [0,0,1,1..99,99]
  Assert(piMSet.size()=200);

  Sum:=0;
  it:=piMSet.ItBegin;
  for i:=0 to piMSet.Size-1 do
  begin
    inc(Sum,integer(it.Value));
    it.Next;
  end;
  Assert(Sum=((0+99)*100 div 2)*2);

  for i:=0 to 100-1 do
  begin
    it:=piMSet.Find(Pointer(i));
    Assert(not it.IsEqual(piMSet.ItEnd));
    Assert(it.Value=Pointer(i));

    Assert(piMSet.Count(Pointer(i))=2);

    it:=piMSet.LowerBound(Pointer(i));
    Assert(it.Value=Pointer(i));
    itt:=piMSet.UpperBound(Pointer(i));
    Assert(it.Distance(itt)=2);
  end;

  Assert(piMSet.Size()=200);
  for i:=0 to 100-1 do
    piMSet.Erase(piMSet.Find(Pointer(i)));
  Assert(piMSet.Size()=100);
  for i:=0 to 100-1 do
    piMSet.Erase(piMSet.Find(Pointer(i)));
  Assert(piMSet.Size()=0);

end;

//Demo uses IStrIntMap ---------------------------------------------------------
procedure TFormDGLDemo.btn_IStrIntMapClick(Sender: TObject);
var
  StrIntMap : IStrIntMap;
  i,Sum : integer;
  it: IStrIntMapIterator;
begin
  StrIntMap :=TStrIntHashMap.Create;
  StrIntMap.Insert('a1',1);
  StrIntMap.Insert('a2',2);
  StrIntMap.Insert('a3',3);
  Assert(StrIntMap.Items['a1']=1);
  Assert(StrIntMap.Items['a2']=2);
  Assert(StrIntMap.Items['a3']=3);


  StrIntMap.Clear();

  for i:=0 to 100 -1 do
    StrIntMap.Items[inttostr(i)]:=i*3; //== StrIntMap.Insert(inttostr(i),i*3);
  Assert(StrIntMap.size()=100);

  Sum:=0;
  for i:=0 to StrIntMap.Size-1 do
    inc(Sum,StrIntMap.Items[inttostr(i)]);
  Assert(Sum=((0+99)*100 div 2)*3);

  for i:=0 to 100-1 do
  begin
    it:=StrIntMap.Find(inttostr(i));
    Assert(not it.IsEqual(StrIntMap.ItEnd));
    Assert(it.Value=i*3);
    Assert(strToint(it.Key)=i);
  end;

  for i:=0 to 100-1 do
    StrIntMap.Erase(StrIntMap.Find(inttostr(i)));
  Assert(StrIntMap.Size()=0);
end;


//Demo uses IStrMultiMap -------------------------------------------------------
procedure TFormDGLDemo.btn_IStrMultiMapClick(Sender: TObject);
var
  StrMMap : IStrMultiMap;
  i,Sum : integer;
  it,itt: IStrMapIterator;
begin
  StrMMap :=TStrHashMultiMap.Create;
  StrMMap.Insert('a1','1');
  StrMMap.Insert('a2','2');
  StrMMap.Insert('a3','3');
  Assert(StrMMap.Items['a1']='1');
  Assert(StrMMap.Items['a2']='2');
  Assert(StrMMap.Items['a3']='3');

  StrMMap.Insert('a1','4');
  Assert((StrMMap.Items['a1']='1') or (StrMMap.Items['a1']='4'));
  Assert(StrMMap.Count('a1')=2);
  it:=StrMMap.LowerBound('a1');
  Assert((strtoint(it.Value)+strtoint(it.NextValue[1]))=(1+4));

  /

  StrMMap.Clear();

  for i:=0 to 200 -1 do
    StrMMap.Items[inttostr(i div 2)]:=inttostr(i div 2); //== StrMMap.Insert(inttostr(i),inttostr(i*3));
  Assert(StrMMap.size()=200);

  Sum:=0;
  for i:=0 to StrMMap.Size-1 do
    inc(Sum,strtoint(StrMMap.Items[inttostr(i div 2)]));
  Assert(Sum=((0+99)*100 div 2)*2);

  for i:=0 to 100-1 do
  begin
    it:=StrMMap.Find(inttostr(i));
    Assert(not it.IsEqual(StrMMap.ItEnd));
    Assert(strtoint(it.Value)=i);
    Assert(strToint(it.Key)=i);

    Assert(StrMMap.Count(inttostr(i))=2);

    it:=StrMMap.LowerBound(inttostr(i));
    Assert(it.Value=inttostr(i));
    Assert(it.Key=inttostr(i));
    itt:=StrMMap.UpperBound(inttostr(i));
    Assert(it.Distance(itt)=2);
  end;

  for i:=0 to 100-1 do
    StrMMap.Erase(StrMMap.Find(inttostr(i)));
  Assert(StrMMap.Size()=100);
  for i:=0 to 100-1 do
    StrMMap.Erase(StrMMap.Find(inttostr(i)));
  Assert(StrMMap.Size()=0);

end;

//Demo uses IIntStack ----------------------------------------------------------
procedure TFormDGLDemo.btn_IIntStackClick(Sender: TObject);
var
  ist : IIntStack;
begin
  ist :=TIntStack.Create;

  ist.Push(5);   //[5]
  ist.Push(6);   //[5,6]
  ist.Push(7);   //[5,6,7]
  Assert(ist.Size()=3);
  Assert(ist.Top=7);

  ist.Pop;    //[5,6]
  Assert(ist.Top=6);
  ist.Pop;    //[5]
  Assert(ist.Top=5);
  ist.Pop;    //[]
  Assert(ist.IsEmpty());

end;

//Demo uses IByteQueue ---------------------------------------------------------
procedure TFormDGLDemo.btn_IByteQueueClick(Sender: TObject);
var
  ibq : IByteQueue;
begin
  ibq :=TByteQueue.Create;

  ibq.Push(5);  //[5]
  ibq.Push(6);  //[5,6]
  ibq.Push(7);  //[5,6,7]
  ibq.Push(8);  //[5,6,7,8]
  Assert(ibq.Size()=4);
  Assert(ibq.Front()=5);
  Assert(ibq.Back()=8);

  ibq.Pop;      //[6,7,8]
  Assert(ibq.Front()=6);
  ibq.Pop;      //[7,8]
  Assert(ibq.Front()=7);
  ibq.Pop;      //[8]
  Assert(ibq.Front()=8);
  ibq.Pop;      //[]
  Assert(ibq.IsEmpty());

end;

//Demo uses IIntPriorityQueue --------------------------------------------------
procedure TFormDGLDemo.btn_IIntPriorityQueueClick(Sender: TObject);
var
  ipq : IIntPriorityQueue;
begin
  ipq :=TIntPriorityQueue.Create; //can uses as: TIntPriorityQueue.Create(aTestBinaryFunction);
                                  //  'aTestBinaryFunction' is then Priority function;

  ipq.Push(10);
  Assert(ipq.Top()=10);
  ipq.Push(7);
  Assert(ipq.Top()=10);
  ipq.Push(50);
  Assert(ipq.Top()=50);
  ipq.Push(13);
  Assert(ipq.Top()=50);
  Assert(ipq.Size()=4);

  ipq.Pop;
  Assert(ipq.Top()=13);
  ipq.Pop;
  Assert(ipq.Top()=10);
  ipq.Pop;
  Assert(ipq.Top()=7);
  ipq.Pop;
  Assert(ipq.IsEmpty());

end;


//Demo uses IByteIterator ------------------------------------------------------
  function ValuesAsStr(const it0,it1:IByteIterator):string;
  var
    it : IByteIterator;
  begin
    result:='';
    it:=it0;
    while not it.IsEqual(it1) do
    begin
      result:=result+inttostr(it.Value)+' ';
      it.Next;
    end;
  end;
var
  AgSum : integer;
  procedure SumAValue(const Value: Byte);
  begin
    inc(AgSum,Value);
  end;
var
  AgStr: string;
procedure TFormDGLDemo.btn_IByteIteratorClick(Sender: TObject);
var
  BContainer : IByteContainer;
  it0,it1: IByteIterator;
  i,sum : integer;
begin
  BContainer :=TByteVector.Create(100);
  //BContainer :=TByteDeque.Create(100);
  //BContainer :=TByteList.Create(100);
  Assert(BContainer.Size()=100);

  it0:=BContainer.ItBegin();
  it1:=BContainer.ItEnd();
  while not it0.IsEqual(it1) do
  begin
    it0.Value:=random(256);
    it0.Next;
  end;

  it0:=BContainer.ItBegin();
  it1:=BContainer.ItEnd();
  Sum:=0;
  while not it0.IsEqual(it1) do
  begin
    inc(sum,it0.Value);
    it0.Next;
  end;

  AgSum:=0;
  TByteAlgorithms.ForEach(BContainer.ItBegin(),BContainer.ItEnd(),@SumAValue);
  Assert(AgSum=Sum);

  AgStr:=ValuesAsStr(BContainer.ItBegin(),BContainer.ItEnd());
  TByteAlgorithms.Sort(BContainer.ItBegin(),BContainer.ItEnd());
  AgStr:=ValuesAsStr(BContainer.ItBegin(),BContainer.ItEnd());
  Assert(TByteAlgorithms.IsSorted(BContainer.ItBegin(),BContainer.ItEnd()));

end;

 

 

housisong
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 29
    评论
专栏目录
DGL库CPU版本和CUDA版本
02-27
DGL库CPU版本和CUDA版本 dgl-0.9.1-cp37-cp37m-win_amd64.whl win-64-dgl-cuda11.1-0.9.1-py37-0.tar.bz DGL库CPU版本和CUDA版本 dgl-0.9.1-cp37-cp37m-win_amd64.whl win-64-dgl-cuda11.1-0.9.1-py37-0.tar.bz DGL...
逐梦旅程---GDICoredemo
SuzukaSD的博客
03-10 50
自用
GDI+基础使用Dome
【PlateauSnow】的博客
03-09 496
定义：GraphicDeviceInterface图形设备接口。 环境：C#、VS2017、.NET Windows窗体 过程： 1、创建 Windows窗体 ，框架选择4.6.1的，然后选好位置，已经名称即可。 2、进入主页，（然后根据图片标记流程执行） 3、进入后台，这里他生成一个方法，由窗体名称+属性名称组成。可以看到，方法的参数其实跟一般的方法还是差不多的，都是这两个参数 （e其实是个假主角，哈哈） 4、写完方法（绘图） 4.1、确定绘画形状：五角星（我用电脑的画...
dgl安装
最新发布
weixin_45780075的博客
03-18 688
如果你的环境支持 GPU，并且你想要在 GPU 上运行 DGL，你需要确保安装了相应版本的 CUDA 并配置好 CUDA 的环境变量。如果你使用的是 Anaconda 或 Miniconda，你也可以使用 conda 来安装 DGL。根据你的系统环境和需求，可能需要根据 DGL 的官方文档进行进一步的配置和安装。在这个命令中，cu102 表示 CUDA 10.2，你可以根据你的 CUDA 版本选择合适的版本号。这将会安装最新版本的 DGL。这将从 DGL 团队的 conda 通道安装 DGL。
【Pytorch神经网络理论篇】 27 图神经网络DGL库：简介+安装+卸载+数据集+PYG库+NetWorkx库
热门推荐
小李的研究生学习日记
03-31 1万+
DGL库是由纽约大学和亚马逊联手推出的图神经网络框架，支持对异构图的处理，开源相关异构图神经网络的代码，在GCMC、RGCN等业内知名的模型实现上也取得了很好的效果。 1 DGL库的实现与性能 实现GNN并不容易，因为它需要在不规则数据上实现较高的GPU吞吐量。 1.1 DGL库简介 DGL库的逻辑层使用了顶点域的处理方式，使代码更容易理解。同时，又在底层的内存和运行效率方面做了大量的工作，使得框架可以发挥出更好的性能。 1.2 DGL库特点 GCMC：DGL的内存优化支...
python import dgl
sinat_38007523的博客
10-21 1327
问题：安装的时候直接conda总是会卡住 解决办法：用python -m加pip好用一些 比如安装cuda113对应版本 python -m pip install dgl-cu113 dglgo -f https://data.dgl.ai/wheels/repo.html
DGL图神经网络库使用大全
sinat_38007523的博客
10-30 2499
图表示实体(节点)和它们的关系(边)，其中节点和边可以是有类型的 (例如，“用户” 和 “物品” 是两种不同类型的节点)。 DGL通过其核心数据结构 DGLGraph 提供了一个以图为中心的编程抽象。 DGLGraph 提供了接口以处理图的结构、节点/边 的特征，以及使用这些组件可以执行的计算。本章首先简要介绍了图的定义（见1.1节），然后介绍了一些 DGLGraph 相关的核心概念：1.1 关于图的基本概念1.2 图、节点和边1.3 节点和边的特征1.4 从外部源创建图1.5 异构图1.6 在GPU上使用
Python库 | dgl_cu111-0.6.1-cp36-cp36m-win_amd64.whl
05-30
资源分类：Python库 所属语言：Python 使用前提：需要解压 资源全名：dgl_cu111-0.6.1-cp36-cp36m-win_amd64.whl 资源来源：官方 安装方法：https://lanzao.blog.csdn.net/article/details/101784059
DGL:Delphi泛型库--DGL(The Delphi Generic Library)
06-16
Delphi泛型库--DGL(The Delphi Generic Library) , writed in 2004. === 安装: 将DGL源代码目录设置到编译器的搜索路径中 使用方法: 直接引用DGL_XXX.pas单元，大部分应用都应该没有问题了； 如果为了速度或效率等...
Delphi泛型库--DGL
11-08
Delphi泛型库--DGL(The Delphi Generic Library) 在Delphi中实现的类型安全、高效、易用的泛型容器和算法库；借鉴了C++标准中的STL；
Python库 | dgl_cu101-0.4.3-cp36-cp36m-manylinux1_x86_64.whl
05-30
资源分类：Python库 所属语言：Python 使用前提：需要解压 资源全名：dgl_cu101-0.4.3-cp36-cp36m-manylinux1_x86_64.whl 资源来源：官方 安装方法：https://lanzao.blog.csdn.net/article/details/101784059
GDI+ 学习demo
08-25
这个是我学习gdi+的demo，里面又渐变等等的例子
（初学必看）deep graph library(dgl)库的入门引导
qq_43391414的博客
12-09 7104
文章目录前言简单？内置数据集定义模型定义dgl中的一个图 前言 下载这个库要去官方网站：https://www.dgl.ai/，网站上会给你下载命令，这有点像下载pytorch的时候。 然后，官方网站提供了一些入门的例子。如果自己有能力，可以自行学习，就不用跟着我们这篇文章学习啦，网址见：https://docs.dgl.ai/tutorials/blitz/index.html。 这个库基本是由中国人开发和维护的，我用了之后的感觉就是：还行。API定义得很人性，所以很容易学习。跟一个普通的库没有什么差别。
DGL安装： import dgl 报错
u011332879的博客
09-30 576
这是自己出现的错误，然后在网上查找了好久才修改成功，希望对大家有帮助。
DGL教程
Everyday try to become better -Kobe Bryant
09-26 1825
注意：往图中添加的特征必须都是tensor格式。dgl图构造器来构造图，需要知道。此时图中没有节点和边的特征。
import dgl 图神经网络库的导入报错问题
weixin_45695606的博客
07-21 1499
dgl库的导入
GNN-第三方库-DGL：教程
u013250861的博客
12-14 816
DGL库很友好出了就在这个地方，这里基本从那边粘贴过来，算作个人笔记。Deep Graph Library (DGL)是一个用于构建图模型的框架安装DGL支持, MXNet和TensorFlow三种后端，默认为PyTorch，可在~/.dgl/config.json中配置。
图神经网络DGL库安装教程
m0_55684014的博客
01-16 1336
图神经网络DGL库详细安装教程
DGL官方教程--API--dgl.function
Minions的博客
03-30 6586
参考：https://docs.dgl.ai/en/latest/api/python/function.html dgl.function 在DGL中，消息传递由两个API表示： send(edges,message_func)用于计算沿给定边缘的消息。 recv(nodes,reduce_func)用于收集传入消息，执行聚合等。 尽管两阶段抽象可以覆盖消息传递范式中定义的所有模型，...
使用dgl展示Cora数据集
05-26
首先，你需要安装dgl库。可以通过以下命令进行安装： ```bash pip install dgl ``` 然后，你需要下载Cora数据集。可以使用以下命令进行下载： ```bash wget https://data.dgl.ai/dataset/cora_raw.zip unzip cora...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 29
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值