使用前保证行列数,地理信息一致
可用于计算月均值,季均值,年均值。只需要将单波段数据放在一个固定文件夹内,运行以下代码,选择输入输出目录即可
PRO MEAN_batch
COMPILE_OPT idl2
ENVI,/RESTORE_BASE_SAVE_FILES
ENVI_BATCH_INIT
inpath=DIALOG_PICKFILE(TITLE='选择输入数据目录',/DIRECTORY)
outpath=DIALOG_PICKFILE(TITLE='选择输出数据目录',/DIRECTORY)
CD,inpath
filenames=FILE_SEARCH('*.dat',count=count)
n=N_ELEMENTS(filenames)
PRINT,n
ENVI_REPORT_INIT, ['Processing......'], title='MCD19A2_BAND_MEAN', base=base
ENVI_REPORT_INC, base, 100
ENVI_REPORT_STAT, base, 0, 100
ENVI_OPEN_FILE,filenames[0],r_fid=fid;打开AOD数据
ENVI_FILE_QUERY,fid,dims=dims,ns=ns,nL=nL,data_type=data_type
map_info=ENVI_GET_MAP_INFO(fid=fid)
ENVI_FILE_MNG,ID=fid,/REMOVE
DATA=MAKE_ARRAY(ns,nl,n,TYPE=data_type,value=0)
Result_DATA=MAKE_ARRAY(ns,nl,TYPE=data_type,value=0)
FOR i=0,n-1 DO BEGIN;波段融合
ENVI_OPEN_FILE,filenames[i],r_fid=fid;打开数据
DATA[*,*,i]=ENVI_GET_DATA(fid=fid,dims=dims,pos=0)
ENVI_FILE_MNG,ID=fid,/REMOVE
ENDFOR
ENVI_REPORT_STAT, base, 5, 100
FOR a=0,ns-1 DO BEGIN;异常值去除求均值
base_value=FIX((a*90)/ns)+5
ENVI_REPORT_STAT, base, base_value, 100
FOR b=0,nl-1 DO BEGIN
arr=WHERE(DATA[a,b,*] EQ 0,n_count);如果存在0说明该时刻此处没有数据,需要去除
IF n_count EQ N_ELEMENTS(DATA[a,b,*]) THEN BEGIN
Result_DATA[a,b]=0;如果全为0,则直接赋值0
ENDIF ELSE BEGIN
Result_DATA[a,b]=TOTAL(DATA[a,b,*])/(N_ELEMENTS(DATA[a,b,*])-n_count)
ENDELSE
ENDFOR
ENDFOR
filename_1=STRMID(filenames[0],0,STRLEN(filenames[0])-4)
filename_2=STRMID(filenames[n-1],0,STRLEN(filenames[n-1])-4)
filename=filename_1+'_'+filename_2+'.dat'
out_path=outpath+filename
ENVI_WRITE_ENVI_FILE,Result_DATA,OUT_NAME=out_path,MAP_INFO=map_info,$
ns=ns,nL=nL,nb=1,data_type=data_type,BNAMES='Optical_Depth_055 BandMean'
ENVI_REPORT_STAT, base, 100, 100
ENVI_REPORT_INIT, base=base, /finish
ENVI_BATCH_EXIT
END