6种类型（53种主要助记符） ：
数据处理指令（22种主要助记符）
跳转指令（4种主要助记符）
Load/Store指令（16种主要助记符）
程序状态寄存器指令（2种主要助记符）
协处理器指令（5种主要助记符）
软件中断指令 （2种主要助记符）
数据处理指令
数据处理指令大致可分为3类：
数据传送指令；
算术逻辑运算指令；
乘法指令
比较指令。
数据处理指令只能对寄存器的内容进行操作，而不能对内存中的数据进行操作。所有ARM数据处理指令均可选择使用S后缀，并影响状态标志。
数据处理指令1
MOV 数据传送指令
格式：MOV{<cond>}{S} <Rd>,<op1>;
功能：Rd＝op1
op1可以是寄存器、被移位的寄存器或立即数。
例如：
MOV R0,＃5 ;R0=5
MOV R0,R1 ;R0=R1
MOV R0,R1,LSL＃5 ;R0=R1左移5位
数据处理指令2
2．MVN 数据取反传送指令
格式：MVN{<cond>}{S} <Rd>,<op1>;
功能：将op1表示的值传送到目的寄存器Rd中，但该值在传送前被按位取反，即Rd=!op1；
op1可以是寄存器、被移位的寄存器或立即数。
例如：
MVN R0,＃0 ;R0=-1
数据处理指令3
3．ADD 加法指令
格式：ADD{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn+op2
op2可以是寄存器，被移位的寄存器或立即数。
例如：
ADD R0,R1,＃5 ;R0=R1+5
ADD R0,R1,R2 ;R0=R1+R2
ADD R0,R1,R2,LSL＃5 ;R0=R1+R2左移5位
数据处理指令4
4．ADC 带进位加法指令
格式：ADC{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn+op2+carry
op2可以是寄存器、被移位的寄存器或立即数；carry为进位标志值。该指令用于实现超过32位的数的加法。
例如：
第一个64位操作数存放在寄存器R2，R3中；
第二个64位操作数存放在寄存器R4，R5中；
64位结果存放在R0，R1中。
64位的加法可由以下语句实现：
ADDS R0,R2,R4 ;低32位相加，S表示结果影响条件标志位的值
ADC R1,R3,R5 ;高32位相加
数据处理指令5
5．SUB 减法指令
格式：SUB{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn-op2
op2可以是寄存器、被移位的寄存器或立即数。
例如：
SUB R0,R1,＃5 ;R0=R1-5
SUB R0,R1,R2 ;R0=R1-R2
SUB R0,R1,R2,LSL＃5 ;R0=R1-R2左移5位
数据处理指令6
6．RSB 反向减法指令
格式：RSB{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：同SUB指令，但倒换了两操作数的前后位置，即Rd＝op2-Rn。
例如：
RSB R0,R1,＃5 ;R0=5-R1
RSB R0,R1,R2 ;R0=R2-R1
RSB R0,R1,R2,LSL＃5 ;R0=R2左移5位-R1
数据处理指令7
7．SBC 带借位减法指令
格式：SBC{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn-op2-!carry
op2可以是寄存器、被移位的寄存器或立即数。
SUB和SBC生成进位标志的方式不同于常规，如果需要借位则清除进位标志，所以指令要对进位标志进行一个非操作。
例如：
第一个64位操作数存放在寄存器R2，R3中；
第二个64位操作数存放在寄存器R4，R5中；
64位结果存放在R0，R1中。
64位的减法（第一个操作数减去第二个操作数）可由以下语句实现：
SUBS R0,R2,R4; 低32位相减，S表示结果影响条件标志位的值
SBC R1,R3,R5; 高32位相减
数据处理指令8
8．RSC 带借位的反向减法指令
格式：RSC{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：同SBC指令，但倒换了两操作数的前后位置，即Rd＝op2-Rn-!carry。
例如：
前提条件与SBC例子相同，操作数1-操作数2的实现语句需改为：
SUBS R0,R2,R4; 低32位相减，S表示结果影响寄存器CPSR的值
RSC R1,R5,R3; 高32位相减
数据处理指令——乘法指令
ARM7TDMI具有三种乘法指令，分别为：
32×32位乘法指令；
32× 32位乘加指令；
32× 32位结果为64位的乘/乘加指令。
数据处理指令9
9．MUL 32位乘法指令
格式：MUL{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn×op2
该指令根据S标志，决定操作是否影响CPSR的值；其中op2必须为寄存器。Rn和op2的值为32位的有符号数或无符号数。
例如：
MULS R0,R1,R2 ;R0＝R1×R2，结果影响寄存器CPSR的值
数据处理指令10
10．MLA 32位乘加指令
格式：MLA{<cond>}{S} <Rd>,<Rn>,<op2>,<op3>;
功能：Rd＝Rn×op2+op3
op2和op3必须为寄存器。Rn、op2和op3的值为32位的有符号数或无符号数。
例如：
MLA R0,R1,R2,R3 ;R0＝R1×R2+R3
数据处理指令11
11．SMULL 64位有符号数乘法指令
格式：
SMULL{<cond>}{S} <Rdl>,<Rdh>,<Rn>,<op2>;
功能：Rdh Rdl＝Rn×op2
Rdh、Rdl和op2均为寄存器。Rn和op2的值为32位的有符号数。
例如：
SMULL R0,R1,R2,R3
;R0＝R2×R3的低32位
;R1＝R2×R3的高32位
数据处理指令12
12．SMLAL 64位有符号数乘加指令
格式：
SMLAL{<cond>}{S} <Rdl>,<Rdh>,<Rn>,<op2>;
功能：Rdh Rdl＝Rn×op2+Rdh Rdl
Rdh、Rdl和op2均为寄存器。Rn和op2的值为32位的有符号数，Rdh Rdl的值为64位的加数。
例如：
SMLAL R0,R1,R2,R3
;R0＝R2×R3的低32位+R0
;R1＝R2×R3的高32位+R1
数据处理指令13
13．UMULL 64位无符号数乘法指令
格式：
UMULL{<cond>}{S} <Rdl>,<Rdh>,<Rn>,<op2>;
功能：同SMULL指令，但指令中Rn和op2的值为32位的无符号数。
例如：
UMULL R0,R1,R2,R3
;R0＝R2×R3的低32位
;R1＝R2×R3的高32位
其中R2，R3的值为无符号数
数据处理指令14
14．UMLAL 64位无符号数乘加指令
格式：
UMLAL {<cond>}{S} <Rdl>,<Rdh>,<Rn>,<op2>;
功能：同SMLAL指令，但指令中Rn，op2的值为32位的无符号数，Rdh Rdl的值为64位无符号数。
例如：
UMLAL R0,R1,R2,R3
;R0＝R2×R3的低32位+R0
;R1＝R2×R3的高32位+R1
其中R2，R3的值为32位无符号数
R1，R0的值为64位无符号数
数据处理指令15
15．AND 逻辑与指令
格式：AND{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn AND op2
op2可以是寄存器，被移位的寄存器或立即数。一般用于清除Rn的特定几位。
例如：
AND R0,R0,＃5
;保持R0的第0位和第2位，其余位清0
数据处理指令16
16．ORR 逻辑或指令
格式：ORR{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn OR op2
op2可以是寄存器、被移位的寄存器或立即数。一般用于设置Rn的特定几位。
例如：
ORR R0,R0,＃5
;R0的第0位和第2位设置为1，其余位不变
数据处理指令17
17．EOR 逻辑异或指令
格式：EOR{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn EOR op2
op2可以是寄存器、被移位的寄存器或立即数。一般用于将Rn的特定几位取反。
例如：
EOR R0,R0,＃5
;R0的第0位和第2位取反，其余位不变
数据处理指令18
18．BIC 位清除指令
格式：BIC{<cond>}{S} <Rd>,<Rn>,<op2>;
功能：Rd＝Rn AND (!op2)
用于清除寄存器Rn中的某些位，并把结果存放到目的寄存器Rd中.
操作数op2是一个32位掩码（mask），如果在掩码中设置了某一位，则清除Rn中的这一位；未设置的掩码位指示Rn中此位保持不变。其中，op2可以是寄存器、被移位的寄存器或立即数。
例如：
BIC R0,R0,＃5
;R0中第0位和第2位清0，其余位不变
数据处理指令19
19．CMP 比较指令
格式：CMP{<cond>} <Rn>,<op1>;
功能：Rn-op1
该指令进行一次减法运算，但不存储结果，根据结果更新CPSR中条件标志位的值。
该指令不需要显式地指定S后缀来更改状态标志。其中，操作数op1为寄存器或立即数。
例如：
CMP R0,＃5
;计算R0-5，根据结果设置条件标志位
ADDGT R0,R0,＃5
;如果R0>5，则执行ADDGT指令
数据处理指令20
20．CMN 反值比较指令
格式：CMN{<cond>} <Rn>,<op1>;
功能：同CMP指令，但寄存器Rn的值是和op1取负的值进行比较。
例如：
CMN R0,＃5 ;把R0与-5进行比较
数据处理指令21
21．TST 位测试指令
格式：TST{<cond>} <Rn>,<op1>;
功能： Rn AND op1
根据结果更新CPSR中条件标志位的值，但不存储结果。
用于检查寄存器Rn是否设置了op1中相应的位。
例如：
TST R0，＃5
；测试R0中第0位和第2位是否为1
数据处理指令22
22．TEQ 相等测试指令
格式：TEQ{<cond>} <Rn>,<op1>;
功能： Rn EOR op1
将寄存器Rn的值和操作数op1所表示的值按位作逻辑异或操作，根据结果更新CPSR中条件标志位的值，但不存储结果。
用于检查寄存器Rn的值是否和op1所表示的值相等。
例如：
TEQ R0,＃5 ;判断R0的值是否和5相等
跳转指令
跳转指令用于实现程序的跳转和程序状态的切换。
ARM程序设计中，实现程序跳转有两种方式：
（1）跳转指令，
（2）直接向程序寄存器PC（R15）中写入目标地址值。
通过向程序计数器PC写入跳转地址值，可以实现在4GB的地址空间中的任意跳转。
使用跳转指令，其跳转空间受到限制。
跳转指令1
1．B 跳转指令
格式：B{<cond>} <addr>;
功能： PC= PC+ addr左移两位
addr的值是相对当前PC（即寄存器R15）的值的一个偏移量，而不是一个绝对地址，它是24位有符号数。实际地址的值由汇编器来计算.
addr的值有符号扩展为32位后，左移两位，然后与PC值相加，即得到跳转的目的地址。
跳转的范围为-32MB~+32MB。
例如：
B exit; 程序跳转到标号exit处
…exit…
跳转指令2
2．BL 带返回的跳转指令
格式：BL{<cond>} <addr>;
功能：同B指令，但BL指令执行跳转操作的同时，还将PC（寄存器R15）的值保存到LR寄存器（寄存器R14）中。
该指令用于实现子程序调用，程序的返回可通过把LR寄存器的值复制到PC寄存器中来实现。
例如：
BL func; 调用子程序func
…
func
…
MOV R15,R14; 子程序返回
跳转指令2
由于返回地址保存在寄存器里，在保存R14之前不应再调用下一级的嵌套子程序；否则，新的返回地址将覆盖原来的返回地址，就无法返回到原来的调用位置。这时一般是把R14压入存储器中的堆栈。由于子程序经常还需要一些工作寄存器，所以可使用多寄存器存储指令同时把这些寄存器中原有的数据一起存储。
例如：
BL SUB1
…
SUB1 STMFD R13!,{R0-R2,R14};保存工作和链接寄存器
BL SUB2
…SUB2…
对于不调用其他子程序的子程序（叶子程序），不需要保存R14，因为它不会被覆盖。
跳转指令3
3．BLX 带返回和状态切换的跳转指令
格式：BLX <addr>;或BLX <Rn>;
功能：处理器跳转到目标地址处，并将PC（寄存器R15）的值保存到LR寄存器（R14）中。
若为第二种格式，寄存器Rn的值是转移目标，Rn的第0位拷贝到CPSR中的T位（决定是继续执行还是切换到Thumb指令），[31:0]位移入PC；
如果Rn[0]是1，则处理器切换执行Thumb指令，并在Rn中的地址开始执行，但是需将最低为清零；如果Rn[0]是0，则处理器继续执行ARM指令，并在Rn中的地址处开始执行，但需将Rn[1]清零。
该指令用于子程序调用和程序状态的切换。
例如：
BLX T16; 跳转到标号T16处执行，T16后面的指令为Thumb指令
…
CODE16
T16 后面指令为Thumb指令
…
跳转指令4
4．BX 带状态切换的跳转指令
格式：BX <Rn>;
功能：处理器跳转到目标地址处，从那里继续执行；
目标地址为寄存器Rn的值和0xFFFFFFFE作与操作的结果。
目标地址处的指令可以是ARM指令，也可以是Thumb 指令。
例如：
ADR R0,exit ;标号exit处的地址装入R0中
BX R0 ;跳转到exit处
Load/Store指令
Load/Store指令用于寄存器和内存间数据的传送。
Load用于把内存中的数据装载到寄存器中。
Store用于把寄存器中的数据存入内存。
该集合的指令使用频繁，在指令集中最为重要，因为其他指令只能操作寄存器，当数据存放在内存中时，必须先把数据从内存装载到寄存器，执行完后再把寄存器中的数据存储到内存中。
Load/Store指令分为3类：
（1）单一数据传送指令（LDR和STR等）
（2）多数据传送指令（LDM和STM）
（3）数据交换指令（SWP和SWPB）
条件执行的举例
将流程图对应GCD算法转换成
1) 普通汇编代码
2)ARM 汇编代码.
只使用 CMP, B 及 SUB指令
条件执行的举例
普通汇编代码
gcd cmp r0, r1 ;reached the end?
beq stop
blt less ;if r0 > r1
sub r0, r0, r1 ;subtract r1 from r0
bal gcd
less sub r1, r1, r0 ;subtract r0 from r1
bal gcd
stop
ARM 代码
gcd cmp r0, r1 ;if r0 > r1
subgt r0, r0, r1 ;subtract r1 from r0
sublt r1, r1, r0 ;else subtract r0 from r1
bne gcd ;
Load/Store指令1-1
1．LDR 字数据加载指令
格式：LDR{<cond>} <Rd>,<addr>;
功能：把addr所表示的内存地址中的字数据装载到目标寄存器Rd中，同时还可以把合成的有效地址写回到基址寄存器。
地址addr可以是一个简单的值、一个偏移量，或者是一个被移位的偏移量。
寻址方式：
Rn：基址寄存器。
Rm：变址寄存器。
Index：偏移量，12位的无符号数。
LDR Rd,[Rn]
;把内存中地址为Rn的字数据装入寄存器Rd中
LDR Rd,[Rn,Rm]
;将内存中地址为Rn+Rm的字数据装入寄存器Rd中
Load/Store指令1-2
LDR Rd,[Rn,＃index]
;将内存中地址为Rn+index的字数据装入Rd中
LDR Rd,[Rn,Rm,LSL＃5]
;将内存中地址为Rn+Rm×32的字数据装入Rd
LDR Rd,[Rn,Rm] ！
;将内存中地址为Rn+Rm的字数据装入Rd，并将新地址Rn+Rm写入Rn
LDR Rd,[Rn,＃index] ！
;将内存中地址为Rn+index的字数据装入Rd，并将新地址Rn+index写入Rn
LDR Rd,[Rn,Rm，LSL＃5]！
;将内存中地址为Rn+Rm×32的字数据装入Rd，并将新地址Rn+Rm×32写入Rn
Load/Store指令1-3
LDR Rd,[Rn],Rm
;将内存中地址为Rn的字数据装入寄存器Rd，并将新地址Rn+Rm写入Rn
LDR Rd,[Rn],＃index
;将内存中地址为Rn的字数据装入寄存器Rd，并将新地址Rn+index写入Rn
LDR Rd,[Rn],Rm,LSL＃5
;将内存中地址为Rn的字数据装入寄存器Rd，并将新地址Rn+Rm×32写入Rn
例如：
LDR R0,[R1,R2,LSL＃5]!
; 将内存中地址为R1+R2×32的字数据装入寄存器R0，并将新地址R1+R2×32写入R1
Load/Store指令2
LDRB 字节数据加载指令
格式：LDR{<cond>}B <Rd>,<addr>;
功能：同LDR指令，但该指令只是从内存读取一个8位的字节数据而不是一个32位的字数据，并将Rd的高24位清0。
例如：
LDRB R0,[R1]
;将内存中起始地址为R1的一个字节数据装入R0中
Load/Store指令3
3．LDRBT 用户模式的字节数据加载指令
格式：LDR{<cond>}BT <Rd>,<addr>;
功能：同LDRB指令，但无论处理器处于何种模式，都将该指令当作一般用户模式下的内存操作。
Load/Store指令4
4．LDRH 半字数据加载指令
格式：LDR{<cond>}H <Rd>,<addr>;
功能：同LDR指令，但该指令只是从内存读取一个16位的半字数据而不是一个32位的字数据，并将Rd的高16位清0。
例如：
LDRH R0,[R1]
;将内存中起始地址为R1的一个半字数据装入R0中
Load/Store指令5
5．LDRSB 有符号的字节数据加载指令
格式：LDR{<cond>}SB <Rd>,<addr>;
功能：同LDRB指令，但该指令将寄存器Rd的高24位设置成所装载的字节数据符号位的值。
例如：
LDRSB R0,[R1]
;将内存中起始地址为R1的一个字节数据装入R0中，R0的高24位设置成该字节数据的符号位
Load/Store指令6
6．LDRSH 有符号的半字数据加载指令
格式：LDR{<cond>}SH <Rd>,<addr>;
功能：同LDRH指令，但该指令将寄存器Rd的高16位设置成所装载的半字数据符号位的值。
例如：
LDRSH R0,[R1]
;将内存中起始地址为R1的一个16位半字数据装入R0中，R0的高16位设置成该半字数据的符号位
Load/Store指令7
7．LDRT 用户模式的字数据加载指令
格式：LDR{<cond>}T <Rd>,<addr>;
功能：同LDR指令，但无论处理器处于何种模式，都将该指令当作一般用户模式下的内存操作。
addr所表示的有效地址必须是字对齐的，否则从内存中读出的数值需进行循环右移操作。
Load/Store指令8
8．STR 字数据存储指令
格式：STR{<cond>} <Rd>,<addr>;
功能：把寄存器Rd中的字数据（32位）保存到addr所表示的内存地址中，同时还可以把合成的有效地址写回到基址寄存器。
地址addr可以是一个简单的值、一个偏移量，或者是一个被移位的偏移量。
寻址方式同LDR指令。
例如：
STR R0,[R1,＃5]!
;把R0中的字数据保存到以R1+5为地址的内存中，然后R1＝R1+5
STR指令应用举例
STR指令应用举例
Load/Store指令9
9．STRB 字节数据存储指令
格式：STR{<cond>}B <Rd>,<addr>;
功能：把寄存器Rd中的低8位字节数据保存到addr所表示的内存地址中。
其他用法同STR指令。
例如：
STRB R0,[R1]
;将寄存器R0中的低8位数据存入R1表示的内存地址中
Load/Store指令10
10．STRBT 用户模式的字节数据存储指令
格式：STR{<cond>}BT <Rd>,<addr>;
功能：同STRB指令，但无论处理器处于何种模式，该指令都将被当作一般用户模式下的内存操作。
Load/Store指令11
11．STRH 半字数据存储指令
格式：STR{<cond>}H <Rd>,<addr>;
功能：把寄存器Rd中的低16位半字数据保存到addr所表示的内存地址中，而且addr所表示的地址必须是半字对齐的。
其他用法同STR指令。
例如：
STRH R0,[R1]
;将寄存器R0中的低16位数据存入R1表示的内存地址中
存储格式对于加载/存储指令的影响
Load/Store指令12
12．STRT 用户模式的字数据存储指令
格式：STR{<cond>}T <Rd>,<addr>;
功能：同STR指令，但无论处理器处于何种模式，该指令都将被当作一般用户模式下的内存操作。
Load/Store指令13-1
13．LDM 批量数据加载指令
格式：
LDM{<cond>}{<type>} <Rn>{!},<regs>{^};
功能：从一片连续的内存单元读取数据到各个寄存器中，内存单元的起始地址为基址寄存器Rn的值，各个寄存器由寄存器列表regs表示。
该指令一般用于多个寄存器数据的出栈。
type字段种类：
IA：每次传送后地址加1。
IB：每次传送前地址加1。
DA：每次传送后地址减1。
DB：每次传送前地址减1。
FD：满递减堆栈。
ED：空递减堆栈。
FA：满递增堆栈。
EA：空递增堆栈。
注意：有一个约定，编号低的寄存器在存储数据或者加载数据时对应于存储器的低地址。
Load/Store指令13-2
例如 LDMIA/IB/DA/DB R13!,{R0-R1,R3};
各指令执行完后，结果如图所示。
Load/Store指令13-4
FD、ED、FA和EA指定是满栈还是空栈，是升序栈还是降序栈，用于堆栈寻址。
一个满栈的栈指针指向上次写的最后一个数据单元.
空栈的栈指针指向第一个空闲单元。
一个降序栈是在内存中反向增长而升序栈在内存中正向增长。
Load/Store指令13-5
格式：
LDM{<cond>}{<type>} <Rn>{!},<regs>{^};
{!}：若选用了此后缀，则当指令执行完毕后，将最后的地址写入基址寄存器。
{^}：当regs中不包含PC时，该后缀用于指示指令所用的寄存器为用户模式下的寄存器，否则指示指令执行时，将寄存器SPSR的值复制到CPSR中。
Load/Store指令14-1
14．STM 批量数据存储指令
格式：STM{<cond>}{<type>} <Rn>{!},<regs>{^};
功能：将各个寄存器的值存入一片连续的内存单元中，内存单元的起始地址为基址寄存器Rn的值，各个寄存器由寄存器列表regs表示。
该指令一般用于多个寄存器数据的入栈。
{^}：指示指令所用的寄存器为用户模式下的寄存器。
其他参数用法同LDM指令。
例如：
STMEA R13!,{R0-R12,PC}
;将寄存器R0~R12以及程序计数器PC的值保存到R13指示的堆栈中
Load/Store指令14-2
举例：其中R1为指令执行前的基址寄存器，R1’则为指令执行后的基址寄存器
Load/Store指令14-3
堆栈操作和数据块传送指令类似，也有4种模式，它们之间的关系如下表所示：
Load/Store指令15
15．SWP 字数据交换指令
格式：SWP{<cond>} <Rd>,<op1>,[<op2>];
功能： Rd＝[op2]，[op2]＝op1
从op2所表示的内存装载一个字并把这个字放置到目的寄存器Rd中，然后把寄存器op1的内容存储到同一内存地址中。
op1，op2均为寄存器。
例如：
SWP R0,R1,[R2]
;将R2所表示的内存单元中的字数据装载到R0，然后将R1中的字数据保存到R2所表示的内存单元中
Load/Store指令16
16．SWPB 字节数据交换指令
格式：SWP{<cond>}B <Rd>,<op1>,[<op2>];
功能：从op2所表示的内存装载一个字节并把这个字节放置到目的寄存器Rd的低8位中，Rd的高24位设置为0；然后将寄存器op1的低8位数据存储到同一内存地址中。
例如：
SWPB R0,R1,[R2]
;将R2所表示的内存单元中的一个字节数据装载到R0的低8位，然后将R1中的低8位字节数据保存到R2所表示的内存单元中
程序状态寄存器指令
用于状态寄存器和通用寄存器间传送数据。
总共有两条指令：MRS和MSR。
两者结合可用来修改程序状态寄存器的值。
程序状态寄存器指令1
1．MRS 程序状态寄存器到通用寄存器的数据传送指令
格式：MRS{<cond>} <Rd>,CPSR/SPSR;
功能：用于将程序状态寄存器的内容传送到目标寄存器Rd中。
当进入中断服务程序或进程切换时，该指令可用来保存当前状态寄存器的值。
例如：
MRS R0,CPSR
;状态寄存器CPSR的值存入寄存器R0中
程序状态寄存器指令2
2．MSR 通用寄存器到程序状态寄存器的数据传送指令
格式：MSR{<cond>} CPSR/SPSR_<field>,<op1>;
功能：用于将寄存器Rd的值传送到程序状态寄存器中。
当退出中断服务程序或进程切换时，该指令可用来恢复状态寄存器的值。
操作数op1可以是通用寄存器或立即数。
<field>：用来设置状态寄存器中需要操作的位。
32位的状态寄存器可以分为4个域：
位[31：24]为条件标志位域，用f表示。
位[23：16]为状态位域，用s表示。
位[15：8]为扩展位域，用x表示。
位[7：0]为控制位域，用c表示。
例如：MSR CPSR_f,R0
;用R0的值修改CPSR的条件标志域
MSR CPSR_fsxc,#5; CPSR的值修改为5
关于cpsr_fsxc,转载了一点解释：
c 指 CPSR中的control field ( PSR[7:0])
f 指 flag field (PSR[31:24])
x 指 extend field (PSR[15:8])
s 指 status field ( PSR[23:16])
31 30 29 28 --- 7 6 - 4 3 2 1 0
N Z C V I F M4 M3 M2 M1 M0
0 0 0 0 0 User26 模式
0 0 0 0 1 FIQ26 模式
0 0 0 1 0 IRQ26 模式
0 0 0 1 1 SVC26 模式
1 0 0 0 0 User 模式
1 0 0 0 1 FIQ 模式
1 0 0 1 0 IRQ 模式
1 0 0 1 1 SVC 模式
1 0 1 1 1 ABT 模式
1 1 0 1 1 UND 模式
对于MSR（寄存器到状态寄存器）的指令，
MSR CPSR, r0
MSR CPSR_all, r0
MSR CPSR_flg, r0
都是已经过时的表示方法。
对于MRS（状态寄存器到寄存器）的指令，
MRS R0, CPSR 等同于MRS R0, CPSR_cxsf
MRS R0, CPSR_all 会有waring
MRS R0, CPSR_flg 会有错误
在ADS中使用c,f,x,s表示cpsr的各个部分是推荐的。从指令来说：
MSR CPSR_f, r0机器码为0xe128f000
MSR CPSR_c, r0机器码为0xe121f000
MSR CPSR_x, r0机器码为0xe122f000
MSR CPSR_s, r0机器码为0xe124f000
可见机器码中用bit[29:16]4bit表示是f,c,x,s的。所以能够在机器执行的时候，
给予不同的执行结果。为了代码向后兼容性，建议使用f,c,x,s尾缀
协处理器指令
ARM处理器最多可支持16个协处理器，用于辅助ARM完成各种协处理操作。
在程序执行过程中，各协处理器只执行自身的协处理指令，而忽略属于ARM处理器和其他协处理器的指令。
ARM协处理器指令可分为3类：
（1）ARM处理器用于初始化协处理器的数据操作指令（CDP）。
（2）协处理器寄存器和内存单元之间的数据传送指令（LDC，STC）。
（3）ARM处理器寄存器和协处理器寄存器之间的数据传送指令（MCR，MRC）。
CDP协处理器操作指令
格式：CDP{<cond>}<p>,<opcode1>,<CRd>,<CRm>,<CRn>,<opcode2>;
功能：用于传递指令给协处理器p，要求其在寄存器CRn和CRm上，进行操作opcode1，并把结果存放到CRd中，可以使用opcode2提供与操作有关的补充信息。
指令中的所有寄存器均为协处理器的寄存器，操作由协处理器完成。
指令中:
P为协处理器编号；
CRd为目的寄存器的协处理器寄存器；
CRm和CRn为存放操作数的协处理器寄存器；
Opcode1和opcode2为协处理器即将执行的操作。
例如：CDP p5，5，c0，c1，c2，9；
该指令用于通知协处理器p5，在c1和c2上执行操作5和9，并将结果存放到c0中。
LDC协处理器数据读取指令
格式：LDC {<cond>}{L}<p>,<CRd>,<addr>;
功能：将addr表示的内存地址中的连续数据传送到目的寄存器CRd中。
L表示指令为长读取操作，比如用于双精度数据的传输；
目的寄存器CRd为协处理器的寄存器；
addr的寻址方式同LDR指令，其寄存器为ARM处理器的寄存器。
例如：
LDC p5，c1，[R1+5]:该指令用于将R1＋5所对应的存储单元中的数据，传送到协处理器p5的寄存器c1中。
STC协处理器数据存储指令
格式：STC{<cond>}{L}<p>,<CRd>,<addr>;
功能：将寄存器CRd的值传送到addr表示的内存地址中。指令中各参数用法同LDC。
例如：STC p5，c1，[R1+5];
该指令用于将协处理器p5中寄存器c1的数据传送到R1＋5所对应的存储单元中。
MCR ARM寄存器到协处理器寄存器的数据传送指令
格式：MCR{<cond>}<p>,<op1>,<Rd>,<CRn>,<CRm>{,op2};
功能：将ARM处理器的寄存器Rd中的数据传送到协处理器p的寄存器CRn，CRm中；op1，op2为协处理器将要执行的操作。
例如：MCR p5,5,R1,C1,C2,9；该指令将R1中的数据传送到协处理器p5的寄存器C1，C2中，协处理器执行操作5和9。
MRC 协处理器寄存器到ARM寄存器的数据传送指令
格式：MRC {<cond>}<p>,<op1>,<Rd>,<CRn>,<CRm>{,op2};
功能：将协处理器p的寄存器CRn，CRm的数据传送到ARM处理器的寄存器Rd中；op1，op2为协处理器将要执行的操作。
例如：MRC p5,5,R1,C1,C2,9；该指令将寄存器C1，C2中的数据传送到R1中，协处理器p5协处理器执行操作5和9。
异常中断指令1
1．SWI 软件中断指令
格式：SWI {<cond>} 24位的立即数；
功能：用于产生软件中断，以使用户程序调用操作系统的系统例程。
指令中24位的立即数指定用户程序调用系统例程的类型，其参数通过通用寄存器传递。
当24位的立即数被忽略时，系统例程类型由寄存器R0指定，其参数通过其他通用寄存器传递。
例如：
SWI 0X05; 调用编号为05的系统例程。
异常中断指令3
2．BKPT 断点中断指令
格式：BKPT 16位的立即数；
功能：用于产生软件断点中断，以便软件调试时使用。16位的立即数用于保存软件调试中额外的断点信息。
指令操作的伪代码：
if (not overdiden by debug hardware) then
R14_abt = adderss of BKPT instruction + 4
SPSR_abt = CPSR
CPSR[4:0] = 0b10111 /* 中止模式 */
CPSR[5] = 0 /* 使程序处于 ARM 状态, T Bit = 0*/
/* CPSR[6] is unchanged, fiq不变*/
CPSR[7] = 1 /* 禁止正常中断，I Bit = 1， 禁止irq */
if high vectors configured then
PC = 0xFFFF000C
else
PC = 0x0000000C
扫一扫
1862
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
