没鸟事 玩全志A33 uboot 之 start.S

/*
 * armboot - Startup Code for OMAP3530/ARM Cortex CPU-core
 *
 * Copyright (c) 2004 Texas Instruments <r-woodruff2@ti.com>
 *
 * Copyright (c) 2001 Marius Gr枚ger <mag@sysgo.de>
 * Copyright (c) 2002 Alex Z眉pke <azu@sysgo.de>
 * Copyright (c) 2002 Gary Jennejohn <garyj@denx.de>
 * Copyright (c) 2003 Richard Woodruff <r-woodruff2@ti.com>
 * Copyright (c) 2003 Kshitij <kshitij@ti.com>
 * Copyright (c) 2006-2008 Syed Mohammed Khasim <x0khasim@ti.com>
 *
 * See file CREDITS for list of people who contributed to this
 * project.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */


#include <asm-offsets.h>
#include <config.h>
#include <version.h>


#define  ARMV7_USR_MODE           0x10
#define  ARMV7_FIQ_MODE           0x11
#define  ARMV7_IRQ_MODE           0x12
#define  ARMV7_SVC_MODE           0x13
#define  ARMV7_MON_MODE          0x16
#define  ARMV7_ABT_MODE           0x17
#define  ARMV7_UND_MODE           0x1b
#define  ARMV7_SYSTEM_MODE        0x1f
#define  ARMV7_MODE_MASK          0x1f
#define  ARMV7_FIQ_MASK           0x40
#define  ARMV7_IRQ_MASK           0x80


.globl _start
_start: b reset
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq
#ifdef CONFIG_SPL_BUILD
_undefined_instruction: .word _undefined_instruction
_software_interrupt: .word _software_interrupt
_prefetch_abort: .word _prefetch_abort
_data_abort: .word _data_abort
_not_used: .word _not_used
_irq: .word _irq
_fiq: .word _fiq
_pad: .word 0x12345678 /* now 16*4=64 */
#else
_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
_pad: .word 0x12345678 /* now 16*4=64 */
#endif /* CONFIG_SPL_BUILD */


.global _end_vect
_end_vect:


.balignl 16,0xdeadbeef
/*************************************************************************
 *
 * Startup Code (reset vector)
 *
 * do important init only if we don't start from memory!
 * setup Memory and board specific bits prior to relocation.
 * relocate armboot to ram
 * setup stack
 *
 *************************************************************************/


.globl _TEXT_BASE
_TEXT_BASE:
.word CONFIG_SYS_TEXT_BASE


#ifdef CONFIG_TEGRA2
/*
 * Tegra2 uses 2 separate CPUs - the AVP (ARM7TDMI) and the CPU (dual A9s).
 * U-Boot runs on the AVP first, setting things up for the CPU (PLLs,
 * muxes, clocks, clamps, etc.). Then the AVP halts, and expects the CPU
 * to pick up its reset vector, which points here.
 */
.globl _armboot_start
_armboot_start:
.word _start
#endif


/*
 * These are defined in the board-specific linker script.
 */
.globl _bss_start_ofs
_bss_start_ofs:
.word __bss_start - _start


.global _image_copy_end_ofs
_image_copy_end_ofs:
.word __image_copy_end - _start


.globl _bss_end_ofs
_bss_end_ofs:
.word __bss_end__ - _start


.globl _end_ofs
_end_ofs:
.word _end - _start


.globl  __int_vector_start__
__int_vector_start__:
.word  __int_vector_start - _start


.globl  __int_vector_end__
__int_vector_end__:
.word  __int_vector_end - _start


.globl  _standby_start__
_standby_start__:
.word  _standby_start - _start


.globl  _standby_end__
_standby_end__:
.word  _standby_end - _start


.globl  _standby_start_lma__
_standby_start_lma__:
.word  _standby_start_lma - _start


#ifdef CONFIG_USE_IRQ
/* IRQ stack memory (calculated at run-time) */
.globl IRQ_STACK_START
IRQ_STACK_START:
.word 0x0badc0de


/* IRQ stack memory (calculated at run-time) */
.globl FIQ_STACK_START
FIQ_STACK_START:
.word 0x0badc0de
#endif


/* IRQ stack memory (calculated at run-time) + 8 bytes */
.globl IRQ_STACK_START_IN
IRQ_STACK_START_IN:
.word 0x0badc0de


/*
 * the actual reset code
 */


reset:
bl save_boot_params
/*
* set the cpu to SVC32 mode
*/
@ mov r0, #0
@ cmp r0, #0
@ beq reset
here:
mrs r0, cpsr
bic r0, r0, #0x1f
orr r0, r0, #0xd3   @switch to svc mode and disable irq/fiq
msr cpsr,r0


#if defined(CONFIG_ARM_A7)
@set SMP bit
mrc p15, 0, r0, c1, c0, 1
orr r0, r0, #(1<<6)
mcr p15, 0, r0, c1, c0, 1
#endif
#if defined(CONFIG_ARCH_SUN9IW1P1)
ldr     r0, =0x008000e0
ldr     r1, =0x16aa0001
str     r1, [r0]
#endif


#if defined(CONFIG_OMAP34XX)
/* Copy vectors to mask ROM indirect addr */
adr r0, _start@ r0 <- current position of code
add r0, r0, #4@ skip reset vector
mov r2, #64@ r2 <- size to copy
add r2, r0, r2@ r2 <- source end address
mov r1, #SRAM_OFFSET0@ build vect addr
mov r3, #SRAM_OFFSET1
add r1, r1, r3
mov r3, #SRAM_OFFSET2
add r1, r1, r3
next:
ldmia r0!, {r3 - r10}@ copy from source address [r0]
stmia r1!, {r3 - r10}@ copy to   target address [r1]
cmp r0, r2@ until source end address [r2]
bne next@ loop until equal */
#if !defined(CONFIG_SYS_NAND_BOOT) && !defined(CONFIG_SYS_ONENAND_BOOT)
/* No need to copy/exec the clock code - DPLL adjust already done
* in NAND/oneNAND Boot.
*/
bl cpy_clk_code@ put dpll adjust code behind vectors
#endif /* NAND Boot */
#endif /* CONFIG_OMAP34XX */
/* the mask ROM code should have PLL and others stable */
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
#endif


/* Set stackpointer in internal RAM to call board_init_f */
call_board_init_f:
ldr sp, =(CONFIG_SYS_INIT_SP_ADDR)
bic sp, sp, #7 /* 8-byte alignment for ABI compliance */
ldr r0,=0x00000000


@bl  boot_standby_relocat


bl asm_UART2_open
1:     


     mov r1, #0x35
     bl uart2_out_char


     ldr r0, =test_string
      bl printascii
//bl uart0_out_char
//b 1b
bl board_init_f


/*------------------------------------------------------------------------------*/


/*
 * void relocate_code (addr_sp, gd, addr_moni)
 *
 * This "function" does not return, instead it continues in RAM
 * after relocating the monitor code.
 *
 */
.globl relocate_code
relocate_code:
mov r4, r0/* save addr_sp */
mov r5, r1/* save addr of gd */
mov r6, r2/* save addr of destination */


/* Set up the stack   */
stack_setup:
mov sp, r4
    /* Set up irq stack */
add r4, r4, #12
add r4, r4, #0x2000
mrs r0, cpsr
    bic r0, r0, #0x1f
    orr r0, r0, #0x12
    msr cpsr_c, r0
mov sp, r4


    /* Set up svc stack */
sub r4, r4, #0x2000
sub r4, r4, #12
mrs r0, cpsr
    bic r0, r0, #0x1f
    orr r0, r0, #0x13
    msr cpsr_c, r0


adr r0, _start
cmp r0, r6
moveq r9, #0/* no relocation. relocation offset(r9) = 0 */
beq clear_bss/* skip relocation */


@ mov r9, #0
@ b   clear_bss


mov r1, r6/* r1 <- scratch for copy_loop */
ldr r3, _image_copy_end_ofs
add r2, r0, r3/* r2 <- source end address    */


copy_loop:
ldmia r0!, {r9-r10}/* copy from source address [r0]    */
stmia r1!, {r9-r10}/* copy to   target address [r1]    */
cmp r0, r2/* until source end address [r2]    */
blo copy_loop


#ifndef CONFIG_SPL_BUILD
/*
* fix .rel.dyn relocations
*/
@ldr r0, _TEXT_BASE/* r0 <- Text base */
adr r0, _start
sub r9, r6, r0/* r9 <- relocation offset */
ldr r10, _dynsym_start_ofs/* r10 <- sym table ofs */
add r10, r10, r0/* r10 <- sym table in FLASH */
ldr r2, _rel_dyn_start_ofs/* r2 <- rel dyn start ofs */
add r2, r2, r0/* r2 <- rel dyn start in FLASH */
ldr r3, _rel_dyn_end_ofs/* r3 <- rel dyn end ofs */
add r3, r3, r0/* r3 <- rel dyn end in FLASH */
fixloop:
ldr r0, [r2]/* r0 <- location to fix up, IN FLASH! */
add r0, r0, r9/* r0 <- location to fix up in RAM */
ldr r1, [r2, #4]
and r7, r1, #0xff
cmp r7, #23/* relative fixup? */
beq fixrel
cmp r7, #2/* absolute fixup? */
beq fixabs
/* ignore unknown type of fixup */
b fixnext
fixabs:
/* absolute fix: set location to (offset) symbol value */
mov r1, r1, LSR #4/* r1 <- symbol index in .dynsym */
add r1, r10, r1/* r1 <- address of symbol in table */
ldr r1, [r1, #4]/* r1 <- symbol value */
add r1, r1, r9/* r1 <- relocated sym addr */
b fixnext
fixrel:
/* relative fix: increase location by offset */
ldr r1, [r0]
add r1, r1, r9
fixnext:
str r1, [r0]
add r2, r2, #8/* each rel.dyn entry is 8 bytes */
cmp r2, r3
blo fixloop
b clear_bss
_rel_dyn_start_ofs:
.word __rel_dyn_start - _start
_rel_dyn_end_ofs:
.word __rel_dyn_end - _start
_dynsym_start_ofs:
.word __dynsym_start - _start


#endif /* #ifndef CONFIG_SPL_BUILD */


clear_bss:
#ifdef CONFIG_SPL_BUILD
/* No relocation for SPL */
ldr r0, =__bss_start
ldr r1, =__bss_end__
#else
ldr r0, _bss_start_ofs
ldr r1, _bss_end_ofs
mov r4, r6/* reloc addr */
add r0, r0, r4
add r1, r1, r4
#endif
mov r2, #0x00000000/* clear    */


clbss_l:str r2, [r0]/* clear loop...    */
add r0, r0, #4
cmp r0, r1
bne clbss_l


#ifdef CONFIG_USE_IRQ
ldr r0, __int_vector_start__
ldr r1, __int_vector_end__
sub r1, r1, r0
mov r2, #0
mov r4, r6
add r0, r0, r4
copy_int_loop:
ldmia   r0!, {r7-r8}
stmia   r2!, {r7-r8}
cmp     r2, r1


@ldr     r7, [r0]
@add     r0, r0, #4
@str     r7, [r2]
@add     r2, r2, #4
@cmp     r2, r1


blo     copy_int_loop
#endif


boot_standby_relocate:
ldr r0, _standby_start__
ldr r1, _standby_end__
ldr r2, _standby_start_lma__
adr r3, _start


add r0, r0, r3
add r1, r1, r3
add r2, r2, r3


copy_standby_loop:
ldmia   r2!, {r7-r8}
stmia   r0!, {r7-r8}
cmp     r0, r1
blo     copy_standby_loop
/*
 * We are done. Do not return, instead branch to second part of board
 * initialization, now running from RAM.
 */
jump_2_ram:
/*
 * If I-cache is enabled invalidate it
 */
#ifndef CONFIG_SYS_ICACHE_OFF
mcr p15, 0, r0, c7, c5, 0@ invalidate icache
mcr     p15, 0, r0, c7, c10, 4@ DSB
mcr     p15, 0, r0, c7, c5, 4@ ISB
#endif
ldr r0, _board_init_r_ofs
adr r1, _start
add lr, r0, r1
add lr, lr, r9
/* setup parameters for board_init_r */
mov r0, r5/* gd_t */
mov r1, r6/* dest_addr */
/* jump to it ... */
mov pc, lr


_board_init_r_ofs:
.word board_init_r - _start




#ifndef CONFIG_SKIP_LOWLEVEL_INIT
/*************************************************************************
 *
 * CPU_init_critical registers
 *
 * setup important registers
 * setup memory timing
 *
 *************************************************************************/
cpu_init_crit:
/*
* Invalidate L1 I/D
*/
mov r0, #0@ set up for MCR
mcr p15, 0, r0, c8, c7, 0@ invalidate TLBs
mcr p15, 0, r0, c7, c5, 0@ invalidate icache
mcr p15, 0, r0, c7, c5, 6@ invalidate BP array
mcr     p15, 0, r0, c7, c10, 4@ DSB
mcr     p15, 0, r0, c7, c5, 4@ ISB


/*
* disable MMU stuff and caches
*/
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002000@ clear bits 13 (--V-)
bic r0, r0, #0x00000007@ clear bits 2:0 (-CAM)
@ orr r0, r0, #0x00000002@ set bit 1 (--A-) Align   ;do not enable this bit, modified by jerry
orr r0, r0, #0x00000800@ set bit 11 (Z---) BTB
#ifdef CONFIG_SYS_ICACHE_OFF
bic r0, r0, #0x00001000@ clear bit 12 (I) I-cache
#else
orr r0, r0, #0x00001000@ set bit 12 (I) I-cache
#endif
mcr p15, 0, r0, c1, c0, 0


/*
* Jump to board specific initialization...
* The Mask ROM will have already initialized
* basic memory. Go here to bump up clock rate and handle
* wake up conditions.
*/
mov ip, lr@ persevere link reg across call
bl lowlevel_init@ go setup pll,mux,memory
mov lr, ip@ restore link
mov pc, lr@ back to my caller
#endif










#define SUNXI_UART0_BASE 0X01C28000
#define SUNXI_UART1_BASE 0X01C28400
#define SUNXI_UART2_BASE 0X01C28800
#define SUNXI_UART3_BASE 0X01C28C00
#define SUNXI_UART4_BASE 0X01C29000
#define SUNXI_UART5_BASE 0X01C29400




//    R0 a1 工作寄存器
//    R1 a2
//    R2 a3
//    R3 a4        
//    R4 v1 必须保护
//    R5 v2  
//    R6 v3 
//    R7 v4 
//    R8 v5   
//    R9 v6
//    R10 sl 栈限制
//    R11 fp 桢指针
//    R12 ip 内部过程调用寄存器
//    R13 sp 栈指针
//    R14 lr 连接寄存器
//    R15 pc 程序计数器



uart0_out_char:
    push {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, lr}
    mov r1, #0x39
    ldr r0, =SUNXI_UART0_BASE
    ldrb r3, [r0, #20]
    tst r3, #32
    beq uart0_out_char
    strb r1, [r0]
    pop {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, pc}




uart2_out_char:
    push {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, lr}
    mov r1, r1
    ldr r0, =SUNXI_UART2_BASE
    ldrb r3, [r0, #20]
    tst r3, #32
    beq uart2_out_char
    strb r1, [r0]
    pop {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, pc}
                         
    




//打印一个字符串
printascii:
    push {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, lr}
    //保存现场
    b    2f
    //向后跳到第一个标号为2的地方
1:                 
    bl uart2_out_char
    //串口2输出一个字符
    teq   r1,   #'\n'
    //判断当前已输出字符是否为换行符
    moveq r1,   #'\r'
    //如果是换行符的话,再自动追加回车符
    beq 1b
    //如果是换行符的话,继续打印
    //否则,处理下一个字符-->
2: 
    teq      r0, #0
    //测试字符串指针是否为空
    ldrneb r1, [r0], #1
    //字符串指针不为空时加载一个字符,并且字符串指针后移一个字符位置
    //字符串指针为空时不执行此条命令
    teqne r1, #0
    //字符串指针不为空时测试加载的字符是否为串结束字符
    //字符串指针为空时不执行此条命令
    bne 1b
    //不是串结束字符,继续打印下一字符
    //是结束字符,执行下一条指令
    //字符串指针为空时执行下一条指令
    pop {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, pc}
    //恢复现场,并返回
                                                                    
printch:
    //打印一个字符
    push {r0, r1, r2, r3, r4, r5, r6, r7, r9, sl, fp, ip, lr}
    mov   r1, r0
    //欲打印之字符
    mov   r0, #0
    //进入就打印一个字符,然后判断是否继续打印
    b     1b
                  
                   
                      
.globl    test_string
test_string:
    .ascii "test string in uboot start.S\n", "\0"
















#ifndef CONFIG_SPL_BUILD
/*
 *************************************************************************
 *
 * Interrupt handling
 *
 *************************************************************************
 */
@
@ IRQ stack frame.
@
#define S_FRAME_SIZE 72


#define S_OLD_R0 68
#define S_PSR 64
#define S_PC 60
#define S_LR 56
#define S_SP 52


#define S_IP 48
#define S_FP 44
#define S_R10 40
#define S_R9 36
#define S_R8 32
#define S_R7 28
#define S_R6 24
#define S_R5 20
#define S_R4 16
#define S_R3 12
#define S_R2 8
#define S_R1 4
#define S_R0 0


#define MODE_SVC 0x13
#define I_BIT 0x80


/*
 * use bad_save_user_regs for abort/prefetch/undef/swi ...
 * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 */


.macro bad_save_user_regs
sub sp, sp, #S_FRAME_SIZE@ carve out a frame on current
@ user stack
stmia sp, {r0 - r12}@ Save user registers (now in
@ svc mode) r0-r12
ldr r2, IRQ_STACK_START_IN@ set base 2 words into abort
@ stack
ldmia r2, {r2 - r3}@ get values for "aborted" pc
@ and cpsr (into parm regs)
add r0, sp, #S_FRAME_SIZE@ grab pointer to old stack


add r5, sp, #S_SP
mov r1, lr
stmia r5, {r0 - r3}@ save sp_SVC, lr_SVC, pc, cpsr
mov r0, sp@ save current stack into r0
@ (param register)
.endm


.macro irq_save_user_regs
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12}@ Calling r0-r12
add r8, sp, #S_PC@ !! R8 NEEDS to be saved !!
@ a reserved stack spot would
@ be good.
stmdb r8, {sp, lr}^@ Calling SP, LR
str lr, [r8, #0]@ Save calling PC
mrs r6, spsr
str r6, [r8, #4]@ Save CPSR
str r0, [r8, #8]@ Save OLD_R0
mov r0, sp
.endm


.macro irq_restore_user_regs
ldmia sp, {r0 - lr}^@ Calling r0 - lr
mov r0, r0
ldr lr, [sp, #S_PC]@ Get PC
add sp, sp, #S_FRAME_SIZE
subs pc, lr, #4@ return & move spsr_svc into
@ cpsr
.endm


.macro get_bad_stack
ldr r13, IRQ_STACK_START_IN@ setup our mode stack (enter
@ in banked mode)


str lr, [r13]@ save caller lr in position 0
@ of saved stack
mrs lr, spsr@ get the spsr
str lr, [r13, #4]@ save spsr in position 1 of
@ saved stack


mov r13, #MODE_SVC@ prepare SVC-Mode
@ msr spsr_c, r13
msr spsr, r13@ switch modes, make sure
@ moves will execute
mov lr, pc@ capture return pc
movs pc, lr@ jump to next instruction &
@ switch modes.
.endm


.macro get_bad_stack_swi
sub r13, r13, #4@ space on current stack for
@ scratch reg.
str r0, [r13]@ save R0 is value.
ldr r0, IRQ_STACK_START_IN@ get data regions start
@ spots for abort stack
str lr, [r0]@ save caller lr in position 0
@ of saved stack
mrs r0, spsr@ get the spsr
str lr, [r0, #4]@ save spsr in position 1 of
@ saved stack
ldr r0, [r13]@ restore r0
add r13, r13, #4@ pop stack entry
.endm


.macro get_irq_stack@ setup IRQ stack
ldr sp, IRQ_STACK_START
.endm


.macro get_fiq_stack@ setup FIQ stack
ldr sp, FIQ_STACK_START
.endm


/*
 * exception handlers
 */
.align 5
undefined_instruction:
get_bad_stack
bad_save_user_regs
bl do_undefined_instruction


.align 5
software_interrupt:
get_bad_stack_swi
bad_save_user_regs
bl do_software_interrupt


.align 5
prefetch_abort:
get_bad_stack
bad_save_user_regs
bl do_prefetch_abort


.align 5
data_abort:
get_bad_stack
bad_save_user_regs
bl do_data_abort


.align 5
not_used:
get_bad_stack
bad_save_user_regs
bl do_not_used


#ifdef CONFIG_USE_IRQ


.align 5
irq:
    sub     lr, lr, #4                                      
    //保存返回地址
stmfd   sp!, {r0-r12, lr}
//@; save context              
//@;寄存器压栈
mrs     r3, spsr     
//@;读取SPSR
stmfd   sp!, {r3}
//@;压栈


    msr     cpsr_c, #(ARMV7_FIQ_MASK | ARMV7_IRQ_MASK | ARMV7_SVC_MODE)    
    //@;切换到SVC模式
    stmfd   sp!, {r0-r12, lr}   
//@;保存lr_usr和其它用到的寄存器


bl      do_irq


    ldmfd   sp!, {r0-r12, lr}                  
//@;恢复SYSTEM模式寄存器
    msr     cpsr_c, #(ARMV7_FIQ_MASK | ARMV7_IRQ_MASK | ARMV7_IRQ_MODE)  
    //@;切换到IRQ模式
    ldmfd   sp!, {r3}  
//@; 数据出栈
    msr     spsr_cxsf, r3
    //@; 还原spsr


ldmfd   sp!, {r0-r12, pc}^   
//@;从异常模式返回 unknown event ignore


.align 5
fiq:
get_fiq_stack
/* someone ought to write a more effective fiq_save_user_regs */
irq_save_user_regs
bl do_fiq
irq_restore_user_regs


#else


.align 5
irq:
get_bad_stack
bad_save_user_regs
bl do_irq


.align 5
fiq:
get_bad_stack
bad_save_user_regs
bl do_fiq


#endif /* CONFIG_USE_IRQ */

#endif /* CONFIG_SPL_BUILD */









void asm_UART2_open( void )
{
  __u32   temp=0, i;
  __u32   uart_clk;
  __u32   lcr;
  volatile unsigned int   *reg;
     int port;
             
     struct spare_boot_head_t  uboot_spare_head_local; 
void  *uart_ctrl;
__u32 apb_freq;
//return;
      uboot_spare_head.boot_data.uart_port = 2;
uboot_spare_head_local.boot_data.uart_port = 2;
    uboot_spare_head_local.boot_data.uart_gpio[0].port = 2;
uboot_spare_head_local.boot_data.uart_gpio[0].port_num = 0;
uboot_spare_head_local.boot_data.uart_gpio[0].mul_sel = 2;
                      
uboot_spare_head_local.boot_data.uart_gpio[1].port = 2;
    uboot_spare_head_local.boot_data.uart_gpio[1].port_num = 1; 
uboot_spare_head_local.boot_data.uart_gpio[1].mul_sel = 2;
port = 2;


// config clock
if(port > 7)
{
return ;
}
reg = (volatile unsigned int *)0x01c2006C;
*reg &= ~(1 << (16 + port));
for( i = 0; i < 100; i++ );
*reg |=  (1 << (16 + port));
//Bus Clock Gating Register 3 
//总线时钟门控寄存器
//开启对应串口的时钟源
    
(*(volatile unsigned int *)0x01c202D8) |= (1 << (16 + port));
    //Bus Software Reset Register 4
    //软件复位对应串口
        
// config uart gpio
// config tx gpio


uart_ctrl = (void *)&uboot_spare_head_local.boot_data.uart_gpio[0];

boot_set_gpio((void *)uart_ctrl, 2, 1);


     apb_freq = 24*1000*1000;



    // Set Baudrate
    uart_clk = ( apb_freq + 8*UART_BAUD ) / (16*UART_BAUD);
    lcr = UART_REG_LCR(port);
    UART_REG_HALT(port) = 1;
    UART_REG_LCR(port) = lcr | 0x80;
    UART_REG_DLH(port) = uart_clk>>8;
    UART_REG_DLL(port) = uart_clk&0xff;
    UART_REG_LCR(port) = lcr & (~0x80);
UART_REG_HALT(port) = 0;
    // Set Lin Control Register
    temp = ((PARITY&0x03)<<3) | ((STOP&0x01)<<2) | (DLEN&0x03);
    UART_REG_LCR(port) = temp;


    // Disable FIFOs
    UART_REG_FCR(port) = 0x06; 
}                                                                       


没有更多推荐了,返回首页