Unity URP自学笔记二 模型描边

在以前的Builtin方式中，一般描边是通过一个Pass来实现，这样做相当于使用了这个shader的物体，在渲染时，需要依次执行模型渲染和描边渲染两个pass，如果某一个时间点不需要显示描边，可能就需要对这个模型换shader或材质，使用起来会有点麻烦。

而最新的URP或HDRP中，虽然也可以使用多个Pass来实现，只是Pass的有数量限制，而且默认只支持那几种LightMode，所以最好的实现是通过Renderer Feather来实现，相当于相机再通过某个材质或shader再渲染一次物体，此时我们就可以把需要描边的物体放到一个Layer中，再用另一个单Pass的shader来渲染。

下面是一个简单的描边Shader

Shader "Unlit/Outline"
{
    Properties
    {
        _OutlineColor("Outline Color",Color) = (0,0,0,1)
        _Outline ("Outline",Range(0,1)) = 0.1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "RenderPipeline"="UniversalRenderPipeline"}
        LOD 100
        Cull Front

        Pass
        {
            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

            struct Atributes
            {
                float4 positionOS : POSITION;
                float3 normalOS : NORMAL;
            };

            struct Varyings
            {
                float4 positionCS : SV_POSITION;
            };

            CBUFFER_START(UnityPerMaterial)
            real4 _OutlineColor;
            real _Outline;
            CBUFFER_END

            Varyings vert (Atributes v)
            {
                Varyings o = (Varyings)0;
                o.positionCS = TransformObjectToHClip(v.positionOS);
                 //法线转到屏幕坐标
                float3 vNormal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normalOS));
                //再转到裁切坐标
                float2 projPos = normalize(mul((float2x2)UNITY_MATRIX_P,vNormal.xy));
                
                o.positionCS.xy += projPos * _Outline * 0.1;
                return o;
            }

            real4 frag (Varyings i) : SV_Target
            {
                return _OutlineColor;
            }
            ENDHLSL
        }
    }
}