Shader自学笔记 3.2.2用世界空间计算法线纹理

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "Custom/texture/test3" {

//  定义纹理属性 增加法线纹理
    Properties {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap("Normal Map",2D)="bump"{}
        _BumpScale("Bump Scale",Float)=1.0
        _Specular("Specular",Color)=(1,1,1)
        _Gloss ("Gloss", Range(8.0,256)) = 20
        }
    SubShader {
    Pass{
        Tags { "LightMode"="ForwardBase" }

        CGPROGRAM

        #pragma vertex vert

        #pragma fragment frag

        #include "Lighting.cginc"

        fixed4 _Color;
        sampler2D _MainTex;
//      纹理缩放平移属性
        float4 _MainTex_ST;
        sampler2D _BumpMap;
        float4 _BumpMap_ST;
        float _BumpScale;
        fixed4 _Specular;
        float _Gloss;

        struct a2v{
        float4 vertex: POSITION;
//      指定顶点法线
        float3 normal:NORMAL;
//      指定顶点切线
        float4 tangent:TANGENT;
//      语义指定第一个纹理
        float4 texcoord:TEXCOORD0;

        };

        struct v2f{
        float4 pos:SV_POSITION;
        float4 uv:TEXCOORD0;
        float4 TtoW0:TEXCOORD1;
        float4 TtoW1:TEXCOORD2;
        float4 TtoW2:TEXCOORD3;
        };

        v2f vert(a2v v){
        v2f o;
        o.pos=mul(UNITY_MATRIX_MVP,v.vertex);
        o.uv.xy=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
        o.uv.zw=v.texcoord.xy*_BumpMap_ST.xy+_BumpMap_ST.zw;

        float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;  
        fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
        fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
        fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 

//      计算矩阵转换切线空间到世界空间
//      把世界空间存到变换矩阵的最后面的w中，节省空间
        o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
        o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
        o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);

        return o;
        }

        fixed4 frag(v2f i):SV_Target{
//              取出世界坐标      
                float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
//              计算世界坐标下光源和注视方向
                fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));

//              获取切线空间法线
                fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
                bump.xy *= _BumpScale;
//              fixed4 packedNormal=tex2D(_BumpMap,i.uv.zw);
//              fixed3 bump;
//              bump.xy = ((tex2D(_BumpMap, i.uv.zw)).xy*2-1)*_BumpScale;
                bump.z = sqrt(1.0 - saturate(dot(bump.xy, bump.xy)));
//              转换法线切线坐标到世界坐标
                bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));

                fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));

                fixed3 halfDir = normalize(lightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);

                return fixed4(ambient + diffuse + specular, 1.0);
        }
        ENDCG
        }

    }
    FallBack "Specular"
}