[cmake]cmake命令之target_include_directories简介

• target_include_directories

  命令格式

  target_include_directories(<target> [SYSTEM] [AFTER|BEFORE]
  <INTERFACE|PUBLIC|PRIVATE> [items1...]
  [<INTERFACE|PUBLIC|PRIVATE> [items2...] ...])

  该命令给指定的目标文件添加头文件搜索目录，所以<target>必须用add_executable()或add_library()等命令先创建出来，和include_directories的主要差别是：

  • include_directories会对当前CMakeLists.txt文件的目标文件生效，并会通过add_subdirectory调用传递到子目录；target_include_directories则针对指定的目标文件生效。

  • target_include_directories对于指定目标添加的目录，有三种范围可选，PUBLIC、PRIVATE和INTERFACE。INTERFACE和PUBLIC会添加到<target>的INTERFACE_INCLUDE_DIRECTORIES属性，PUBLIC和PRIVATE会添加到<target>的INCLUDE_DIRECTORIES属性中。

参数选项

• AFTER或BEFORE

  指定添加的目录是追加到头文件搜索目录列表，还是在头文件搜索目录列表的最前面插入。

• SYSTEM

  该选项表明被添加的目录是系统目录，系统目录的搜索顺序在普通的头文件搜索目录之后，并且会添加到目标的INTERFACE_SYSTEM_INCLUDE_DIRECTORIES属性中。

• INTERFACE或PUBLIC或PRIVATE

  指定添加到目标的范围属性，INTERFACE和PUBLIC会添加到<target>的INTERFACE_INCLUDE_DIRECTORIES属性，PUBLIC和PRIVATE会添加到<target>的INCLUDE_DIRECTORIES属性中。

示例说明

• 为可执行文件添加头文件搜索目录

  目录结构

  target_include_directories/
  ├── CMakeLists.txt
  └── main.cpp
  

  CMakeLists.txt文件内容：

  cmake_minimum_required(VERSION 3.22)
  project(target_include_test)
  
  add_executable(main main.cpp)
  target_include_directories(main 
                              PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
  
  get_property(dirs_interface TARGET main PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET main PROPERTY INCLUDE_DIRECTORIES)
  message("# In parent scope, target main: interface[${dirs_interface}], normal[${dirs_normal}]")
  

  main.cpp文件内容：

  #include <iostream>
  
  int main(int argc, char** argv)
  {
      std::cout << "In main..." << std::endl;
      return 0;
  }
  

  在target_include_directories目录下，运行cmake .以及make VERBOSE=1，关键输出：

  $ cmake .
  ……
  # In parent scope, target main: interface[], normal[/XXX/target_include_directories]
  
  $ make VERBOSE=1
  ……
  /usr/bin/c++    -MD -MT CMakeFiles/main.dir/main.cpp.o -MF CMakeFiles/main.dir/main.cpp.o.d -o CMakeFiles/main.dir/main.cpp.o -c /XXX/target_include_directories/main.cpp
  
  $ ./main 
  In main...
  

• 头文件目录的传递性

  目录结构：

  其中test编译为库文件，提供了一个test_print()的函数。

  target_include_directories/
  ├── CMakeLists.txt
  ├── main.cpp
  └── test
      ├── CMakeLists.txt
      ├── test.cpp
      └── test.h
  

  1）可执行文件main不添加test目录，库文件编译时添加INTERFACE范围的test目录

  target_include_directories/CMakeLists.txt文件内容：

  cmake_minimum_required(VERSION 3.22)
  project(target_include_test)
  
  add_subdirectory(test)
  
  add_executable(main main.cpp)
  
  get_property(dirs_interface TARGET main PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET main PROPERTY INCLUDE_DIRECTORIES)
  message("# In parent scope, target main property: interface[${dirs_interface}], normal[${dirs_normal}]")
  
  target_link_libraries(main test)
  get_property(dirs_interface TARGET main PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET main PROPERTY INCLUDE_DIRECTORIES)
  message("# In parent scope, after add test lib, target main property: interface[${dirs_interface}], normal[${dirs_normal}]")
  

  target_include_directories/main.cpp文件内容：

  #include "test.h"
  #include <iostream>
  
  int main(int argc, char** argv)
  {
      std::cout << "In main..." << std::endl;
      test_print();
      return 0;
  }
  

  target_include_directories/test/CMakeLists.txt文件内容：

  add_library(test test.cpp)
  target_include_directories(test INTERFACE ${CMAKE_CURRENT_SOURCE_DIR})
  
  get_property(dirs_interface TARGET test PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET test PROPERTY INCLUDE_DIRECTORIES)
  message("-- # In child scope, target test property: interface[${dirs_interface}], normal[${dirs_normal}]")
  

  target_include_directories/test/test.h文件内容：

  #ifndef __TEST_TT__
  #define __TEST_TT__
  void test_print();
  #endif
  

  target_include_directories/test/test.cpp文件内容：

  #include "test.h"
  #include <iostream>
  
  void test_print()
  {
      std::cout << "In test: say hello!" << std::endl;
  }
  

  在target_include_directories目录下，运行cmake .以及make VERBOSE=1，关键输出：

  $ cmake .
  ……
  -- # In child scope, target test property: interface[/home/shengyi/code/gitee_repo/projects/cmake/target_include_directories/test], normal[]
  # In parent scope, target main property: interface[], normal[]
  # In parent scope, after add test lib, target main property: interface[], normal[]
  
  $ make VERBOSE=1
  ……
  [ 75%] Building CXX object CMakeFiles/main.dir/main.cpp.o
  /usr/bin/c++  -I/XXX/target_include_directories/test  -MD -MT CMakeFiles/main.dir/main.cpp.o -MF CMakeFiles/main.dir/main.cpp.o.d -o CMakeFiles/main.dir/main.cpp.o -c /home/shengyi/code/gitee_repo/projects/cmake/target_include_directories/main.cpp
  [100%] Linking CXX executable main
  
  $ ./main 
  In main...
  In test: say hello!
  

  可见通过PUBLIC或INTERFACE添加到库文件test的目录，也可以传递到可执行文件main（PRIVATE无法传递，可以尝试修改一下）。

  2）可执行文件main中直接添加test目录，库文件编译时不添加test目录

  与上面的对比，只修改了两个CMakeLists.txt文件，去除了target_include_directories/test/CMakeLists.txt中的target_include_directories语句，在target_include_directories/CMakeLists.txt中通过target_include_directories将test目录增加到目标文件main中。

  target_include_directories/CMakeLists.txt文件内容：

  cmake_minimum_required(VERSION 3.22)
  project(target_include_test)
  
  add_subdirectory(test)
  
  add_executable(main main.cpp)
  target_include_directories(main PRIVATE test)
  get_property(dirs_interface TARGET main PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET main PROPERTY INCLUDE_DIRECTORIES)
  message("# In parent scope, target main property: interface[${dirs_interface}], normal[${dirs_normal}]")
  
  target_link_libraries(main test)
  get_property(dirs_interface TARGET main PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET main PROPERTY INCLUDE_DIRECTORIES)
  message("# In parent scope, after add test lib, target main property: interface[${dirs_interface}], normal[${dirs_normal}]")
  

  target_include_directories/CMakeLists.txt文件内容：

  add_library(test test.cpp)
  
  get_property(dirs_interface TARGET test PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  get_property(dirs_normal TARGET test PROPERTY INCLUDE_DIRECTORIES)
  message("-- # In child scope, target test property: interface[${dirs_interface}], normal[${dirs_normal}]")
  

  在target_include_directories目录下，运行cmake .以及make VERBOSE=1，关键输出：

  $ cmake .
  ……
  -- # In child scope, target test property: interface[], normal[]
  # In parent scope, target main property: interface[], normal[/XXX/target_include_directories/test]
  # In parent scope, after add test lib, target main property: interface[], normal[/XXX/target_include_directories/test]
  
  $ make VERBOSE=1
  ……
  [ 75%] Building CXX object CMakeFiles/main.dir/main.cpp.o
  /usr/bin/c++  -I/XXX/target_include_directories/test  -MD -MT CMakeFiles/main.dir/main.cpp.o -MF CMakeFiles/main.dir/main.cpp.o.d -o CMakeFiles/main.dir/main.cpp.o -c /home/shengyi/code/gitee_repo/projects/cmake/target_include_directories/main.cpp
  [100%] Linking CXX executable main
  
  $ ./main 
  In main...
  In test: say hello!