串口RS232

最新推荐文章于 2022-07-30 11:41:22 发布
最新推荐文章于 2022-07-30 11:41:22 发布
阅读量5.1k 收藏 20
点赞数 2
分类专栏： FPGA 文章标签： usb uart
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/bunny9__/article/details/120022817
版权

串口RS232

1. 串口简介

通用异步收发传输器，英文全称Universal Asynchronous Receiver/Transmitter，简称UART
UART
UART是一种通用的数据通信协议，也是异步串行通信口（串口）的总称，它在发送数据时将并行数据转换成串行数据来传输，在接收数据时将接收到的数据转换成并行数据
UART是异步串行通信口，SPI是同步的，双方约定好使用频率一致的时钟，主机发送时钟
UART中，数据的收发都有独立的端口，所以它可以实现全双工通信

RS232传输距离比较近，传输速率也比较慢，数据线只有两条，可以节省IO口

2. 串口RS232接口

是UART串口的一种，没有时钟线只有两个数据线
在这里插入图片描述
在这里插入图片描述
注意：两个设备间的TXD和RXD应交叉相连

串口数据的发送和接收都是基于帧结构的，起始位+数据位+停止位，共10bit，空闲状态下rx和tx都保持高电平
在这里插入图片描述
波特率：来波特率指数据信号对载波的调制速率，它用单位时间内载波调制状态改变次数来表示，其单位为波特(Baud)，Bps

比特率：比特率是每秒传输的比特数。单位为比特（bps位/秒）

波特率源与比特率的关系为：比特率=波特率 * 单个调制状态对应的二进制位数

串口常用波特率有4800、9600、115200
9600Bps的串口比特率就是9600*1bps，串口发送或接收1bit数据的时间称为1个波特，也就是1/9600s。clk = 50MHz，T = 20ns，9600Bps下，传输一个波特需要的时钟个数，cnt = (1 * 10^9)ns / 9600 / 20ns 约等于5208，相当于每个bit的传输间隔需要50MHz时钟下的5208个clk

3. 代码实现

实现50MHz下9600波特率传输

波特率为9600Baud
一秒传输9600个波特
每个波特10bit数据，1bit起始位 + 8bit数据位 + 1bit结束位

每个码元传输需要的clk数 = ((1/9600)*10^9ns) / 20ns≈ 5208
串口传输，每个码元也就是一个bit，也可以理解为传递每个bit需要的clk数

在这里插入图片描述

UART接收模块

将上位机发送过来的串行数据进行接收，转换成并行数据

在这里插入图片描述
在这里插入图片描述

module uart_rx 
#(
	parameter	UART_BPS	=	'd9600			,
	parameter	CLK_FREQ	=	'd50_000_000	
)
(
	input	wire			sys_clk		,
	input	wire			sys_rst_n	,
	input	wire			rx			,
	
	output	reg		[ 7: 0]	po_data		,
	output	reg				po_flag
);

//	parameter	BAUD_CNT_MAX	=	5208;	// 9600Bps		(1/9600s)/(1/50M) = F/Bps = 50M / 9600
	localparam	BAUD_CNT_MAX	=	CLK_FREQ / UART_BPS;

	reg				rx_reg1		;	// 同步到系统时钟下
	reg				rx_reg2		;
	reg				rx_reg3		;	// 打两拍，减小亚稳态危害
	reg				start_flag	;	// 开始一个数据帧的传输标志信号
	reg				work_en		;	// 标识数据采集范围，接收数据工作使能信号
	reg		[15: 0]	baud_cnt	;	// 计数1个码元需要的clk，0~8207
	reg				bit_flag	;	// 每bit数据稳定点拉高一拍
	reg		[ 3: 0]	bit_cnt		;	// 10bit数据计数器
	reg		[ 7: 0]	rx_data		;
	reg				rx_flag		;
	
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			begin
				rx_reg1	<=	1'b1;	// 空闲状态为高
				rx_reg2	<=	1'b1;
				rx_reg3	<=	1'b1;
			end
		else
			begin
				rx_reg1	<=	rx;
				rx_reg2	<=	rx_reg1;
				rx_reg3	<=	rx_reg2;
			end


	// start_flag：检测下降沿
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			start_flag	<=	1'b0;
		else	if (~rx_reg2 && rx_reg3 && work_en == 1'b0)	// 检测下降沿，并且现在不在数据采集范围内
			start_flag	<=	1'b1;
		else
			start_flag	<=	1'b0;


	// work_en
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			work_en	<=	1'b0;
		else	if (start_flag == 1'b1)
			work_en	<=	1'b1;
		else	if (bit_cnt == 4'd8 && bit_flag == 1'b1)
			work_en	<=	1'b0;
		else
			work_en	<=	work_en;


	// baud_cnt
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			baud_cnt	<=	16'd0;
		else	if ((baud_cnt == BAUD_CNT_MAX - 1'b1) ||(work_en == 1'b0) )
			baud_cnt	<=	160'd0;
		else
			baud_cnt	<=	baud_cnt + 1'b1;	


	// bit_flag：当baud_cnt计数器计数到中间数时采样的数据最稳定，拉高一个标志信号表示数据可以被采样
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			bit_flag	<=	1'b0;
		else	if  (baud_cnt == BAUD_CNT_MAX / 2 - 1'b1)	// 数据稳定的最中间位置
			bit_flag	<=	1'b1;
		else
			bit_flag	<=	1'b0;


	// bit_cnt
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			bit_cnt	<=	4'd0;
		else	if ((bit_cnt == 4'd8) && (bit_flag == 1'b1))
			bit_cnt	<=	4'd0;
		else	if (bit_flag == 1'b1)
			bit_cnt	<=	bit_cnt + 1'b1;
		else
			bit_cnt	<=	bit_cnt;


	// rx_data
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			rx_data	<=	8'b0;
		else	if (((bit_cnt >= 4'd1) && (bit_cnt <= 4'd8)) && (bit_flag == 1'b1))
			rx_data	<=	{rx_reg3, rx_data[7:1]};
		else
			rx_data	<=	rx_data;


	// rx_flag
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			rx_flag	<=	1'b0;
		else	if ((bit_flag == 1'b1) && (bit_cnt == 4'd8))
			rx_flag	<=	1'b1;
		else
			rx_flag	<=	1'b0;


	// po_data
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			po_data	<=	8'b0;
		else	if (rx_flag == 1'b1)
			po_data	<=	rx_data;


	// po_flag
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			po_flag	<=	1'b0;
		else
			po_flag	<=	rx_flag;

endmodule

`timescale	1ns/1ns

module uart_rx_tb ();

	reg		sys_clk		;
	reg		sys_rst_n	;
	reg		rx			;
	
	wire	[ 7: 0]	po_data	;
	wire			po_flag	;
	
	
	uart_rx
	#(
		.UART_BPS	('d9600		),
		.CLK_FREQ	('d50_000_000	)
	)
	uart_rx_inst
	(
		.sys_clk	(sys_clk	),
		.sys_rst_n	(sys_rst_n	),
		.rx			(rx			),
		
		.po_data	(po_data	),
		.po_flag	(po_flag	)
	);

	always # 10	sys_clk = ~sys_clk;
	
	initial	begin
		sys_clk		=	1;
		sys_rst_n	=	0;
		rx	=	1;
		#10
		sys_rst_n	=	1;
	end
	
	// 模拟发送数据帧
	initial	begin
		#200
		rx_bit(8'd0);
		rx_bit(8'd1);
		rx_bit(8'd2);
		rx_bit(8'd3);
		rx_bit(8'd4);
		rx_bit(8'd5);
		rx_bit(8'd6);
		rx_bit(8'd7);
		rx_bit(8'b1100_1010);
	end




// 任务函数
task	rx_bit ;

	input			[ 7: 0]	data;
	
	integer	i;
	
	begin
		for (i = 0; i < 10 ; i = i + 1)	begin		// 这个begin不可缺少，不然设置的延时起不到循环内的延迟作用
			case (i)
				0:	rx	<=	1'b0;		// 起始位
				1:	rx	<=	data[0];	// 数据位
				2:	rx	<=	data[1];
				3:	rx	<=	data[2];
				4:	rx	<=	data[3];
				5:	rx	<=	data[4];
				6:	rx	<=	data[5];
				7:	rx	<=	data[6];
				8:	rx	<=	data[7];
				9:	rx	<=	1'b1;		// 结束位
			endcase
			#(5208 * 20)
			;
		end
	end
endtask

endmodule

在这里插入图片描述

UART发送模块

将FPGA内部的数据以固定的波特率，并转串，包装成数据帧，发送给上位机

module uart_tx 
#(
	parameter	UART_BPS	=	'd9600			,
	parameter	CLK_FREQ	=	'd50_000_000	
)
(
	input	wire			sys_clk		,
	input	wire			sys_rst_n	,
	input	wire	[ 7: 0]	pi_data		,
	input	wire			pi_flag		,
	
	output	reg				tx
);

	localparam	BAUD_CNT_MAX	=	CLK_FREQ / UART_BPS;

	reg				work_en		;
	reg		[15: 0]	baud_cnt	;
	reg				bit_flag	;
	reg		[ 3: 0]	bit_cnt		;
	
	
	// work_en
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			work_en	<=	1'b0;
		else	if ((bit_cnt == 4'd9) && (bit_flag == 1'b1))
			work_en	<=	1'b0;
		else	if (pi_flag == 1'b1)
			work_en	<=	1'b1;
		else
			work_en	<=	work_en;
			
	
	// baud_cnt
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)	
			baud_cnt	<=	16'd0;
		else	if ((work_en == 1'b0) || (baud_cnt == BAUD_CNT_MAX - 1'b1))
			baud_cnt	<=	16'd0;
		else	if (work_en == 1'b1)
			baud_cnt	<=	baud_cnt + 1'b1;
	
	
	// bit_flag
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			bit_flag	<=	1'b0;
		else	if (baud_cnt == 16'd1)	// 每一个波特计数周期，拉高一个bit_flag周期，相邻脉冲间隔为一个波特
			bit_flag	<=	1'b1;
		else
			bit_flag	<=	1'b0;
	
	
	// bit_cnt
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			bit_cnt	<=	4'd0;
		else	if ((bit_cnt == 4'd9) && (bit_flag == 1'b1))
			bit_cnt	<=	4'd0;
		else	if ((work_en == 1'b1) && (bit_flag == 1'b1))
			bit_cnt	<=	bit_cnt + 1'b1;
		else
			bit_cnt	<=	bit_cnt;


	// tx
	always @ (posedge sys_clk or negedge sys_rst_n)
		if (sys_rst_n == 1'b0)
			tx	<=	1'b1;
		else	if (bit_flag == 1'b1)
			case (bit_cnt)
				0:	tx	<=	1'b0;
				1:	tx	<=	pi_data[0];
				2:	tx	<=	pi_data[1];
				3:	tx	<=	pi_data[2];
				4:	tx	<=	pi_data[3];
				5:	tx	<=	pi_data[4];
				6:	tx	<=	pi_data[5];
				7:	tx	<=	pi_data[6];
				8:	tx	<=	pi_data[7];
				9:	tx	<=	1'b1;
				default:	tx	<=	1'b1;
			endcase

endmodule

在这里插入图片描述

顶层模块

在这里插入图片描述
模拟接收串行数据8’b1100_1010，随后逐比特发送
在这里插入图片描述

4. 下板验证

在这里插入图片描述

Bunny9__
关注
  • 2
    点赞
  • 踩
  • 20
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
qt实现RS-232串口通信
qq_45031489的博客
03-12 1181
串口（Serial Port）是计算机用于与外部设备进行数据通信的一种通信接口。它是一种通过逐位传输数据的方式来进行通信的接口，与并行口（Parallel Port）相对。串口通常用于连接各种外部设备，如调制解调器、打印机、传感器、嵌入式系统等。
RS-232
最新发布
handy34的博客
07-01 1348
串口典型的传输波特率包括110bps、300bps、1200bps、2400bps、4800bps、9600bps、19200bps、38400bps、57600bps和115200bps等。①防护器件回流路径为FG(设备外壳)，即表示当设备为金属外壳时，进行分地处理，FG与板卡地通过1nF电容连接，FG就近连接至机壳；我司有规范要求，电路设计时将RX、TX均做上拉处理，但只焊接TX的上拉电阻，RX的上拉电阻不焊接。逻辑1的电平为-3～-15V，逻辑0的电平为+3～+15V，电平的定义反相了一次。
RS-232接口标准（串口）
大西瓜不甜的博客
10-18 4104
RS-232标准接口（又称EIA RS-232）是常用的串行通信接口标准之一，它是由美国电子工业协会(EIA)联合贝尔系统公司、调制解调器厂家及计算机终端生产厂家于1970年共同制定，其全名是“数据终端设备( DTE)和数据通信设备(DCE)之间串行二进制数据交换接口技术标准”。 在串行通讯时，要求通讯双方都采用一个标准接口，使不同的设备可以方便地连接起来进行通讯。RS-232-C接口(又称EIARS-232-C)是目前最常用的一种串行通讯接口。(“RS-232-C”中的“-C”只不过表示RS-23.
RS232串行接口参数定义
lanmanyinhua的专栏
10-20 5653
 1.RS232通讯距离：波特率 (bps)1 号电缆传输距离（英尺）2 号电缆传输距离（英尺）1105000300030050003000120030003000240010005004800100025096002502502.电平规范：在TxD和RxD上：逻辑1(MARK) =-3V～-15V                                逻辑0(SPACE)=+3～＋15V
串口RS232程序知识详解
08-19
串口RS232是一种串行通信协议，使用串行线路传输数据。它广泛应用于嵌入式系统、机器人、自动控制系统等领域。RS232协议定义了串口的物理层和数据链路层的规范，包括数据位、停止位、奇偶校验位、波特率等参数。 ...
串口RS232接口图.pdf
10-08
串口通信标准中， RS-232C 作为串行通信接口的电气标准，该标准定义了数据终端设备（DTE）和数据通信设备（DCE）间按位串行传输的接口信息，合理安排了接口的电气信号和机械要求，在世界范围内得到了广泛的应用。...
串口RS232检测电路
01-17
串口RS232检测电路是一种专门用于检测和分析串行通信接口——RS232电平信号的硬件电路。RS232，全称是EIA/TIA-232标准，是早期广泛应用于计算机和其他设备之间进行串行通信的一种接口标准。它定义了数据传输速率、...
基于VHDL的串口RS232电路设计
07-31
总之，基于VHDL的串口RS232电路设计利用了VHDL的强大描述能力和EDA工具的灵活性，使得设计师能够定制化的构建串行通信电路，满足特定的波特率和帧格式要求，同时降低了设计的复杂性和成本。随着技术的进步，这种设计...
中控播放器 串口RS232，485和网络TCP、UDP控制协议
03-31
支持各类中控控制的播放器，支持的协议有串口RS232，485和网络TCP、UDP控制协议。 程序内附带控制指令一份，控制操作有播放，暂停，停止，音量，视频切换。 节目支持视频，音频和图片三种。兼容所有中控软件。
RS232串口驱动
10-25
基本上的转接头和系统支持 亲测z-tek 能用。
rs232串口通信文档
07-20
rs232串口通信 1.RS-232-C 详解 2.串口通信基本接线方法 3.串口通讯的概念及接口电路 4.有关RS232 和RS485 接口的问答 5.同步通信方式 6.通信协议 7.实战串行通讯 8.全双工和半双工方式 9.浅析PC 机串口通讯流控制 10.奇偶校验 11.开发通信软件的技术与技巧 12.接口技术的基本知识 13.一个单片机串行数据采集/传输模块的设计 14.单工、半双工和全双工的定义 15.从RS232 端口获得电源 16.串行同步通信的应用 17.串行通信波特率的一种自动检测方法 18.RS-232、RS-422 与RS-485 标准及应用 19.串口泵
VC6.0实现RS232串口通信
01-07
VC6.0实现RS232串口通信
利用程序实现串口RS232与电脑通信.zip_busyugo_rs232_rs232串口_verilog_verilog 串口
09-25
在电子设计领域，RS232串行通信接口是一种广泛使用的标准，用于设备间的通信，尤其是在嵌入式系统和PC之间。本项目聚焦于利用Verilog硬件描述语言在Field Programmable Gate Array（FPGA）上实现RS232串口通信。通过...
串口rs232用verilog实现
12-14
本项目涉及的主题是“串口RS232的Verilog实现”，它涵盖了通信接口设计的重要一环，特别是在嵌入式系统和微控制器应用中。RS232是一种标准的串行通信接口，广泛用于设备间的通信，尽管现代技术有更快速的替代品，但...
RS232串口通信
qq_60265388的博客
07-30 6458
单片机常用11.0592M的的晶振，这个奇怪数字是有来历的： 波特率为9600BPS每位位宽t1=1/9600s 晶振周期t2=1/11.0592/1000000S 单片机机器周期t3=12*t2 t1/t3=96 即对于9600BPS的串口，单片机对其以96倍的速率进行采样。 如果单片机晶振用的不正确，会对串口接受产生误码。...
RS-232串口介绍
Flower195的专栏
12-02 1778
串口介绍 其实是从百度百科和wiki上看到写到这里加深一下印象。 串行接口 (Serial Interface) 是指数据一位一位地顺序传送，其特点是通信线路简单，只要一对传输线就可以实现双向通信（可以直接利用电话线作为传输线），从而大大降低了成本，特别适用于远距离通信，但传送速度较慢。 串行接口 一条信息的各位数据被逐位按顺序传送的通讯方式称为串行通讯。串行通讯的
串口rs232通讯代码
08-13
串口（RS232）通信是一种通过串行接口（通常是DB9接口）进行数据传输的通信方式。 在编写串口通信的代码时，通常需要使用到串口的相关函数和库，如Windows下的WinAPI函数、Linux下的POSIX函数等。 下面是一个基本的串口通讯示例代码： C语言版本（Windows平台）： ```c #include <windows.h> int main() { HANDLE hSerial; DCB dcbSerialParams = {0}; COMMTIMEOUTS timeouts = {0}; char data[] = "Hello, World!"; DWORD bytes_written; // 打开串口 hSerial = CreateFile("COM1", GENERIC_READ | GENERIC_WRITE, 0, NULL, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, NULL); if (hSerial == INVALID_HANDLE_VALUE) { printf("Error opening serial port\n"); return 1; } // 配置串口参数 dcbSerialParams.DCBlength = sizeof(dcbSerialParams); if (!GetCommState(hSerial, &dcbSerialParams)) { printf("Error getting serial port state\n"); CloseHandle(hSerial); return 1; } dcbSerialParams.BaudRate = CBR_9600; dcbSerialParams.ByteSize = 8; dcbSerialParams.StopBits = ONESTOPBIT; dcbSerialParams.Parity = NOPARITY; if (!SetCommState(hSerial, &dcbSerialParams)) { printf("Error setting serial port state\n"); CloseHandle(hSerial); return 1; } // 配置读写超时时间 timeouts.ReadIntervalTimeout = 50; timeouts.ReadTotalTimeoutConstant = 50; timeouts.ReadTotalTimeoutMultiplier = 10; timeouts.WriteTotalTimeoutConstant = 50; timeouts.WriteTotalTimeoutMultiplier = 10; if (!SetCommTimeouts(hSerial, &timeouts)) { printf("Error setting serial port timeouts\n"); CloseHandle(hSerial); return 1; } // 发送数据 if (!WriteFile(hSerial, data, sizeof(data) - 1, &bytes_written, NULL)) { printf("Error writing to serial port\n"); CloseHandle(hSerial); return 1; } // 关闭串口 CloseHandle(hSerial); return 0; } ``` 这个示例代码通过打开串口、配置串口参数、配置读写超时时间以及发送数据等步骤实现了基本的串口通讯功能。具体的串口操作函数和参数可以根据实际需求进行调整和补充。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值