SmartfoxServer的客户端逻辑处理模版

最新推荐文章于 2017-03-28 09:55:52 发布

justzhuiing

最新推荐文章于 2017-03-28 09:55:52 发布

阅读量457

点赞数

分类专栏： Unity 文章标签： smartfoxserver

本文链接：https://blog.csdn.net/aa1287537617/article/details/41215499

版权

Unity 专栏收录该内容

83 篇文章 0 订阅

订阅专栏

A: 代码模板

介绍

这篇文章大家可以了解一下代码模板，使用该模板我们可以开发很多基于SmartFoxServer的应用。模板包含了发起连接，认证，加入房间，等等基本的方法。和服务器端的相应.

如果您已经学习了 "连接" (5.1) 和 "简单聊天 (5.2) ，请接着往下看。

» 基本步骤

1) 发起socket连接:这是第一步. 就像是在敲服务器的门。如果服务器开着就会相应你，并激活一个连接。

2) 登入: 在这一阶段，你要告诉服务器你是谁你想和哪个应用交互，如果操作成功的话，你就可以当前zone里的房间列表

3) 加入房间: 一旦进入了房间，你就可以和其他用户和应用的逻辑进行交互。

»代码

这里是应用-模板的代码，在源文件中有详细的注释。

import it.gotoandplay.smartfoxserver.*

stop()

var ip:String		= "127.0.0.1"
var port:Number 	= 9339
var zone:String 	= "simpleChat"

// Load the policy file from the server
System.security.loadPolicyFile("xmlsocket://" + ip + ":" + port)

var smartfox:SmartFoxClient = new SmartFoxClient()
smartfox.onConnection = handleConnection
smartfox.connect(ip, port)


function handleConnection(success)
{
        if (success)
        {
                trace(">> Connection successfull")
                sendLogin()
        }
        else
        {
                trace("[ ERROR ]: Can't connect!")
        }
}


function sendLogin()
{
        smartfox.login(zone, "")
}


smartfox.onLogin = function(resObj:Object)
{
        if (resObj.success)
        {
                // Login Successfull
                trace(">> Login successfull. Nickname: " + resObj.name)
        }
        else
        {
                trace("[ ERROR ]: Login error. Server said: " + resObj.error)
        }
}


smartfox.onRoomListUpdate = function(roomList:Object)
{
        trace(">> Received the list of rooms\n")
        trace("\tRoom List:")
        trace("\t--------------------------------------------")
        
        // Show the list of rooms
        for (var i in roomList)
        {
                trace("\t" + roomList[i].getName())
        }
        
        // a blank line
        trace("")
        
        // Join the default room
        this.autoJoin()
}


smartfox.onJoinRoom = function(roomObj:Room)
{
        trace(">> Room: '" + roomObj.getName() + "' joined successfully")
}


smartfox.onJoinRoomError = function(errorMsg)
{
        trace("[ ERROR ]: Error joining the room. Server said: " + errorMsg)
}


smartfox.onConnectionLost = function()
{
        trace("[ ERROR ]: Connection with server was lost")
}

在代码中实现3步骤:

1)发起 socket 连接:调用 connect()和处理 onConnection() 方法.

2) 登入:调用sendLogin()方法发送一个zone名和空的用户名. 用户为以游客的身份登入. 使用 onLogin() 来处理登录的相应

提示: 我们可以在服务器端设置登录处理。模板里是为了方便才使用游客登录方式

3) 加入房间: 调用join() 和 autoJoin()加入房间。并处理onJoinRoom() / on JoinRoomError()。

» 跳幁

大家会发现我们的代码都在第一幁，可能有些开发者喜欢把代码写在不同的幁。

如果您要写在不同的幁上，请注意您的请求和相应要在同一幁里。不然的话可能会出问题。比如：您在第一幁发起了连接，那么处理连接事件也要在该幁。

» 总结

一旦以上的三步都成功执行了，我们就可以开始交互游戏逻辑了。

B: Flex 2.0代码模板

介绍

Flex Builder 2的模板包含两部分：SFSTemplate.mxml文件和main.as文件

参考章节 "Connection" (5.1) 和 "Simple Chat" (5.2)