ANSYS APDL 壳单元和实体单元的连接-MPC方法

MPC即多点约束方程（Multipoint Constraint）

采用MPC方法可以不需要连接处的节点一一对应就能将不连续，自由度不协调的单元连接起来。

使用MPC功能连接三维实体单元与壳单元是通过定义需要连接的实体部分和壳部分为接触关系，设置接触单元的接触算法为MPC algorithm，并且定义接触面行为为绑定来实现的。

FINISH
/CLEAR

/COM 定义参数

/PREP7
H=1.0 $B=1.0 $L1=0.5 $L2=3.0 $T=0.1


/COM 定义单元类型

ET,1,SOLID185
ET,2,SHELL181
ET,3,TARGE170
KEYOPT,3,5,2
ET,4,CONTA175
KEYOPT,4,2,2
KEYOPT,4,12,5
KEYOPT,4,5,0
KEYOPT,4,11,1

/COM 定义材料属性

MP,EX,1,2.06E11
MP,PRXY,1,0.3
MP,DENS,1,7850

/COM 实常数，代表壳单元的厚度

R,1,T
R,2

/COM 创建几何模型
BLC4,,,B,H,L1
WPOFFS,,H-T,L1
WPROTA,,90,
VSBW,ALL
WPCSYS
WPOFFS,,H-T/2,L1
WPROTA,,90,
BLC4,,,B,L2
!NUMMRG,ALL


VATT,1,,1
ESIZE,T/3
VMESH,ALL

ASEL,S,LOC,Z,L1+T,L1+L2
ESIZE,T/3
AATT,1,1,2
AMESH,ALL

/com,************** 创建接触**************

ASEL,S,,,13
NSLA,S,1
TYPE,3
REAL,2
ESURF
ALLS
LSEL,S,,,1
NSLL,S,1
TYPE,4
REAL,2
ESURF
ALLS

/com,************** 6.创建壳-实体装配界面**************

SHSD,2,surface

/com,************** 9.设置边界条件**************

NSEL,S,LOC,Z,L1+T/2,L1+L2
NSEL,R,LOC,X,T/2,B-T/2
*GET,NN,NODE,,COUNT
F,ALL,FY,240000/NN

ASEL,S,LOC,Y,0
DA,ALL,ALL
ALLSEL,ALL

/SOLU
SOLVE


/POST1
SET,LAST
PLDISP,1
PLNSOL, U,SUM, 0,1.0
PLNSOL, S,EQV, 0,1.0  

由于MPC方法不需要逐一建立约束方程，不需要在实体和壳连接处有公共节点，所以MPC方法过程简单，使用方便。。