数列

题目描述

给定一个正整数k(3≤k≤15),把所有k的方幂及所有有限个互不相等的k的方幂之和构成一个递增的序列，例如，当k=3时，这个序列是：
1，3，4，9，10，12，13，…
（该序列实际上就是：3^0，3^1，3^0+3^1，3^2，3^0+3^2，3^1+3^2，
3^0+3^1+3^2，…）
请你求出这个序列的第N项的值（用10进制数表示）。
例如，对于k=3，N=100，正确答案应该是981。

输入格式

输入只有1行，为2个正整数，用一个空格隔开：
k N
（k、N的含义与上述的问题描述一致，且3≤k≤15，10≤N≤1000）。

输出格式

输出为计算结果，是一个正整数（在所有的测试数据中，结果均不超过2.1*10^9）。（整数前不要有空格和其他符号）。

样例输入

3 100

样例输出

这道题主要是递推，for i:=1 to now-1 do f[now]=f[now]+f[i];

type list=array[0..10000]of longint;//注意开数组的时候，不能只开1000
var k,n:longint;f:list;
procedure init;
  begin
    readln(k,n);
    fillchar(f,sizeof(f),0);
  end;
procedure main;
  var i,j,now,s,p,sum:longint;
    begin
      now:=1;
      f[now]:=1;p:=0;
      repeat
        inc(now);inc(p);sum:=1;
        for i:=1 to p do sum:=sum*k;
        f[now]:=sum;
        s:=now;
        for i:=1 to now-1 do
          begin
            inc(s);
            f[s]:=f[now]+f[i];
          end;
        now:=s;
      until now>=n;
      writeln(f[n]);
     end;
begin
 assign(input,'7.in');reset(input);
 assign(output,'7.out');rewrite(output);
  init;
  main;
 close(input);close(output);
end.

当然，网上也有神牛推出一种重磅打造的全新方法（有点夸张....)——位运算，膜拜。。。。。：

我们把n转换成二进制，如样例：
100---> 1100100
根据题意，
若二进制第i为是1，
则k^(i-1)应存在于待求解的求和公式中
因此
先定义j为1，每次shl 1
(也就是乘二，换句话说在二进制最后一位后面添个0，
因此i就是1后面有几个0咯，在换句话说（i+1）就是j中1所在的位数。。。)
对n取
n and j，因为j只有最高位（二进制）为1
因此得出的数只有0或J（也就是不等于0）两种可能
所以若得数为J，说明n的二进制表示中第i+1位是1，则我们把
k^i 加入总和中，自然得到解了
（注意数据范围）

var i,j,k,n,s:longint;
begin
  read(k,n);
  i:=0;s:=0;j:=1;
  repeat
    if n and j<>0 then s:=s+round(exp(ln(k)*i));
    j:=j shl 1;
    inc(i);
  until j>n;
  writeln(s);
end.