1 、启动文件简介
DA14580的启动文件为boot_vectors.s，启动文件由汇编编写，是系统上电复位后第一个执行的程序。主要做了以下工作：
1.1、初始化堆栈指针 SP =__initial_sp
1.2、初始化PC指针 =Reset_Handler
1.3、初始化中断向量表
1.4、配置系统时钟
1.5、调用C库函数_main初始化用户堆栈，从而最终调用main函数去到C的世界
2 、查找ARM汇编指令
在讲解启动代码的时候，会涉及到ARM的汇编指令和Cortex内核的指令，有关Cortex内核的指令我们可以参考《CM3权威指南CnR2》第四章：指令集。剩下的ARM的汇编指令我们可以在MDK->Help->Uvision Help中搜索到，以EQU为例，检索如下：
检索出来的结果会有很多，我们只需要看Assembler User Guide 这部分即可。下面列出了启动文件中使用到的ARM汇编指令，该列表的指令全部从ARM Development Tools这个帮助文档里面检索而来。其中编译器相关的指令WEAK和ALIGN为了方便也放在同一个表格了。
3、启动文件代码讲解
3.1、Stack栈配置
Stack_Size EQU 0x00000600
AREA STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem SPACE Stack_Size
__initial_sp开辟栈的大小为0X00000600（1.5KB），名字为STACK，NOINIT即不初始化，可读可写，8（2^3）字节对齐。
栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部SRAM的大小。如果编写的程序比较大，定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了硬fault的时候，这时你就要考虑下是不是栈不够大，溢出了。
EQU：宏定义的伪指令，相当于等于，类似与C中的define。
AREA：告诉汇编器汇编一个新的代码段或者数据段。STACK表示段名，这个可以任意命名；NOINIT表示不初始化；READWRITE表示可读可写，ALIGN=3，表示按照2^3对齐，即8字节对齐。
SPACE：用于分配一定大小的内存空间，单位为字节。这里指定大小等于Stack_Size。
标号__initial_sp紧挨着SPACE语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。
3.2、Heap堆配置
Heap_Size EQU 0x00000100
AREA HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem SPACE Heap_Size
__heap_limit开辟堆的大小为0X00000100（256字节），名字为HEAP，NOINIT即不初始化，可读可写，8（2^3）字节对齐。__heap_base表示堆的起始地址，__heap_limit表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反。
堆主要用来动态内存的分配，像malloc()函数申请的内存就在堆上面。
PRESERVE8
THUMBPRESERVE8：指定当前文件的堆栈按照8字节对齐。
THUMB：表示后面指令兼容THUMB指令。THUBM是ARM以前的指令集，16bit，现在Cortex-M系列的都使用THUMB-2指令集，THUMB-2是32位的，兼容16位和32位的指令，是THUMB的超级。
3.3、向量表
AREA RESET,DATA, READONLY
EXPORT __Vectors
EXPORT __Vectors_End
EXPORT __Vectors_Size定义一个数据段，名字为RESET，可读。并声明__Vectors、__Vectors_End和__Vectors_Size这三个标号具有全局属性，可供外部的文件调用。
EXPORT：声明一个标号可被外部的文件使用，使标号具有全局属性。如果是IAR编译器，则使用的是GLOBAL这个指令。
当内核响应了一个发生的异常后，对应的异常服务例程(ESR)就会执行。为了决定ESR 的入口地址，内核使用了"向量表查表机制"。这里使用一张向量表。向量表其实是一个WORD（32 位整数）数组，每个下标对应一种异常，该下标元素的值则是该ESR 的入口地址。向量表在地址空间中的位置是可以设置的，通过NVIC 中的一个重定位寄存器来指出向量表的地址。在复位后，该寄存器的值为0。因此，在地址0 （即FLASH 地址0）处必须包含一张向量表，用于初始时的异常分配。要注意的是这里有个另类：0 号类型并不是什么入口地址，而是给出了复位后MSP 的初值。
__Vectors DCD __initial_sp ; Top of Stack
IF :DEF:__REMAP_SYSRAM
DCD Reset_Handler+0x20000000 ; Reset Handler
ELSE
DCD Reset_Handler ; Reset Handler
ENDIF
DCD NMI_Handler ; NMI Handler
DCD HardFault_Handler ; Hard Fault Handler
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD SVC_Handler ; SVCall Handler
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD PendSV_Handler ; PendSV Handler
DCD SysTick_Handler ; SysTick Handler
DCD BLE_WAKEUP_LP_Handler
DCD BLE_FINETGTIM_Handler
DCD BLE_GROSSTGTIM_Handler
DCD BLE_CSCNT_Handler
DCD BLE_SLP_Handler
DCD BLE_ERROR_Handler
DCD BLE_RX_Handler
DCD BLE_EVENT_Handler
DCD SWTIM_Handler
DCD WKUP_QUADEC_Handler
DCD BLE_RF_DIAG_Handler
DCD BLE_CRYPT_Handler
DCD UART_Handler
DCD UART2_Handler
DCD I2C_Handler
DCD SPI_Handler
DCD ADC_Handler
DCD KEYBRD_Handler
DCD RFCAL_Handler
DCD GPIO0_Handler
DCD GPIO1_Handler
DCD GPIO2_Handler
DCD GPIO3_Handler
DCD GPIO4_Handler
__Vectors_End
__Vectors_Size EQU __Vectors_End - __Vectors__Vectors为向量表起始地址，__Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。
向量表从FLASH的0地址开始放置，以4个字节为一个单位，地址0存放的是栈顶地址，0X04存放的是复位程序的地址，以此类推。从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道C语言中的函数名就是一个地址。
DCD：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。在向量表中，DCD分配了一堆内存，并且以ESR的入口地址初始化它们。
3.4、复位程序
AREA |.text|, CODE, READONLY定义一个名称为.text的代码段，可读。
Reset_Handler PROC
EXPORT Reset_Handler [WEAK]
IMPORT __main
IMPORT SystemInit
;remap
IF :DEF:__REMAP_SYSRAM
LDR R0, =0x0
LDR R1, [R0]
LDR R0, =0x20000000
LDR R2, [R0]
CMP R2, R1
BEQ remap_done
LDR R0, =0x50000012
LDRH R1, [R0]
LSRS R2, R1, #2
LSLS R1, R2, #2
MOVS R2, #0x2
ADDS R1, R1, R2 ;remap SYSRAM to 0
LSLS R2, R2, #14
ADDS R1, R1, R2 ;SW RESET
STRH R1, [R0]
remap_done
ENDIF
;remap
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDPPROC是定义子程序的伪指令，位置在子程序的开始处，它和ENDP分别表示子程序定义的开始和结束两者必须成对出现。
复位子程序是系统上电后第一个执行的程序，调用SystemInit函数初始化系统时钟，然后调用C库函数_mian，最终调用main函数去到C的世界。
WEAK：表示弱定义，如果外部文件优先定义了该标号则首先引用该标号，如果外部文件没有声明也不会出错。这里表示复位子程序可以由用户在其他文件重新实现，这里并不是唯一的。
IMPORT：表示该标号来自外部文件，跟C语言中的EXTERN关键字类似。这里表示SystemInit和__main这两个函数均来自外部的文件。
SystemInit()是一个标准的库函数，在system_ARMCM0.c这个文件中定义。主要作用是配置系统时钟。
__main是一个标准的C库函数，主要作用是初始化用户堆栈，最终调用main_func函数去到C的世界。
LDR R0, =SystemInit ;把函数SystemInit的地址赋值给R0,这里R0相当于是中间寄存器
BLX R0 ;跳转到SystemInit去执行,执行完该函数之后，会执行下面一条指令
LDR R0, =__main ;把函数__main的地址赋值给R0,这里R0相当于是中间寄存器
BX R0 ;跳转到__main去执行,不需要返回此次
3.5、中断服务程序
在启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的，真正的中断复服务程序需要我们在外部的C文件里面重新实现，这里只是提前占了一个位置而已。
如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时，程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无限循环，即程序就死在这里。
IMPORT NMI_HandlerC
NMI_Handler\
PROC
movs r0, #4
mov r1, lr
tst r0, r1
beq NMI_stacking_used_MSP
mrs r0, psp
ldr r1,=NMI_HandlerC
bx r1
NMI_stacking_used_MSP
mrs r0, msp
ldr r1,=NMI_HandlerC
bx r1
ENDP
IMPORT HardFault_HandlerC
HardFault_Handler\
PROC
movs r0, #4
mov r1, lr
tst r0, r1
beq HardFault_stacking_used_MSP
mrs r0, psp
ldr r1,=HardFault_HandlerC
bx r1
HardFault_stacking_used_MSP
mrs r0, msp
ldr r1,=HardFault_HandlerC
bx r1
ENDP
IMPORT SVC_Handler_c
SVC_Handler PROC
movs r0, #4
mov r1, lr
tst r0, r1
beq SVC_stacking_used_MSP
mrs r0, psp
ldr r1,=SVC_Handler_c
bx r1
SVC_stacking_used_MSP
mrs r0, msp
ldr r1,=SVC_Handler_c
bx r1
ENDP
PendSV_Handler PROC
EXPORT PendSV_Handler [WEAK]
B .
ENDP
SysTick_Handler PROC
EXPORT SysTick_Handler [WEAK]
B .
ENDP
Default_Handler PROC
EXPORT BLE_WAKEUP_LP_Handler [WEAK]
EXPORT BLE_FINETGTIM_Handler [WEAK]
EXPORT BLE_GROSSTGTIM_Handler [WEAK]
EXPORT BLE_CSCNT_Handler [WEAK]
EXPORT BLE_SLP_Handler [WEAK]
EXPORT BLE_ERROR_Handler [WEAK]
EXPORT BLE_RX_Handler [WEAK]
EXPORT BLE_EVENT_Handler [WEAK]
EXPORT SWTIM_Handler [WEAK]
EXPORT WKUP_QUADEC_Handler [WEAK]
EXPORT BLE_RF_DIAG_Handler [WEAK]
EXPORT BLE_CRYPT_Handler [WEAK]
EXPORT UART_Handler [WEAK]
EXPORT UART2_Handler [WEAK]
EXPORT I2C_Handler [WEAK]
EXPORT SPI_Handler [WEAK]
EXPORT ADC_Handler [WEAK]
EXPORT KEYBRD_Handler [WEAK]
EXPORT RFCAL_Handler [WEAK]
EXPORT GPIO0_Handler [WEAK]
EXPORT GPIO1_Handler [WEAK]
EXPORT GPIO2_Handler [WEAK]
EXPORT GPIO3_Handler [WEAK]
EXPORT GPIO4_Handler [WEAK]
B：跳转到一个标号。这里跳转到一个‘.’，即表示无线循环
3.6、用户堆栈初始化
ALIGNALIGN：对指令或者数据存放的地址进行对齐，后面会跟一个立即数。缺省表示4字节对齐。
IF :DEF:__MICROLIB
EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit
ELSE
IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap
__user_initial_stackheap
LDR R0, = Heap_Mem
LDR R1, = (Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR
ALIGN
ENDIF
END
判断是否定义了__MICROLIB ，如果定义了则赋予标号__initial_sp（栈顶地址）、__heap_base（堆起始地址）、__heap_limit（堆结束地址）全局属性，可供外部文件调用。有关这个宏我们在 KEIL 里面配置，具体见下图。然后堆栈的初始化就由 C 库函数_main 来完成。
如 果没 有 定 义 __MICROLIB ， 则 才 用 双 段 存 储 器 模 式 ， 且 声 明 标 号__user_initial_stackheap 具有全局属性，让用户自己来初始化堆栈。
IF,ELSE,ENDIF：汇编的条件分支语句，跟C语言的if ,else类似
END：文件结束
扫一扫
400
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
