JZOJ 4813 【NOIP2016提高A组五校联考2】running

running

题目大意

学校的操场可以看成一个由$n$个格子排成的一个环形，格子按照顺时针顺序从$0$到$n$-$1$标号。
小胡观察到有$m$个同学在跑步，最开始每个同学都在起点（即$0$号格子），每个同学都有个步长$a_i$，每跑一步，每个同学都会往顺时针方向前进$a_i$个格子。由于跑道是环形的，如果一个同学站在$n$-$1$这个格子上，如果他前进一个格子，他就会来到$0$。
求永远不会被跑到的格子的数目。

数据范围

对于$100$%的数据，$1$<=$n$<=$10^9$ ，$1$<=$m$<=$50$ ， $1$<=$a_i$<=$n$

题解

首先我们先证明一个定理：第i个同学经过的格子一定是$gcd$($a_i$,$n$)的倍数。
这个易证：设$gcd$($a_i$,$n$)=$c$

$a_i$*$k_1$ $mod$ $n$=$x$

$a_i$ * $k_1$-$k_2$ * $n$=$x$

$a_i*k_1 \over c$ * $c$-$k_2*n \over c$* $c$=$x$

${a_i*k_1-k_2*n}\over gcd(a_i,n)$*$gcd$($a_i$,$n$)=$x$

其中${a_i*k_1-k_2*n}\over gcd(a_i,n)$很显然 是整数，得证！

接下来我们需要证明第$i$个同学一定会经过所有是$gcd$($a_i$,$n$)的倍数的格子。
首先，第$i$个同学第一次走到自己走过的格子一定是$0$（此结论非常显然，证明略，请读者自行思考），此时走过的长度为$lcm$($a_i$,$n$)，每次跑步的步长是$a_i$，所以一次循环中一共跑了$lcm(a_i,n)\over a_i$次，即

$a_i*n \over gcd(a_i,n)*a_i$=$n\over gcd(a_i,n)$,

刚好不重复地把所有是$gcd$($a_i$,$n$)的倍数的格子都走了一遍（结合一开始证明的结论可得出）。

有了这个结论，这题就容易多了，通过这个结论，我们就可以算出一定会被经过的格子数目，如果算成$\sum_{i=1}^{m}{n\over gcd(a_i,n)}$，那就会把某些格子算重复了。
那我们怎么办了？
用格子的位置$i$与$n$的最小公约数来分类。

枚举一个$n$的约数$d$，若存在一个$i$，使得$gcd$($a_i$,$n$)|$d$ 说明所有$gcd$($i$,$n$)=$d$的格子都能被到达，这样的格子个数等同于满足$gcd$($i\over d$,$n \over d$)=$1$的个数，即与$n \over d$互质的数字的个数，即$\phi {({n \over d})}$。（$d$=$gcd$($i$,$n$)）
这样算的话每个合法格子既不会被算重也不会被算漏。

Code(Pascal)

var
    a,g:array[0..50] of int64;
    n,m,ljz,ans,o:int64;
    i,l:longint;
    ys:array[0..100,1..2] of int64;
function gcd(a,b:int64):int64;
    var
        t:int64;
    begin
        repeat
            t:=b;
            b:=a mod b;
            a:=t;
        until b=0;
        exit(a);
    end;
procedure js(p:int64);
    var
        i,k:longint;
    begin
        p:=n div p;
        k:=p;
        for i:=2 to trunc(sqrt(p)) do
        if k mod i=0 then
        begin
            p:=(p div i)*(i-1);
            while k mod i=0 do
            k:=k div i;
        end;
        if k>1 then p:=(p div k)*(k-1);
        ans:=ans+p;
    end;
begin
    readln(n,m);
    for i:=1 to m do
    begin
        read(a[i]);
        g[i]:=gcd(a[i],n);
    end;
    for i:=1 to trunc(sqrt(n)) do
    if n mod i=0 then
    begin
        for l:=1 to m do
        if i mod g[l]=0 then
        begin
            js(i);
            break;
        end;
        if i<>sqrt(n) then
        for l:=1 to m do
        if n div i mod g[l]=0 then
        begin
            js(n div i);
            break;
        end;
    end;
    writeln(n-ans);
end.