斜率优化专题

dp是一个在noip必考的项目（据说今年又要出新算法了），于是在机房老师的引导下，学习了斜率优化dp（真是一个好东西）

下面说一下我的心得吧：

  首先对于斜率优化呢

  这是一种无法用直接单调队列优化的算法，由于它的转移方程中存在着一个或多个会根据当前状态有关的量，故单调队列无法直接优化，而这里就用到了斜率优化。

  下面给出一道例题

P3195 [HNOI2008]玩具装箱TOY

题目描述

P教授要去看奥运，但是他舍不下他的玩具，于是他决定把所有的玩具运到北京。他使用自己的压缩器进行压缩，其可以将任意物品变成一堆，再放到一种特殊的一维容器中。P教授有编号为 1\cdots N1⋯N 的 NN 件玩具，第 ii 件玩具经过压缩后变成一维长度为 C_iCi​ .为了方便整理，P教授要求在一个一维容器中的玩具编号是连续的。同时如果一个一维容器中有多个玩具，那么两件玩具之间要加入一个单位长度的填充物，形式地说如果将第 ii 件玩具到第 jj 个玩具放到一个容器中，那么容器的长度将为 x=j-i+\sum\limits_{k=i}^{j}C_kx=j−i+k=i∑j​Ck​ 制作容器的费用与容器的长度有关，根据教授研究，如果容器长度为 xx ,其制作费用为 (X-L)^2(X−L)2 .其中 LL 是一个常量。P教授不关心容器的数目，他可以制作出任意长度的容器，甚至超过 LL 。但他希望费用最小.

感谢@ACの666 提供的Latex题面

输入输出格式

输入格式：

 

第一行输入两个整数N，L.接下来N行输入Ci.1<=N<=50000,1<=L,Ci<=10^7

 

输出格式：

 

输出最小费用

 

输入输出样例

输入样例#1： 复制

5 4
3
4
2
1
4

输出样例#1： 复制

1

我们发现这题的dp方程十分的简单

  f[i]=min{f[j]+(sum[i]-sum[j]+i-j-l-1)^2}(看不懂或推不出的请学好dp再来）

方便起见 我们定义xa[i]=sum[i]+i  xb[i]:=sum[i]+i+l+1

转移方程变为了f[i]=min{f[j]+(xa[i]-xb[j])^2}(0<=j<i)

 数据范围一看就不是O（n^2）能承受的，我们必然要对其中的一维状态或是一维转移优化

若是优化状态。。。。（O(1)的状态那不就变贪心了吗？？？，某些题的贪心性质就是这样被发现的）

但是这题我们没有发现可以贪心的线索，那我们只能优化转移了

这里我们发现对于一个新的i的转移有一个sum[i]和它-l的平方影响 ，很明显无法简单使用单调队列优化转移
在这里，我们不妨假设有j<k，对于i的转移k比j优

则就会得到

                                               f[j]+(xa[i]-xb[j])^2>f[k]+(xa[i]-xb[k])^2

打开这个式子：         f[j]+xa[i]^2+xb[j]^2-2*xa[i]*xb[j]>f[k]+xa[i]^2+xb[k]^2-2*xa[i]*xb[k]

                                  f[j]+xb[j]^2-(f[k]+xb[k]^2)<2*xa[[i]*(xb[j]-xb[k])

                             这里就会很容易发生一些错误

由于j<k，那么这题的sum数组又是单调递增的，则xb[j]-xb[k]其实是一个负数，当我们把他除过去的时候，不等号就会改变方向

我们发现      （f[j]+xb[j]^2-(f[k]+xb[k]^2)）/（2*(xb[j]-xb[k])）>xa[i]

 左边只剩下了关于j和k的量，不妨用g（j，k）表示（f[j]+xb[j]^2-(f[k]+xb[k]^2)）/（2*(xb[j]-xb[k])）

于是我们发现当g（j，k）<xa[i]时k就会更优

反之g（j,k）>xa[i]时j就会更优，神奇的事情发生了

我们发现如果存在j1<j2<j3,g(j1,j2)>g(j2,j3）时无论xa[i]如何取值，在这里j2这个转移一定不会是最优的

那我们只要维护一个G单调不降就可以了

同时发现若xa[i]大于了单调队列中最小的一个，后面的元素都会没有用，所以在队首维护一个单调性把小于xa[i]的值都弹出，每次取队首的元素作为最优的转移对象，那么时间复杂度就会降到O（n）的时间范围，一个元素只会进队一次出队一次，均摊O(1)

那么为什么要叫斜率优化呢，我们发现g(j,k)里可以抽象的把j和k看做两个点而g(j,k)可以看做是j到k的斜率，维护g的单调性就相当与维护一个二维的凸包，每次出现xa[i]，就是相当与用一条斜率为xa[i]的线去在这个凸包上截取最近的一个点。

那么斜率优化也就讲到这里了

安利一波代码

var
n,l,i,j,head,tail:longint;
a,sum,xb,xa,f,q:array[0..1000000] of int64;
function g(a,b:longint):double;
begin
  exit((f[a]-f[b]+xb[a]*xb[a]-xb[b]*xb[b])/((xb[a]-xb[b])<<1));
end;
begin
  readln(n,l);
  for i:=1 to n do
  begin
    read(a[i]);
    sum[i]:=sum[i-1]+a[i];
    xa[i]:=sum[i]+i;
    xb[i]:=sum[i]+i+l+1;
  end;
  xb[0]:=l+1;
  head:=1; tail:=1;
  q[1]:=0;
  for i:=1 to n do
  begin
    while (head<tail) and (g(q[head+1],q[head])<xa[i]) do inc(head);
    j:=q[head];
    f[i]:=f[j]+(xa[i]-xb[j])*(xa[i]-xb[j]);
    while (head<tail) and (g(q[tail],q[tail-1])>g(q[tail-1],i)) do dec(tail);
    inc(tail); q[tail]:=i;
  end;
  writeln(f[n]);
end.