第001节_辅线1_硬件知识_LED原理图
当我们学习C语言的时候,我们会写个Hello程序。那当我们写ARM程序,也该有一个简单的程序引领我们入门,这个程序就是点亮LED。
我们怎样去点亮一个LED呢? 分为三步:
1.看原理图,确定控制LED的引脚;
2.看主芯片的芯片手册,确定如何设置控制这个引脚;
3.写程序;
先来讲讲怎么看原理图: LED样子有很多种,像插脚的,贴片的。
它们长得完全不一样,因此我们在原理图中将它抽象出来。
点亮LED需要通电源,同时为了保护LED,加个电阻减小电流。 控制LED灯的亮灭,可以手动开关LED,但在电子系统中,不可能让人来控制开关,通过编程,利用芯片的引脚去控制开关。
LED的驱动方式,常见的有四种。
方式1:使用引脚输出3.3V点亮LED,输出0V熄灭LED。
方式2:使用引脚拉低到0V点亮LED,输出3.3V熄灭LED。
有的芯片为了省电等原因,其引脚驱动能力不足,这时可以使用三极管驱动。
方式3:使用引脚输出1.2V点亮LED,输出0V熄灭LED。
方式4:使用引脚输出0V点亮LED,输出1.2V熄灭LED。
由此,主芯片引脚输出高电平/低电平,即可改变LED状态,而无需关注GPIO引脚输出的是3.3V还是1.2V。 所以简称输出1或0:
逻辑1-->高电平
逻辑0-->低电平
第002节_辅线1_硬件知识_S3C2440启动流程与GPIO操作
在原理图中,同名的Net表示是连在一起的。
怎么样GPF4怎么输出1或0?
1. 配置为输出引脚;
2. 设置状态;
因此,设置GPFCON[9:8]=0b01,即GPF4配置为输出;
设置GPFDAT[4]=1或者0,即输出高电平或低电平;
S3C2440框架:
S3C2440启动流程:
Nor启动:
Nor Flash的基地址为0,片内RAM地址为0x4000_0000;
CPU读出Nor上第1个指令(前4字节),执行;
CPU继续读出其它指令执行。
Nand启动:
片内4k RAM基地址为0,Nor Flash可以正常读取,但是不能写入;
2440硬件把Nand前4K内容复制到片内的RAM,然后CPU从0地址取出第1条指令执行。
第003节_编写第1个程序点亮LED
在开始写第1个程序前,先了解一些概念。
2440是一个SOC,它里面的CPU有R1、R2、R3……等寄存器;
它里面的GPIO控制器也有很多寄存器,如GPFCON、GPFDAT。
这两个寄存器是有差异的,在写代码的时候,CPU里面的寄存器可以直接访问,其它的寄存器要以地址进行访问。
把GPF4配置为输出,需要把0x100写入GPFCON这个寄存器,即写到0x5600_0050上;
把GPF4输出1,需要把0x10写到地址0x5600_0054上;
把GPF4输出0,需要把0x00写到地址0x5600_0054上;
这里的写法会破坏寄存器的其它位,其它位是控制其它引脚的,为了让第一个裸板程序尽可能的简单,才简单粗暴的这样处理。
写程序需要用到几条汇编代码:
(1).LDR (load):读寄存器
举例:LDR R0,[R1]
假设R1的值是x,读取地址x上的数据(4字节),保存到R0中;
(2).STR (store):写寄存器
举例:STR R0,[R1]
假设R1的值是x,把R0的值写到地址x(4字节);
(3).B 跳转
(4).MOV (move)移动,赋值 举例1:MOV R0,R1 把R1的值赋值给R0;
举例2:MOV R0,#0x100 把0x100赋值给R0,即R0=0x100;
(5).LDR
举例:LDR R0,=0x12345678 这是一条伪指令,即实际中并不存在这个指令,他会被拆分成几个真正的ARM指令,实现一样的效果。 最后结果是R0=0x12345678。
在ARM的32位指令中,有些字节表示指令,有些字节表示数据,因此表示数据的没有32位,不能表示一个32位的任意值,只能表示一个较小的简单值,这个简单值称为立即数。引入伪指令后,利用LDR可以为R0赋任意大小值,编译器会自动拆分成真正的的指令,实现目的。
有了前面5个汇编指令的基础,我们就可以写代码了。
第一个程序只能是汇编,以前你们可能写过单片机程序,一上来就写main()函数,那是编译器帮你封装好了。
第一个LED程序代码如下(led_on.S):
/*
* 点亮LED1: gpf4
*/
.text //表明是代码段
.global _start //定义一个符号
_start:
/* 配置GPF4为输出引脚
* 把0x100写到地址0x56000050
*/
ldr r1, =0x56000050
ldr r0, =0x100 /* mov r0, #0x100 */
str r0, [r1]
/* 设置GPF4输出高电平
* 把0写到地址0x56000054
*/
ldr r1, =0x56000054
ldr r0, =0 /* mov r0, #0 */
str r0, [r1]
/* 死循环 */
halt:
b halt
编译此文件的Makefile文件内容如下:
all:
#先编译,不链接
arm-linux-gcc -c -o led_on.o led_on.S
#链接,并指定链接地址为0
arm-linux-ld -Ttext 0 led_on.o -o led_on.elf
#生成.bin文件,可以下载的文件
arm-linux-objcopy -O binary -S led_on.elf led_on.bin
#生成反汇编文件
arm-linux-objdump -D led_on.elf > led_on.dis
clean:
rm *.bin *.o *.dis *.elf
以后只需要 使用 make 命令进行编译, make clean 命令进行清理。
最后烧写到开发板上,即可看到只有一个LED亮,符合我们预期。
第004节_汇编与机器码:
我们可以通过反汇编来查看。
生成的led_on.dis就是反汇编文件。led_on.dis如下:
led_on.elf: file format elf32-littlearm
Disassembly of section .text:
00000000 <_start>:
0: e59f1014 ldr r1, [pc, #20] ; 1c <halt+0x4>
4: e3a00c01 mov r0, #256 ; 0x100
8: e5810000 str r0, [r1]
c: e59f100c ldr r1, [pc, #12] ; 20 <halt+0x8>
10: e3a00000 mov r0, #0 ; 0x0
14: e5810000 str r0, [r1]
00000018 <halt>:
18: eafffffe b 18 <halt>
1c: 56000050 .word 0x56000050
20: 56000054 .word 0x56000054
第一列是地址,第二列是机器码,第三列是汇编码;
在反汇编文件里可以看到,ldr r1, =0x56000050被转换成ldr r1, [pc, #20],pc+20地址的值为0x56000050,通过这种方式为r1赋值。 对于立即数0x100而言,ldr r0,=0x100即是转换成了mov r0,#256;
在2440这个SOC里面,R0-R15都在CPU里面,其中:
R13 别名:sp(Stack Pointer)栈指针,调用C代码时必须设置栈;
R14 别名:lr(Link Register)返回地址,保存返回地址;
R15 别名:pc(program Counter)程序计数器=当前指令地址+8。
为什么PC的值等于当前指令地址+8?
ARM指令采用流水线机制,当前执行地址A的指令,已经在对地址A+4的指令进行译码,已经在读取地址A+8的指令,其中A+8就是当前PC的值。
C/汇编(给人类方便使用的语言)===>编译器===>bin,含有机器码(给CPU使用)。
第005节_编程知识_进制
在C语言中怎么表示这些进制呢?
十进制: int a = 96;
八进制: int a = 0140; //0开头
十六进制: int a = 0x60; //0x开头
用0b开头表示二进制,约定俗成的规定。
第006节_编程知识_字节序
字节序:
假设int a = 0x12345678;
前面说了16进制每位是4个bit表示,在内存中,是以8个bit作为1byte进行存储的,因此0x12345678中每两位作为1byte,其中0x78是低位,0x12是高位。
在内存中的存储方式有两种:
0x12345678的低位(0x78)存在低地址,即方式1,叫做小字节序(Little endian);
0x12345678的高位(0x12)存在低地址,即方式2,叫做大字节序(Big endian);
一般的arm芯片都是小字节序,对于2440可以设置某个寄存器,让整个系统使用大字节序或小字节序,它默认使用小字节序。
第007节_编写C程序控制LED
C语言的指针操作:
(1).所有的变量在内存中都有一块区域;
(2).可以通过变量/指针操作内存;
a. 我们写出了main函数, 谁来调用它?
b. main函数中变量保存在内存中, 这个内存地址是多少?
答: 我们还需要写一个汇编代码, 给main函数设置内存, 调用main函数。
led.c源代码:
int main()
{
unsigned int *pGPFCON = (unsigned int *)0x56000050;
unsigned int *pGPFDAT = (unsigned int *)0x56000054;
/* 设置GPF4为输出引脚 */
*pGPFCON = 0x1500;
/* 设置GPF4输出低电平 */
*pGPFDAT = 0x0;
return 0;
}
start.S源码:
.text
.global _start
_start:
/*设置内存:sp栈*/
ldr sp,=4096 /*nand启动*/
// ldr sp, =0x40000000 /*nor启动*/
/*调用main*/
bl main
halt:
b halt
Makefile源码:
all:
arm-linux-gcc -c -o led.o led.c
arm-linux-gcc -c -o start.o start.S
arm-linux-ld -Ttext 0 start.o led.o -o led.elf
arm-linux-objcopy -O binary -S led.elf led.bin
arm-linux-objdump -D led.elf > led.dis
clean:
rm *.bin *.o *.elf *.dis
最后将上面三个文件放入Ubuntu主机编译,然后烧写到开发板即可。
第008节_几条汇编指令_bl_add_sub_ldm_stm
ADD/SUB 加法/减法
举例1:
add r0,r1,#4
效果为:r0=r1+4;
举例2:
sub r0,r1,#4
效果为:r0=r1-4;
举例3:
sub r0,r1,r2
效果为:r0=r1-r2;
BL(Brarch and Link)带返回值的跳转 跳转到指定标号处,并将返回地址(下一条指令)保存在lr寄存器;
LDM/STM 读写内存指令,写入多个寄存器/把多个寄存器的值写入内存;
可搭配的后缀有,过后增加(Increment After)、预先增加(Increment Before)、过后减少(Decrement After)、预先减少(Decrement Before);
举例1:
stmdb sp!, (fp,ip,lr,pc)
假设sp=4096;db意思是先减后存,按高编号寄存器的值保存在内存的高地址处。
举例2:
ldmia sp, (fp,ip,pc)
009节_解析C程序的内部机制
start.S:
①设置栈;
②调用main,并把返回值地址保存到lr中;
led.c的main()内容:
①定义2个局部变量;
②设置变量;
③return 0;
问题:
①为什么要设置栈?
因为c函数要用。
②怎么使用栈?
a.保存局部变量;
b.保存lr等寄存器;
③调用者如何传参数给被调用者?
调用者通过r0~r3寄存器传参数给被调用函数;
④被调用者如何传返回值给调用者?
也是通过r0~r3寄存器传返回值;
⑤怎么从栈中恢复那些寄存器?
在arm中有个ATPCS规则,约定r0-r15寄存器的用途。
r0-r3:调用者和被调用者之间传参数;
r4-r11:函数可能被使用,所以在函数的入口保存它们,在函数的出口恢复它们;
下面分析个实例 start.S:
.text
.global _start
_start:
/* 设置内存: sp 栈 */
ldr sp, =4096 /* nand启动 */
//ldr sp, =0x40000000+4096 /* nor启动 */
/* 调用main */
bl main
halt:
b halt
led.c:
int main()
{
unsigned int *pGPFCON = (unsigned int *)0x56000050;
unsigned int *pGPFDAT = (unsigned int *)0x56000054;
/* 配置GPF4为输出引脚 */
*pGPFCON = 0x100;
/* 设置GPF4输出0 */
*pGPFDAT = 0;
return 0;
}
将前面的程序反汇编得到led.dis如下:
/* 反汇编文件注释 */
/* 文件格式:lef32,小端对齐 */
led_c.elf: file format elf32-littlearm
/* text段的反汇编 */
Disassembly of section .text:
00000000 <_start>:
0: e3a0da01 mov sp, #4096 ; 0x1000 /* sp寄存器的值等于4096 */
4: eb000000 bl c <main> /* 跳转到0xc地址执行,同时lr寄存器的值设为0x8 */
00000008 <halt>:
8: eafffffe b 8 <halt> /* 死循环跳转指令 */
0000000c <main>:
c: e1a0c00d mov ip, sp /* 将sp的值4096保存到ip寄存器中 */
10: e92dd800 stmdb sp!, {fp, ip, lr, pc} /* 将fp, ip, lr, pc寄存器中的值保存的sp栈中;先减后存 */
14: e24cb004 sub fp, ip, #4 ; 0x4 /* fp=ip-4,也就是4092 */
18: e24dd008 sub sp, sp, #8 ; 0x8 /* 将sp的值设置为4080-8=4072 */
1c: e3a03456 mov r3, #1442840576 ; 0x56000000 /* 将r3寄存器的指设为0x56000000 */
20: e2833050 add r3, r3, #80 ; 0x50 /* 将r3=r3+0x50,即r3的值等于0x56000050 */
24: e50b3010 str r3, [fp, #-16] /* 将r3的值保存到fp-16()地址处4076处 */
28: e3a03456 mov r3, #1442840576 ; 0x56000000 /* 将r3寄存器的值设为0x56000000 */
2c: e2833054 add r3, r3, #84 ; 0x54 /* 将r3寄存器的值加0x54,即0x56000054 */
30: e50b3014 str r3, [fp, #-20] /* 将r3的值保存到(fp-20)(4072)处 */
34: e51b2010 ldr r2, [fp, #-16] /* 将(fp-16)(4076)地址处的值加载到r2寄存器中 */
38: e3a03c15 mov r3, #5376 ; 0x1500 /* 将r3寄存器设置0x1500 */
3c: e5823000 str r3, [r2] /* 将r3中的值0x1500保存到0x56000050地址 */
40: e51b2014 ldr r2, [fp, #-20] /* 将(fp-20)(4072)地址处的值保存到r2寄存器中 */
44: e3a03000 mov r3, #0 ; 0x0 /* 将r3寄存器的值设为0 */
48: e5823000 str r3, [r2] /* 将r3寄存器的值0保存到地址0x56000054中 */
4c: e3a03000 mov r3, #0 ; 0x0 /* 将r3寄存器的值设为0 */
50: e1a00003 mov r0, r3 /* 将r0寄存器的值设为0 */
54: e24bd00c sub sp, fp, #12 ; 0xc /* 将sp的值设为fp-12,也就是4080 */
58: e89da800 ldmia sp, {fp, sp, pc} /* 将fp, sp, pc寄存器中的值加载到sp栈中,先读后增 */
/* 下面这部分是注释,.bin文件中不包含 */
Disassembly of section .comment:
00000000 <.comment>:
0: 43434700 cmpmi r3, #0 ; 0x0
4: 4728203a undefined
8: 2029554e eorcs r5, r9, lr, asr #10
c: 2e342e33 mrccs 14, 1, r2, cr4, cr3, {1}
10: Address 0x10 is out of bounds.
反汇编代码已经做了详细的注释,这里就不在解释。
过程中的内存数据情况:
前面那个例子,汇编调用main.c并没有传递参数,这里修改下c程序,让其传递参数。
start.S:
.text
.global _start
_start:
/* 设置内存: sp 栈 */
ldr sp, =4096 /* nand启动 */
//ldr sp, =0x40000000+4096 /* nor启动 */
mov r0, #4
bl led_on
ldr r0, =100000
bl delay
mov r0, #5
bl led_on
halt:
b halt
led.c:
void delay(volatile int d)
{
while (d--);
}
int led_on(int which)
{
unsigned int *pGPFCON = (unsigned int *)0x56000050;
unsigned int *pGPFDAT = (unsigned int *)0x56000054;
if (which == 4)
{
/* 配置GPF4为输出引脚 */
*pGPFCON = 0x100;
}
else if (which == 5)
{
/* 配置GPF5为输出引脚 */
*pGPFCON = 0x400;
}
/* 设置GPF4/5输出0 */
*pGPFDAT = 0;
return 0;
}
编译并烧写程序,发现先点亮LED1,后点亮LED2。
我们编写的程序代码是先点亮led1,然后延时一会,再点亮led2,进入死循环。
但在开发板上的实际效果是led1先亮,延时一会,led2再亮,然后一会之后,led1再次亮了。
这和我们的设计的代码流程不吻合,这是因为2440里面有个看门狗定时器,开发板上电后,需要在一定时间内“喂狗”(设置相应的寄存器),否则就会重启开发板。
之所以这样设计,是为了让芯片出现死机时,能够自己复位,重新运行。
这里暂时用不到看门狗,先关闭看门狗,从参考手册可知,向0x53000000寄存器写0即可关闭看门狗;
设置内存的栈,通过写读操作来判断是Nand Flash还是Nor Flash;
设置GPFCON让GPF4/5/6配置为输出引脚;
并点亮这三个LED。
完整代码如下:
.text
.global _start
_start:
/* 关闭看门狗 */
ldr r0, =0x53000000
ldr r1, =0
str r1, [r0]
/* 设置内存: sp 栈 */
/* 分辨是nor/nand启动
* 写0到0地址, 再读出来
* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
* 否则就是nor启动
*/
mov r1, #0
ldr r0, [r1] /* 读出原来的值备份 */
str r1, [r1] /* 0->[0] */
ldr r2, [r1] /* r2=[0] */
cmp r1, r2 /* r1==r2? 如果相等表示是NAND启动 */
ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
moveq sp, #4096 /* nand启动 */
streq r0, [r1] /* 恢复原来的值 */
bl main
halt:
b halt
led.c的内容如下:
void delay(volatile int d)
{
while (d--);
}
int main(void)
{
volatile unsigned int *pGPFCON = (volatile unsigned int *)0x56000050;
volatile unsigned int *pGPFDAT = (volatile unsigned int *)0x56000054;
int val = 0; /* val: 0b000, 0b111 */
int tmp;
/* 设置GPFCON让GPF4/5/6配置为输出引脚 */
*pGPFCON &= ~((3<<8) | (3<<10) | (3<<12));
*pGPFCON |= ((1<<8) | (1<<10) | (1<<12));
/* 循环点亮 */
while (1)
{
tmp = ~val;
tmp &= 7;
*pGPFDAT &= ~(7<<4);
*pGPFDAT |= (tmp<<4);
delay(100000);
val++;
if (val == 8)
val =0;
}
return 0;
}
2440里面有很多寄存器,如果每次对不同的寄存器进行查询和操作会很麻烦,因此可以先提前定义成宏,做成一个头文件,每次调用就行。
此文章大部分是从韦东山老师网站的WIKI上面复制过来的。有什么错误的地方,欢迎指正。