u-boot第一阶段分析（二）

start.S分析（二）

注：本次分析的u-boot是九鼎官方的u-boot代码
下载地址：链接：http://pan.baidu.com/s/1gfpDZqj 密码：7cqe

---

继续上一章节的内容
一 启动代码的16字节校验头

#if defined(CONFIG_EVT1) && !defined(CONFIG_FUSED)
	.word 0x2000
	.word 0x0
	.word 0x0
	.word 0x0
#endif

注：uboot这里start.S中在开头位置放了16字节的填充占位，这个占位的16字节只是保证正式的image的头部确实有16字节，但是这16字节的内容是不对的，还是需要后面去计算校验和然后重新填充的。

二 异常向量表的构建

.globl _start
_start: b	reset @复位异常
	ldr	pc, _undefined_instruction
	ldr	pc, _software_interrupt
	ldr	pc, _prefetch_abort
	ldr	pc, _data_abort
	ldr	pc, _not_used
	ldr	pc, _irq
	ldr	pc, _fiq

这里就是代码的真正开始的地方，我们开机时就是执行的复位异常。当我们启动u-boot时，代码直接跳转到reset去开始执行。

三 地址对齐

.balignl 16,0xdeadbeef

这行代码的意思是让当前地址对齐排布，如果当前地址不对齐则自动向后走直到对齐，并且向后走的那些内存要用0xdeadbeef来填充。

四 链接地址

_TEXT_BASE:
	.word	TEXT_BASE

在u-boot中找不到TEXT_BASE的值，是因为这是我们链接时指定的uboot的链接地址。
注：u-boot源代码中和配置Makefile中很多变量是可以互相运送的。简单来说有些符号的值可以从Makefile中传递到源代码中。

五 复位代码的主要功能
1.设置cpu为管理模式（svc）

/*
	 * set the cpu to SVC32 mode and IRQ & FIQ disable
	 */
	@;mrs	r0,cpsr
	@;bic	r0,r0,#0x1f
	@;orr	r0,r0,#0xd3
	@;msr	cpsr,r0
	msr	cpsr_c, #0xd3		@ I & F disable, Mode: 0x13 - SVC

被注释掉的四行代码和第五行表达的同一个意思：
将CPU设置为禁止FIQ IRQ，ARM状态，SVC模式。
注：ARM cpu在复位时默认进入svc模式。

2.cpu初始化

    bl	disable_l2cache

	bl	set_l2cache_auxctrl_cycle

	bl	enable_l2cache
	
       /*
        * Invalidate L1 I/D
        */
        mov	r0, #0                  @ set up for MCR
        mcr	p15, 0, r0, c8, c7, 0   @ invalidate TLBs
        mcr	p15, 0, r0, c7, c5, 0   @ invalidate icache

       /*
        * disable MMU stuff and caches
        */
        mrc	p15, 0, r0, c1, c0, 0
        bic	r0, r0, #0x00002000     @ clear bits 13 (--V-)
        bic	r0, r0, #0x00000007     @ clear bits 2:0 (-CAM)
        orr	r0, r0, #0x00000002     @ set bit 1 (--A-) Align
        orr	r0, r0, #0x00000800     @ set bit 12 (Z---) BTB
        mcr 	p15, 0, r0, c1, c0, 0

（1）bl disable_l2cache 禁止l2 cache
（2）bl set_l2cache_auxctrl_cycle l2 cache相关初始化
（3）bl enable_l2cache 使能l2 cache
（4）刷新L1 cache的icache和dcache。
（5）关闭MMU

3.识别并暂存启动介质选择

/* Read booting information */
        ldr	r0, =PRO_ID_BASE
        ldr	r1, [r0,#OMR_OFFSET]
        bic	r2, r1, #0xffffffc1

这几行代码是读取启动信息，PRO_ID_BASE的值为0xE0000000，0MR_0FFSET的值为0x04。
(1)从哪里启动是由SoC的OM5:OM0这6个引脚的高低电平决定的。
(2)实际上在210内部有一个寄存器（地址是0xE0000004），这个寄存器中的值是硬件根据OM引脚的设置而自动设置值的。这个值反映的就是OM引脚的接法（电平高低），也就是真正的启动介质是谁。
(3)我们代码中可以通过读取这个寄存器的值然后判断其值来确定当前选中的启动介质是Nand还是SD还是其他的。
(4)这几行代码执行完后，在r2寄存器中存储了一个数字，这个数字等于某个特定值时就表示SD启动，等于另一个特定值时表示从Nand启动····

4.设置栈

ldr	sp, =0xd0036000 /* end of sram dedicated to u-boot */
sub	sp, sp, #12	/* set stack */@用sp减去12，是栈的大小
mov	fp, #0

（1）这是第一次设置栈，这次设置栈是在SRAM中设置的，因为当前整个代码还在SRAM中运行，此时DDR还未被初始化还不能用。栈地址0xd0036000是自己指定的，指定的原则就是这块空间只给栈用，不会被别人占用。
（2）在调用函数前初始化栈，主要原因是在被调用的函数内还有再次调用函数，而bl指令只会将返回地址存储到LR中，但是我们只有一个LR，所以在第二层调用函数前要先将LR入栈，否则函数返回时第一层的返回地址就丢了。