Qt小例子学习80- 使用信号/插槽控制 Qt QML SwipeView

Qt小例子学习80- 使用信号/插槽控制 Qt QML SwipeView

main.qml

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 2.4

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("SwipeView Test")

    SwipeView {
        id: view
        anchors.fill: parent
        currentIndex: 4
        Repeater {
            model: 10
            Loader {
                active: SwipeView.isCurrentItem || SwipeView.isNextItem || SwipeView.isPreviousItem
                sourceComponent: Item{
                    Text {
                        text: "Page: "+index
                        anchors.centerIn: parent
                    }
                }
            }
        }
    }
    Connections{
        target: manager
        onToRight: if(view.currentIndex + 1 != view.count) view.currentIndex += 1
        onToLeft: if(view.currentIndex != 0) view.currentIndex -= 1
    }

    PageIndicator {
        id: indicator
        count: view.count
        currentIndex: view.currentIndex
        anchors.bottom: view.bottom
        anchors.horizontalCenter: parent.horizontalCenter
    }
}

main.cpp

#include <QApplication>
#include <QHBoxLayout>
#include <QPushButton>
#include <QQmlApplicationEngine>
#include <QQmlContext>

class SwipeManager : public QObject
{
    Q_OBJECT
public:
    using QObject::QObject;
public slots:
    void moveToRight() { emit toRight(); }
    void moveToLeft() { emit toLeft(); }
signals:
    void toRight();
    void toLeft();
};

int main(int argc, char *argv[])
{
    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);

    QApplication app(argc, argv);
    SwipeManager manager;

    QQmlApplicationEngine engine;
    engine.rootContext()->setContextProperty("manager", &manager);
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));
    if (engine.rootObjects().isEmpty())
        return -1;

    QWidget w;
    QPushButton left("to left");
    QPushButton right("to right");
    QHBoxLayout *lay = new QHBoxLayout(&w);
    lay->addWidget(&left);
    lay->addWidget(&right);
    QObject::connect(&left, &QPushButton::clicked, &manager,
                     &SwipeManager::moveToLeft);
    QObject::connect(&right, &QPushButton::clicked, &manager,
                     &SwipeManager::moveToRight);
    w.show();

    return app.exec();
}

#include "main.moc"