基于ARM的硬件启动程序设计-初始化堆栈（转载）

ARM有7种运行状态，每一种状态的堆栈指针寄存器(SP)都是独立的。所以，对于程序中需要用的每一种处理器模式，都要给SP定义一个堆栈地址。流程为：修改状态寄存器内的状态位，使处理器切换到需要的模式，然后给SP赋值。需要注意的是：不要切换到User模式进行该模式下的堆栈设置，因为进入User模式后就不能再操作CPSR返回到其他模式了。

先定义各种模式对应的CPSR寄存器M[4:0]的值，该值决定了进入何种模式，可参考相关数据手册。

Mode_USR        EQU     0x10

Mode_FIQ        EQU     0x11

Mode_IRQ        EQU     0x12

Mode_SVC        EQU     0x13

Mode_ABT        EQU     0x17

Mode_UND        EQU     0x1B

Mode_SYS        EQU     0x1F

I_BIT           EQU     0x80  ; when I bit is set (1), IRQ is disabled

F_BIT           EQU     0x40  ; when F bit is set (1), FIQ is disabled

下面是初始化堆栈的代码段：

InitStack   

        MOV     R0, LR

; /* 设置管理模式堆栈 */

        MSR     CPSR_c, #(Mode_SVC | I_BIT | F_BIT)  ; 0xd3

        LDR     SP, StackSvc

; /* 设置中断模式堆栈 */

        MSR     CPSR_c, #(Mode_IRQ | I_BIT | F_BIT)  ; 0xd2

        LDR     SP, StackIrq

; /* 设置快速中断模式堆栈 */

        MSR     CPSR_c, #(Mode_FIQ | I_BIT | F_BIT)  ; 0xd1

        LDR     SP, StackFiq

; /* 设置中止模式堆栈 */

        MSR     CPSR_c, #(Mode_ABT | I_BIT | F_BIT)  ; 0xd7

        LDR     SP, StackAbt

; /* 设置未定义模式堆栈 */

        MSR     CPSR_c, #(Mode_UND | I_BIT | F_BIT)  ; 0xdb

        LDR     SP, StackUnd

; /* 设置系统模式堆栈 */

        MSR     CPSR_c, #(Mode_SYS | I_BIT | F_BIT)  ; 0xdf

        LDR     SP, StackUsr

        MOV     PC, R0

StackUsr           DCD     UsrStackSpace + (USR_STACK_LEGTH - 1) * 4

StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4

StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4

StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4

StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4

; /* 分配堆栈空间 */

        AREA    MyStacks, DATA, NOINIT, ALIGN=2

UsrStackSpace      SPACE   USR_STACK_LEGTH * 4  ;用户（系统）模式堆栈空间

SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;管理模式堆栈空间

IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中断模式堆栈空间

FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;快速中断模式堆栈空间

AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;中止义模式堆栈空间

UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;未定义模式堆栈

以管理模式堆栈空间为例说明一下。

SVC_STACK_LEGTH 定义为 16 ，分配结果为：分配16个4字节的存储空间，把该存储空间初始化为0，并且把SP指向堆栈底部（内存高位）。

从上面memory的内容上面可以看出。管理模式堆栈分配了从0x00008080~0x00008044 一共16*4字节空间。其中0x00008040地址存储器上放置的是0x00008080，也就是该堆栈底部的指针的值。

就是说，StackSvc           DCD    SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4这条32位的伪指令，经过编译后，是在0x00008040(StackSvc)地址上放置SvcStackSpace地址值(0x00008080)。也就是把0x00008080赋给了SP了。

再看看地址0x00008080~0x00008044 上的内容，全部是andeq   r0,r0,r0。从汇编指令格式来翻译，andeq  r0,r0,r0翻译成16禁止代码后，刚好是0x00000000。

 

 

 

启动代码中堆栈初始化解析magicchip 发表于 2007-7-23 20:10:00

2

推荐

如果支持本站，请点击本站广告，以表示对我的支持！

 

在启动代码中有：

;定义堆栈的大小

SVC_STACK_LEGTH         EQU         0

FIQ_STACK_LEGTH         EQU         0

IRQ_STACK_LEGTH         EQU         128

ABT_STACK_LEGTH         EQU         0

UND_STACK_LEGTH         EQU         0

Reset

        LDR     PC, ResetAddr

        LDR     PC, UndefinedAddr

        LDR     PC, SWI_Addr

        LDR     PC, PrefetchAddr

        LDR     PC, DataAbortAddr

        DCD     0xb9205f80

        LDR     PC, [PC, #-0xff0]

        LDR     PC, FIQ_Addr

ResetAddr           DCD     ResetInit

UndefinedAddr       DCD     Undefined

SWI_Addr            DCD     SoftwareInterrupt

PrefetchAddr        DCD     PrefetchAbort

DataAbortAddr       DCD     DataAbort

Nouse               DCD     0

IRQ_Addr            DCD     0

FIQ_Addr            DCD     FIQ_Handler

;未定义指令

Undefined

        B       Undefined

;软中断

SoftwareInterrupt

        B       SoftwareInterrupt

;取指令中止

PrefetchAbort

        B       PrefetchAbort

;取数据中止

DataAbort

        B       DataAbort

;快速中断

FIQ_Handler

        B       FIQ_Handler

StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4

StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4

StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4

StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4

;/* 分配堆栈空间 */

        AREA    MyStacks, DATA, NOINIT, ALIGN=2

SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;管理模式堆栈空间

IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中断模式堆栈空间

FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;快速中断模式堆栈空间

AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;中止义模式堆栈空间

UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;未定义模式堆栈

其中，IRQ_STACK_LEGTH 为128，根据

IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中断模式堆栈空间

可知，IrqStackSpace 为128*4个字节空间的首地址，然后在

StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

中， IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4 = 128*4 + (128-1)*4 = (128+127)*4，就是说实际的irq堆栈大小为 (128+127)*4个字节，是这样的吗？

回答1:是这样吗？StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

中的IrqStackSpace 为128*4个连续字节的首地址，IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4 表示一个基址 加上一个内存大小的偏移量从而构成了128*4 个连续的字节空间？

回答2:可如果是这样的话直接写为

StackIrq           DCD     (IRQ_STACK_LEGTH )* 4

不就可以了吗？为什么还要用到space语句呢？

回答3:不是你讲的那样StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

这里的StackIrq是顶格写的，是一个标号，实质就是一个地址。这句伪指令，是将一个数值（IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4）放到一个地址上去（StackIrq）。

IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4

是从IrqStackSpace这个位置（地址）开始，分配一定长度（IRQ_STACK_LEGTH * 4）的空间。

StackIrq 实际上指向了堆栈的栈顶（这个堆栈的最高地址）。

请参考宛城布衣写的常用ARM指令集及汇编，里面有这两条指令的解释。

回答4:eyuge2说的对eyuge2说的很对,StakckIrq里放的是向量中断堆栈的栈顶地址

回答5:re我知道问题出在哪了，是我没有正确的理解DCD和SPACE的使用格式。

按照我楼顶的第一个帖子的理解是错误的，当时觉得那么理解也不妥当，因为那样的话就会有

(128+127)*4的字节作为堆栈空间了。

而在稍后发的第三个帖子里：

是这样吗？

StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

中的IrqStackSpace 为128*4个连续字节的首地址，IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4 表示一个基址 加

上一个内存大小的偏移量从而构成了128*4 个连续的字节空间？

的理解是正确的，但是混淆了DCD指令和SPACE指令的功能。

<label> DCD expr1 {,expr2}{,expr3}...

的意思是讲表达式的值存储在当前的地址中，此地址标号为label，只是将expr1，expr2，expr3...的值装在以label

开始的地址里，并不能分配expr1个连续的字节；

而SPACE的使用格式为

{label} SPACE  expr

这个指令才是真正的分配expr个连续的字节，而这些连续字节的首地址为label，

所以，

在

StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4

中，IrStackSpace可以看作是一个基地址，(IRQ_STACK_LEGTH - 1)* 4作为一个偏移量，两者的和就是这个地址的最

高端，这个最高地址就是堆栈StackIrq的栈顶。而 IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4 的结果毕竟是一个

数值，将这个数值用 DCD 伪指令存放在标号为 StackIrq的内存地址中，这样当访问 StackIrq 时就读取了他的栈顶

的地址了。

刚才看了eyuge2 和 秋天的枫叶 的回帖觉得这么理解应该是对得了，谢谢两位，谢谢大家。

回答6:对,就是这么理解的!