SRAM代码重定位详解——基于S5PV210

最新推荐文章于 2024-03-04 14:06:08 发布

电信狗

最新推荐文章于 2024-03-04 14:06:08 发布

阅读量933

点赞数 2

文章标签： SRAM 代码重定向 S5PV210

本文链接：https://blog.csdn.net/dssegf/article/details/102421142

版权

本篇博客主要讲解了如何对SRAM中代码进行重定位的操作，硬件平台基于朱有鹏老师Stydy210开发板，板载主芯片为S5PV210。

一、重定位和为什么要重定位

首先我们需要需要明白两个概念：

运行地址，顾名思义就是程序运行的时候的地址，也就是你用工具将代码下载到RAM的那个地址，也叫加载地址
链接地址，由链接脚本指定的地址。为什么需要链接脚本指定地址呢？你想一下，在c语言编程中，当我们需要调用一个A函数的时候，编译器是怎么找到这个A函数？编译器肯定是知道它被放在哪里才可以找到它。那就是链接脚本的作用，链接脚本其实在程序被执行之前都已经指定A函数一个地址编号，以后所有的函数调用我们都会去这个地址编号那里寻找A函数。有点类似于c语言的指针变量

简单来说就是运行地址是我们代码目前真正运行的位置，而链接地址则是我们指定给编译器，告诉编译器我们的代码的位置在哪里，当运行地址和链接地址相等的时候，相安无事，但是，在某些情况下，我们希望运行地址和链接地址不相等，这就需要我们对代码进行重定位，这就是是重定位的由来。

但是在什么情况下我们希望运行地址和链接地址不同呢，我们来看一下芯片启动的例子：

当一块芯片启动的时候，依靠内部的SRAM，可以运行一小段代码，而因为DDR还没初始化，注定了开始的运行地址是在内部SRAM中的。当我们需要运行一个操作系统，那么点的内存怎么够运行呢？所以这时候就需要初始化DDR才可，而因为我们知道这代码将来都是在DDR上面运行的，所以链接脚本指定的链接地址肯定是DDR上面的地址，所以这就出现了链接地址跟运行地址不同的情况了

因此，在上面的情况下，我们需要把链接地址链接到DDR中，而运行地址却在SRAM里，当然，这只是重定位的其中一个例子而已，目的只是为了让大家感受一下为什么要用重定位，接下来该怎么进行重定位呢？

二、如何重定位

话不多说，直接上代码

/*
 * 文件名： led.s 
 * 作者： 朱老师
 * 描述： 演示重定位（在SRAM内部重定位）
 */
 #define 	WTCON 0xE2700000
 #define  SVC_STACK 0xd0037d80
 .global _start     // 把_start链接属性改为外部，这样其他文件就可以看见_start了
_start:
// 第1步：关看门狗（向WTCON的bit5写入0即可）
 ldr r0, =WTCON
 ldr r1, =0x0
 str r1, [r0]
 
// 第2步：设置SVC栈
 ldr sp, =SVC_STACK

 // 第3步：开/关icache
 mrc p15,0,r0,c1,c0,0;   // 读出cp15的c1到r0中
 //bic r0, r0, #(1<<12)   // bit12 置0  关icache
 orr r0, r0, #(1<<12)   // bit12 置1  开icache
 mcr p15,0,r0,c1,c0,0;
 
 // 第4步：重定位
 // adr指令用于加载_start当前运行地址
 adr r0, _start    // adr加载时就叫短加载  
 // ldr指令用于加载_start的链接地址:0xd0024000
 ldr r1, =_start // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载

// bss段的起始地址
 ldr r2, =bss_start // 就是我们重定位代码的结束地址，重定位只需重定位代码段和数据段即可
 cmp r0, r1   // 比较_start的运行时地址和链接地址是否相等
 beq clean_bss  // 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
      // 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
      // 重定位完成后继续执行clean_bss。

// 用汇编来实现的一个while循环
copy_loop:
 ldr r3, [r0], #4    // 源
 str r3, [r1], #4 // 目的   这两句代码就完成了4个字节内容的拷贝
 cmp r1, r2   // r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2
 bne copy_loop

 // 清bss段，其实就是在链接地址处把bss段全部清零
clean_bss:
 ldr r0, =bss_start     
 ldr r1, =bss_end
 cmp r0, r1    // 如果r0等于r1，说明bss段为空，直接下去
 beq run_on_dram   // 清除bss完之后的地址
 mov r2, #0
clear_loop:
 str r2, [r0], #4  // 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），
 cmp r0, r1    // 然后r0 = r0 + 4
 bne clear_loop

run_on_dram: 
 // 长跳转到led_blink开始第二阶段
 ldr pc, =led_blink    // ldr指令实现长跳转
 
 // 从这里之后就可以开始调用C程序了
 //bl led_blink     // bl指令实现短跳转
 
// 汇编最后的这个死循环不能丢
 b .

以上代码来自于朱有鹏老师嵌入式系统开发裸机教程，这一段是朱老师根据之前流水灯和icache的程序改的代码，关于朱老师的流水灯和icache的程序我也写过一次博客，如果想了解可以戳以下链接：
S5PV210之iCache的打开和关闭

在这里因为我们只关注代码中重定位的部分，所以我们删除掉其他部分，把代码变成这样：

 adr r0, _start    

 ldr r1, =_start 
 
 ldr r2, =bss_start 
 cmp r0, r1   
 beq clean_bss  

copy_loop:
   ldr r3, [r0], #4  
   str r3, [r1], #4
   cmp r1, r2
   bne copy_loop

clean_bss:
   ldr r0, =bss_start     
   ldr r1, =bss_end
   cmp r0, r1  
   beq run_on_dram
   mov r2, #0
 
clear_loop:
   str r2, [r0], #4 
   cmp r0, r1 
   bne clear_loop
run_on_dram: 
   ldr pc, =led_blink
   b .

嗯，，，，在看代码之前我们先搞清楚以下几点：

以上代码是为了完成一个任务：在SRAM中将代码从0xd0020010重定位到0xd0024000，本来代码是运行在0xd0020010的，但是我们希望代码实际是在0xd0024000位置运行的。需要对代码进行重定位
对于一个程序来说，大致上可以将其分为代码段，数据段和BSS段
text段:就是放程序代码的,编译时确定,只读,
data段:存放在编译阶段(而非运行时)就能确定的数据,可读可写，就是通常所说的静态存储区,赋了初值的全局变量和静态变量存放在这个区域,常量也存放在这个区域
BSS段:定义而没有赋初值的全局变量和静态变量,放在这个区域
位置无关码与位置有关码：
位置无关码（PIC）：依赖于程序当前运行的PC值，进行相对的跳转，导致的结果就是，无论代码在哪，总能达到指令的正常目的，因此是位置无关的。
位置有关码：不依赖当前PC值，是绝对跳转，只有程序运行在链接地址处时，才能达到指令的正常目的，因此是位置有关系的。
对于S5PV210来说，它的启动过程为：先运行内部IROM中的BL0（用来执行各种初始化的操作），再由BL0加载BL1到SRAM中执行，如果是裸机程序，到此为止，而如果有OS时，BL1运行时会加载BL2到SRAM中去运行；BL2运行时会初始化DDR并且将OS搬运到DDR去执行OS，启动完成，我们在这里写的是裸机程序，没有操作系统，所以，我们可以破坏BL1，也就是把程序下载到BL1中，从而达到初始化芯片以后，执行我们的程序的效果，但是要注意的是BL0引导BL1的初始化地址是固定的，即0xd0020010,也就是说我们只能把程序下载到0xd0020010起始的位置。
链接脚本的作用：我的浅显理解是它指定了程序的链接地址，并且指名程序的代码段，数据段和BSS段三者究竟是如何组织的。

了解了以上几点后，我们再来看代码
首先第一句：

adr r0, _start

这句话的意思是什么呢？_start是我们整个程序的开始，adr是短加载指令，当它加载符号地址时，加载的是运行时地址，我们知道程序的运行地址实际上就是我们的下载地址，也就是0xd0020010，也就是说r0=0xd00020010.

第二句：

ldr r1, =_start

在这里我们使用的是ldr指令，ldr指令在加载符号地址时，加载的是链接地址，链接地址我们按照要求需要把它设置到0xd0024000，那么我们是怎么设置这个链接地址的呢，我们来看看链接脚本代码：

SECTIONS
{
 . = 0xd0024000;
 
 .text : {
  start.o
  * (.text)
 }
      
 .data : {
  * (.data)
 }
 
 bss_start = .; 
 .bss : {
  * (.bss)
 }
 
 bss_end  = .; 
}

其中的. = 0xd0024000;这句实际上就是指定了链接地址是0xd0024000，我们知道链接脚本就是用来组织代码的，这里代码想表达的意思就是整个程序的首地址是0xd0024000，接下来是程序代码段（text）然后是程序的数据段（data）最后是程序的bss段，并且还把bss段的首地址定义为bss_start，然后把bss段的末地址定义为bss_end，整个链接脚本其实不过完成了这些功能而已。所以说，程序的链接地址在被链接脚本确定后就等于0xd0024000，回到第二句代码，那么r1=0xd0024000

接下来的这一句：

ldr r2, =bss_start
cmp r0, r1
beq clean_bss

实际上把bss段的首地址赋给r2，然后把r0和r1进行比较，实际上就是把运行地址和链接地址进行比较，由上面的分析可知两者是不相等的，所以跳过beq clean_bss代码，而直接执行下面的代码

copy_loop:
    ldr r3, [r0], #4 
    str r3, [r1], #4
    cmp r1, r2
    bne copy_loop

到这句代码中，程序进入了一个循环，完成的功能是把运行地址中的那一份代码原封不动的拷贝到链接地址中去，但是，是不是程序的所有的代码呢？不是的，我们知道r2 =bss_start，r2只是bss段的首地址，而循环中值的条件是r1=r2，也就是说我并不是把运行地址里面的所有的程序都给了链接地址处，而是只给了test段和data段，而bss段怎么办呢，因为bss段里面的变量必须都是0（这个是规定的），所以没有必要去传bss段，但这不代表链接程序里面就不需要bss段了，我们可以手动给链接地址处的代码创建一个bss段（一般来说，只要有编译器，我们写程序就可以不要管bss段的，设置bss段完全是编译器要做的事，但是因为我们要完成的是代码的重定向，编译器没有办法帮我们做，所以需要我们自己来做一个bss段）

下面我们来着重看一下上面代码中的这两句：

ldr r3, [r0], #4 
str r3, [r1], #4

这两句翻译成C语言是不是就清楚多了：

r3 = *r0;
r0+=4;
*r1 = r3;
r1+=4;

这里实际上是把r0和r1当成指针在用了，先赋值以后指针再自加，通过这样的步骤实现了拷贝的功能

接下来这一步就是来清bss段了

clean_bss:
    ldr r0, =bss_start
    ldr r1, =bss_end
    cmp r0, r1
    beq run_on_dram
    mov r2, #0
clear_loop:
    str r2, [r0], #4
    cmp r0, r1
    bne clear_loop

取r0、r1分别为链接地址bss段的起始和结尾地址（因为ldr地址取符号地址的时候取的都是链接地址），然后比较两者的值（在这里肯定是不相等的），所以使r2=0，接下来的clear_loop的作用是什么呢，实际上就是把r2（也就是0）填充到链接地址的bss段，长度是多少呢？就是bss_end-bss_end的值，实际上也就是运行地址那一份代码中的bss段的长度

run_on_dram:
    ldr pc, =led_blink
    b .

这里需要解释一下：led_blink其实是一个用C语言写的函数，代码我没有贴出来，因为重点不在这里，实际上这句代码就是让pc的值进行跳转，跳转到那个C函数里面去，然后b.让程序卡死在这里，然后讲到这里有一个问题需要注意：其实整个程序里面只有ldr pc, =led_blink这一句是位置有关码，其它的代码都是位置无关码，在我们的程序中，除了这一句以外其它的代码都在运行地址中运行，因为既然是位置无关码，它在运行地址运行也好，在链接地址运行也好，得到的情况总是相同的，因此我们不关心，而只有位置有关码，我们必须要使它在链接地址中去运行，所以我们要想运行led_blink函数，要让PC指针跳转到在链接地址中的led_blink函数中去。